Full Code of aphyr/tea-time for AI

Repository: aphyr/tea-time
Branch: master
Commit: b055044f0753
Files: 10
Total size: 38.4 KB

Directory structure:
gitextract_0pt7c4no/

├── .gitignore
├── CHANGELOG.md
├── LICENSE
├── README.md
├── doc/
│   └── intro.md
├── project.clj
├── src/
│   └── tea_time/
│       ├── core.clj
│       └── virtual.clj
└── test/
    └── tea_time/
        ├── core_test.clj
        └── virtual_test.clj

================================================
FILE CONTENTS
================================================

================================================
FILE: .gitignore
================================================
/target
/classes
/checkouts
pom.xml
pom.xml.asc
*.jar
*.class
/.lein-*
/.nrepl-port
.hgignore
.hg/


================================================
FILE: CHANGELOG.md
================================================
# Change Log
All notable changes to this project will be documented in this file. This change log follows the conventions of [keepachangelog.com](http://keepachangelog.com/).

## [Unreleased]
### Changed
- Add a new arity to `make-widget-async` to provide a different widget shape.

## [0.1.1] - 2018-04-02
### Changed
- Documentation on how to make the widgets.

### Removed
- `make-widget-sync` - we're all async, all the time.

### Fixed
- Fixed widget maker to keep working when daylight savings switches over.

## 0.1.0 - 2018-04-02
### Added
- Files from the new template.
- Widget maker public API - `make-widget-sync`.

[Unreleased]: https://github.com/your-name/tea-time/compare/0.1.1...HEAD
[0.1.1]: https://github.com/your-name/tea-time/compare/0.1.0...0.1.1


================================================
FILE: LICENSE
================================================
THE ACCOMPANYING PROGRAM IS PROVIDED UNDER THE TERMS OF THIS ECLIPSE PUBLIC
LICENSE ("AGREEMENT"). ANY USE, REPRODUCTION OR DISTRIBUTION OF THE PROGRAM
CONSTITUTES RECIPIENT'S ACCEPTANCE OF THIS AGREEMENT.

1. DEFINITIONS

"Contribution" means:

a) in the case of the initial Contributor, the initial code and
documentation distributed under this Agreement, and

b) in the case of each subsequent Contributor:

i) changes to the Program, and

ii) additions to the Program;

where such changes and/or additions to the Program originate from and are
distributed by that particular Contributor. A Contribution 'originates' from
a Contributor if it was added to the Program by such Contributor itself or
anyone acting on such Contributor's behalf. Contributions do not include
additions to the Program which: (i) are separate modules of software
distributed in conjunction with the Program under their own license
agreement, and (ii) are not derivative works of the Program.

"Contributor" means any person or entity that distributes the Program.

"Licensed Patents" mean patent claims licensable by a Contributor which are
necessarily infringed by the use or sale of its Contribution alone or when
combined with the Program.

"Program" means the Contributions distributed in accordance with this
Agreement.

"Recipient" means anyone who receives the Program under this Agreement,
including all Contributors.

2. GRANT OF RIGHTS

a) Subject to the terms of this Agreement, each Contributor hereby grants
Recipient a non-exclusive, worldwide, royalty-free copyright license to
reproduce, prepare derivative works of, publicly display, publicly perform,
distribute and sublicense the Contribution of such Contributor, if any, and
such derivative works, in source code and object code form.

b) Subject to the terms of this Agreement, each Contributor hereby grants
Recipient a non-exclusive, worldwide, royalty-free patent license under
Licensed Patents to make, use, sell, offer to sell, import and otherwise
transfer the Contribution of such Contributor, if any, in source code and
object code form.  This patent license shall apply to the combination of the
Contribution and the Program if, at the time the Contribution is added by the
Contributor, such addition of the Contribution causes such combination to be
covered by the Licensed Patents. The patent license shall not apply to any
other combinations which include the Contribution. No hardware per se is
licensed hereunder.

c) Recipient understands that although each Contributor grants the licenses
to its Contributions set forth herein, no assurances are provided by any
Contributor that the Program does not infringe the patent or other
intellectual property rights of any other entity. Each Contributor disclaims
any liability to Recipient for claims brought by any other entity based on
infringement of intellectual property rights or otherwise. As a condition to
exercising the rights and licenses granted hereunder, each Recipient hereby
assumes sole responsibility to secure any other intellectual property rights
needed, if any. For example, if a third party patent license is required to
allow Recipient to distribute the Program, it is Recipient's responsibility
to acquire that license before distributing the Program.

d) Each Contributor represents that to its knowledge it has sufficient
copyright rights in its Contribution, if any, to grant the copyright license
set forth in this Agreement.

3. REQUIREMENTS

A Contributor may choose to distribute the Program in object code form under
its own license agreement, provided that:

a) it complies with the terms and conditions of this Agreement; and

b) its license agreement:

i) effectively disclaims on behalf of all Contributors all warranties and
conditions, express and implied, including warranties or conditions of title
and non-infringement, and implied warranties or conditions of merchantability
and fitness for a particular purpose;

ii) effectively excludes on behalf of all Contributors all liability for
damages, including direct, indirect, special, incidental and consequential
damages, such as lost profits;

iii) states that any provisions which differ from this Agreement are offered
by that Contributor alone and not by any other party; and

iv) states that source code for the Program is available from such
Contributor, and informs licensees how to obtain it in a reasonable manner on
or through a medium customarily used for software exchange.

When the Program is made available in source code form:

a) it must be made available under this Agreement; and

b) a copy of this Agreement must be included with each copy of the Program.

Contributors may not remove or alter any copyright notices contained within
the Program.

Each Contributor must identify itself as the originator of its Contribution,
if any, in a manner that reasonably allows subsequent Recipients to identify
the originator of the Contribution.

4. COMMERCIAL DISTRIBUTION

Commercial distributors of software may accept certain responsibilities with
respect to end users, business partners and the like. While this license is
intended to facilitate the commercial use of the Program, the Contributor who
includes the Program in a commercial product offering should do so in a
manner which does not create potential liability for other Contributors.
Therefore, if a Contributor includes the Program in a commercial product
offering, such Contributor ("Commercial Contributor") hereby agrees to defend
and indemnify every other Contributor ("Indemnified Contributor") against any
losses, damages and costs (collectively "Losses") arising from claims,
lawsuits and other legal actions brought by a third party against the
Indemnified Contributor to the extent caused by the acts or omissions of such
Commercial Contributor in connection with its distribution of the Program in
a commercial product offering.  The obligations in this section do not apply
to any claims or Losses relating to any actual or alleged intellectual
property infringement. In order to qualify, an Indemnified Contributor must:
a) promptly notify the Commercial Contributor in writing of such claim, and
b) allow the Commercial Contributor to control, and cooperate with the
Commercial Contributor in, the defense and any related settlement
negotiations. The Indemnified Contributor may participate in any such claim
at its own expense.

For example, a Contributor might include the Program in a commercial product
offering, Product X. That Contributor is then a Commercial Contributor. If
that Commercial Contributor then makes performance claims, or offers
warranties related to Product X, those performance claims and warranties are
such Commercial Contributor's responsibility alone. Under this section, the
Commercial Contributor would have to defend claims against the other
Contributors related to those performance claims and warranties, and if a
court requires any other Contributor to pay any damages as a result, the
Commercial Contributor must pay those damages.

5. NO WARRANTY

EXCEPT AS EXPRESSLY SET FORTH IN THIS AGREEMENT, THE PROGRAM IS PROVIDED ON
AN "AS IS" BASIS, WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, EITHER
EXPRESS OR IMPLIED INCLUDING, WITHOUT LIMITATION, ANY WARRANTIES OR
CONDITIONS OF TITLE, NON-INFRINGEMENT, MERCHANTABILITY OR FITNESS FOR A
PARTICULAR PURPOSE. Each Recipient is solely responsible for determining the
appropriateness of using and distributing the Program and assumes all risks
associated with its exercise of rights under this Agreement , including but
not limited to the risks and costs of program errors, compliance with
applicable laws, damage to or loss of data, programs or equipment, and
unavailability or interruption of operations.

6. DISCLAIMER OF LIABILITY

EXCEPT AS EXPRESSLY SET FORTH IN THIS AGREEMENT, NEITHER RECIPIENT NOR ANY
CONTRIBUTORS SHALL HAVE ANY LIABILITY FOR ANY DIRECT, INDIRECT, INCIDENTAL,
SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING WITHOUT LIMITATION
LOST PROFITS), HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN
CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE)
ARISING IN ANY WAY OUT OF THE USE OR DISTRIBUTION OF THE PROGRAM OR THE
EXERCISE OF ANY RIGHTS GRANTED HEREUNDER, EVEN IF ADVISED OF THE POSSIBILITY
OF SUCH DAMAGES.

7. GENERAL

If any provision of this Agreement is invalid or unenforceable under
applicable law, it shall not affect the validity or enforceability of the
remainder of the terms of this Agreement, and without further action by the
parties hereto, such provision shall be reformed to the minimum extent
necessary to make such provision valid and enforceable.

If Recipient institutes patent litigation against any entity (including a
cross-claim or counterclaim in a lawsuit) alleging that the Program itself
(excluding combinations of the Program with other software or hardware)
infringes such Recipient's patent(s), then such Recipient's rights granted
under Section 2(b) shall terminate as of the date such litigation is filed.

All Recipient's rights under this Agreement shall terminate if it fails to
comply with any of the material terms or conditions of this Agreement and
does not cure such failure in a reasonable period of time after becoming
aware of such noncompliance. If all Recipient's rights under this Agreement
terminate, Recipient agrees to cease use and distribution of the Program as
soon as reasonably practicable. However, Recipient's obligations under this
Agreement and any licenses granted by Recipient relating to the Program shall
continue and survive.

Everyone is permitted to copy and distribute copies of this Agreement, but in
order to avoid inconsistency the Agreement is copyrighted and may only be
modified in the following manner. The Agreement Steward reserves the right to
publish new versions (including revisions) of this Agreement from time to
time. No one other than the Agreement Steward has the right to modify this
Agreement. The Eclipse Foundation is the initial Agreement Steward. The
Eclipse Foundation may assign the responsibility to serve as the Agreement
Steward to a suitable separate entity. Each new version of the Agreement will
be given a distinguishing version number. The Program (including
Contributions) may always be distributed subject to the version of the
Agreement under which it was received. In addition, after a new version of
the Agreement is published, Contributor may elect to distribute the Program
(including its Contributions) under the new version. Except as expressly
stated in Sections 2(a) and 2(b) above, Recipient receives no rights or
licenses to the intellectual property of any Contributor under this
Agreement, whether expressly, by implication, estoppel or otherwise. All
rights in the Program not expressly granted under this Agreement are
reserved.

This Agreement is governed by the laws of the State of New York and the
intellectual property laws of the United States of America. No party to this
Agreement will bring a legal action under this Agreement more than one year
after the cause of action arose. Each party waives its rights to a jury trial
in any resulting litigation.


================================================
FILE: README.md
================================================
# Tea-Time

> There was a disaster hanging silently in the air around him waiting for him to
> notice it. His knees tingled.
>
> What he needed, he had been thinking, was a client. He had been thinking that
> as a matter of habit. It was what he always thought at this time of the
> morning. What he had forgotten was that he had one.
>
> He stared wildly at his watch. Nearly eleven-thirty. He shook his head to try
> and clear the silent ringing between his ears, then made a hysterical lunge
> for his hat and his great leather coat that hung behind the door.
>
> Fifteen seconds later he left the house, five hours late but moving fast.
>
>  --Douglas Adams, "The Long Dark Tea-Time of the Soul"

Many programs need to interact with clocks: reading the current time,
scheduling some operation to be done at a particular time or a few seconds from
now, or performing some housekeeping task every few seconds. They may need to
dynamically create new tasks, push them back to a later time, and cancel them
when they are no longer needed. Moreover, testing these real-time behaviors for
side effects is notoriously slow and buggy. Tea-Time is a minimal Clojure
library which provides a global, lightweight, and testable scheduler for
exactly these purposes.

Tea-Time is adapted from the scheduler in Riemann, a distributed systems
monitoring server, where it has served for several years in
moderate-performance, long-running deployments. It's not perfect, but its API
and functionality have proven useful and stable.

Consistent use of Tea-Time can make it easier to write and test programs which
interact with wall clocks. With one call, you can switch from using wall clocks
to a virtual time, which advances only when you tell it to; scheduled tasks
evaluate synchronously, appearing to execute exactly at their target times.
Callers callers will read the virtual clock rather than the system clock. This
allows you to write tests for hours of "real-time" behavior which execute deterministically, in milliseconds.

Tea-Time is not for working with dates or human times; it works purely in
microseconds and the posix timescale. Tea-Time is not a parser or formatter.
There's no notion of intervals or calendars. These are all admirable goals,
better served by Joda Time, Juxt's Tick, et al.

## Installation

[![Clojars Project](https://img.shields.io/clojars/v/tea-time.svg)](https://clojars.org/tea-time)

## Quick Tour

```clj
user=> (require '[tea-time.core :as tt])
nil
user=> (tt/unix-time-micros)   ; Wall clock in microseconds
1522776026066000
user=> (tt/linear-time-micros) ; Monotonic clock in microseconds
128572305580
user=> (tt/start!)             ; Start threadpool

; Say hi after 1 second
user=> (tt/after! 1 (bound-fn [] (prn :hi)))
#tea_time.core.Once
{:cancelled #<Atom@6f21520e false>
 :f #<Fn@4919b682 clojure.core/bound_fn_STAR_[fn]>
 :id 1
 :t 128599825869}

; One second later...
:hi

; Every 10 seconds (after a 2 second wait)...
user=> (def dirk (tt/every! 10 2 (bound-fn [] (prn "THAT is a thing"))))
"THAT is a thing"
"THAT is a thing"
"THAT is a thing"
...

; Defer the next execution until 30 seconds from now
user=> (tt/defer! dirk 30)
129800.514632
... Ah, a breather ...
"THAT is a thing"

; That's over, it's cancelled
user=> (tt/cancel! dirk)
true
```

## Working with Clocks

The core library is one namespace:

```clj
user=> (require '[tea-time.core :as tt])
nil
```

Internally, Tea-time uses microseconds, represented as 64-bit signed longs, for
a balance of speed, representability, and precision. There are two timescales.
The Unix timescale, which is derived from System/currentTimeMillis,
approximately tracks "wall clock time", and can flow unevenly or even
backwards.

```clj
user=> (tt/unix-time-micros)
1522772393355000
```

For convenience and where precision is not critical, we also provide times in seconds, represented as 64-bit doubles.

```clj
user=> (tt/unix-time)
1.522772450458E9
user=> (long (tt/unix-time))
1522772475
```

You can convert back and forth:

```clj
user=> (tt/seconds->micros 1.2)
1200000
user=> (tt/micros->seconds 200)
2.0E-4
```

The linear timescale is derived from System/nanoTime, and advances
monotonically. However, it is not synchronized to any thing in particular, and
can only be used within a single JVM.

```clj
user=> (tt/linear-time)
125261.653199
user=> (tt/linear-time-micros)
125266476873
```

Use the linear timescale to measure relative times, e.g. the time it takes to
perform something in a single JVM. Use the Unix timescale to schedule things
that should be roughly synchronized across multiple JVMs. Do not use any time
for safety-critical applications: the list of ways clocks can go wrong is
effectively unbounded.

```clj
user=> (let [t1 (tt/linear-time)]
         (Thread/sleep 1000)
         (- (tt/linear-time) t1))
1.0001519999932498
```

## One-time Tasks

First, start the Tea-Time threadpool. This is a global set of worker threads which will evaluate scheduled tasks.

```clj
user=> (tt/start!)
```

You can stop the threadpool later with `tt/stop!`, which will politely finish
execution of any tasks currently being evaluated, and block until all threads
have exited.

To schedule a task after n seconds, use `after!`

```clj
user=> (def task (tt/after! 2 (bound-fn [] (prn "I took two seconds"))))
#'user/task
... wait two seconds...
user=> "I took two seconds"
```

We use `bound-fn` here to retain a handle to the repl's stdout, so `prn` works.
Regular `fn` works fine in most cases, and if you use a logger like
`clojure.tools.logging`, it'll work fine with plain old `fn` too.

You can *cancel* a task: if it hasn't been executed yet, it won't be when it
comes due. Canceling an already completed task is legal, but does nothing.

```clj
user=> (def task (tt/after! 10 (bound-fn [] (prn "I took ten seconds"))))
#'user/task
user=> (tt/cancel! task)
true
; ... nothing happens ...
```

## Recurring tasks

To schedule a recurring task, which should execute every n seconds, use
`every!`. Every takes an interval in seconds, and starts immediately.

```clj
(def task (tt/every! 2 (bound-fn [] (prn :hi))))
:hi
#'user/task
user=> :hi
:hi
:hi
user=> (tt/cancel! task)
true
; ... no more :hi's
```

You can also defer the first execution by providing an initial delay. To run
every 2 seconds, starting 5 seconds from now, say `(tt/every! 2 5 (bound-fn
(prn :hi)))`.

Recurrent tasks are also *deferrable*: you can push back the execution time to
to 10 seconds *from now*.

```clj
user=> (def task (tt/every! 2 (bound-fn [] (prn :hi))))
:hi
:hi
user=> (tt/defer! task 10)
126565647078
; Ahhh, a brief respite
:hi
:hi
```

This is particularly helpful for streaming or batching systems that accrue
events over time, and if nothing transpires for a few seconds, should flush
their state. Tea-Time makes `defer!` cheap, so you can call it on every event.

## Testing with Virtual Time

Testing real-time systems is *hard*: you usually wind up with a morass of sleep
statements, barriers, and weird race conditions. Tea-Time includes a hook to
run time-based tests *deterministically*.

First, make sure the scheduler is stopped, and pull in the virtual namespace.

```clj
user=> (tt/stop!)
[]
user=> (require '[tea-time.virtual :as tv])
nil
```

Use the `with-virtual-time!` macro to evaluate code with a virtual clock and
scheduler.

```clj
user=> (tv/with-virtual-time! (tt/unix-time))
0.0
user=> (tv/with-virtual-time! (tt/unix-time))
0.0
user=> (tv/with-virtual-time! (tt/linear-time))
0.0
user=> (tv/with-virtual-time! (tt/linear-time))
0.0
```

Time is *frozen* at 0 microseconds. Let's schedule some tasks.

```clj
user=> (tv/with-virtual-time!
          (tt/after! 2500 (bound-fn []
            (prn "I'm task 1, clocks are" (tt/unix-time) (tt/linear-time)))))
          (tt/after! 1.23 (bound-fn []
            (prn "I'm task 2, clocks are" (tt/unix-time) (tt/linear-time))))))
```

Nothing will happen. Time is still frozen. Let's jump forward to one second:

```clj
user=> (tv/advance! 1)
1.0
user=> (tv/with-virtual-time! (tt/unix-time))
1.0
```

The clock is now 1, but nothing has happened. Let's jump ahead to an hour:

```clj
user=> (tv/with-virtual-time! (tv/advance! 3600))
"I'm task 2, clocks are" 1.23 1.23
"I'm task 1, clocks are" 2500.0 2500.0
3600.0
```

Note that the tasks evaluated in their scheduled order--t2 before t1--and each
task observed the correct linear and unix times. So long as code uses
tea-time's wrappers, we can test hours of "real-time" behavior in a few
milliseconds, and obtain *deterministic* execution.

To reset the virtual clock to zero and clear all tasks, use

```clj
user=> (tv/reset-time!)
nil
user=> (tv/with-virtual-time! (tt/unix-time))
0.0
```

We provide a pair of handy fixtures for writing clojure.tests using virtualized
time:

```clj
(use-fixtures :once tv/call-with-virtual-time!)
(use-fixtures :each tv/reset-time!)
```

See `tests/` for additional examples.

## License

Copyright © 2018 Kyle Kingsbury

Distributed under the Eclipse Public License either version 1.0 or (at
your option) any later version.


================================================
FILE: doc/intro.md
================================================
# Introduction to tea-time

TODO: write [great documentation](http://jacobian.org/writing/what-to-write/)


================================================
FILE: project.clj
================================================
(defproject tea-time "1.0.1"
  :description "A simple, testable scheduler for asynchronous, cancellable, possibly periodic computation."
  :url "https://github.com/aphyr/tea-time"
  :license {:name "Eclipse Public License"
            :url "http://www.eclipse.org/legal/epl-v10.html"}
  :dependencies [[org.clojure/tools.logging "0.4.1"]]
  :profiles {:dev {:dependencies [[org.clojure/clojure "1.9.0"]]}})


================================================
FILE: src/tea_time/core.clj
================================================
(ns tea-time.core
  "Clocks and scheduled tasks. Provides functions for getting the current time
  and running functions (Tasks) at specific times and periods. Includes a
  threadpool for task execution, controlled by (start!) and (stop!)."
  (:import [java.util.concurrent ConcurrentSkipListSet]
           [java.util.concurrent.locks LockSupport])
  (:require [clojure.stacktrace    :refer [print-stack-trace]]
            [clojure.tools.logging :refer [warn info]]))

(defprotocol Task
  (succ [task]
    "The successive task to this one.")
  (run [task]
    "Executes this task.")
  (cancel! [task]
    "Cancel this task."))

(defprotocol Deferrable
  (defer! [this delay]
    "Schedule a task for a new time measured in seconds from now")

  (defer-micros! [this delay]
    "Schedule a task for a new time measured in microseconds from now"))


;; The clock implementation ;;;;;;;;;;;;;;;;;;;;;

(defn real-unix-time-micros
  "The current unix epoch time in microseconds, taken from
  System/currentTimeMillis"
  ^long
  []
  (* (System/currentTimeMillis) 1000))

(defn real-linear-time-micros
  "A current time on a linear scale with no fixed epoch; counts in
  microseconds. Unlike unix-time, which can pause, skip, or flow backwards,
  advances mostly monotonically at (close) to physical time, one second per
  second."
  ^long
  []
  (long (/ (System/nanoTime) 1000)))

(defn micros->seconds
  "Convert microseconds to seconds, as doubles."
  ^double
  [t]
  (/ t 1000000.0))

(defn seconds->micros
  "Convert seconds to microseconds, as longs."
  ^long
  [t]
  (long (* t 1000000)))

(defn ^double real-unix-time
  "The current unix epoch time in seconds, taken from System/currentTimeMillis"
  ^double
  []
  (micros->seconds (real-unix-time-micros)))

(defn real-linear-time
  "The current linear time in seconds, taken from System/nanoTime"
  ^double
  []
  (micros->seconds (real-linear-time-micros)))

;; The clock API ;;;;;;;;;;;;;;;;;;;;;;;;;

(def unix-time-micros
  "Rebindable alias for real-unix-time-micros"
  real-unix-time-micros)

(def linear-time-micros
  "Rebindable alias for real-linear-time-micros"
  real-linear-time-micros)

(def unix-time
  "Rebindable alias for real-unix-time"
  real-unix-time)

(def linear-time
  "Rebindable alias for real-linear-time"
  real-linear-time)

;; More conversions ;;;;;;;;;;;;;;;;;;;;;

(defn unix-micros->linear-micros
  "Converts an instant in the unix timescale to an instant on the linear
  timescale, approximately."
  ^long
  [^long unix]
  (+ (linear-time-micros) (- unix (unix-time-micros))))

;; Global state ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

; TODO: pull this stuff out into some sort of configurable Scheduler datatype,
; and provide a global default?

(def max-task-id
  (atom 0))

(def ^ConcurrentSkipListSet tasks
  "Scheduled operations."
  (ConcurrentSkipListSet.
    (fn [a b] (compare [(:t a) (:id a)]
                       [(:t b) (:id b)]))))

(def thread-count
  "Number of threads in the threadpool"
  4)

(def park-interval-micros
  "Time we might sleep when nothing is scheduled, in micros."
  10000)

(def threadpool
  (atom []))

(def running
  "Whether the threadpool is currently supposed to be alive."
  (atom false))

;; Scheduling guts ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

(defn ceil
  "Ceiling. For integers, identity. For other things, uses Math/ceil and
  coerces to long."
  [x]
  (if (integer? x)
    x
    (long (Math/ceil x))))

(defn task-id
  "Return a new task ID."
  []
  (swap! max-task-id inc))

(defn next-tick
  "Given a period dt, beginning at some point in time anchor, finds the next
  tick after time now, such that the next tick is separate from anchor by an
  exact multiple of dt. If now is omitted, defaults to (linear-time), and both
  anchor and dt are in seconds. If now is passed, anchor, dt, and now can be in
  any unit, so long as they all agree."
  ([anchor dt]
   (next-tick anchor dt (linear-time)))
  ([anchor dt now]
   (+ now (- dt (mod (- now anchor) dt)))))

; Look at all these bang! methods! Mutability is SO EXCITING!

(defn reset-tasks!
  "Resets the task queue to empty, without triggering side effects."
  []
  (.clear tasks))

(defn poll-task!
  "Removes the next task from the queue."
  []
  (.pollFirst tasks))

(defn schedule-sneaky!
  "Schedules a task. Does *not* awaken any threads."
  [task]
  (.add tasks task)
  task)

(defn schedule!
  "Schedule a task. May awaken a thread from the threadpool to investigate."
  [task]
  (schedule-sneaky! task)
  (when @running
    (LockSupport/unpark (rand-nth @threadpool)))
  task)

;; Task datatypes ;;;;;;;;;;;;;;;;;;;;;;;

(defrecord Once [id f ^long t cancelled]
  Task
  (succ [this] nil)
  (run [this] (when-not @cancelled (f)))
  (cancel! [this]
          (reset! cancelled true)))

(defrecord Every [id f ^long t ^long interval deferred-t cancelled]
  Task
  (succ [this]
        (when-not @cancelled
          (let [next-time (or @deferred-t (+ t interval))]
            (reset! deferred-t nil)
            (assoc this :t next-time))))

  (run [this]
       (when-not (or @deferred-t @cancelled) (f)))

  (cancel! [this]
          (reset! cancelled true))

  Deferrable
  (defer! [this delay]
    (micros->seconds (defer-micros! this (seconds->micros delay))))

  (defer-micros! [this delay]
    (reset! deferred-t (+ (linear-time-micros) delay))))

(defn at-linear-micros!
  "Calls f at t microseconds on the linear timescale."
  [t f]
  (schedule! (Once. (task-id) f t (atom false))))

(defn at-unix-micros!
  "Calls f at t microseconds on the unix timescale. We convert this time to the
  linear timescale, so it may behave oddly across leap seconds."
  [t f]
  (at-linear-micros! (unix-micros->linear-micros t) f))

(defn at-unix!
  "Calls f at t seconds on the unix timescale. We convert this time to
  the linear timescale, so it may behave oddly across leap seconds."
  [t f]
  (at-unix-micros! (seconds->micros t) f))

(defn after!
  "Calls f after delay seconds."
  [delay f]
  (schedule! (Once. (task-id)
                    f
                    (+ (linear-time-micros) (seconds->micros delay))
                    (atom false))))

(defn every!
  "Calls f every interval seconds, after delay, also in seconds. If no delay is
  provided, starts immediately."
  ([interval f]
   (every! interval 0 f))
  ([interval delay f]
   (assert (not (neg? delay)))
   (schedule! (Every. (task-id)
                      f
                      (+ (linear-time-micros) (seconds->micros delay))
                      (seconds->micros interval)
                      (atom nil)
                      (atom false)))))

(defn run-tasks!
  "While running, takes tasks from the queue and executes them when ready. Will
  park the current thread when no tasks are available."
  [i]
  (while @running
    (try
      (if-let [task (poll-task!)]
        ; We've acquired a task.
        (do
          ; (info "Task acquired")
          (if (<= (:t task) (linear-time-micros))
            ; This task is ready to run
            (do
              ;(info :task task :time (linear-time-micros))
              ; Run task
              (try
                (run task)
                (catch Exception e
                  (warn e "Tea-Time task" task "threw"))
                (catch AssertionError t
                  (warn t "Tea-Time task" task "threw")))
              (when-let [task' (succ task)]
                ; Schedule the next task.
                (schedule-sneaky! task')))
            (do
              ; Return task.
              (schedule-sneaky! task)
              ; Park until that task comes up next. We can't use parkUntil cuz
              ; it uses posix time which is non-monotonic. WHYYYYYY Note that
              ; we're sleeping 100 microseconds minimum, and aiming to wake up
              ; 1 ms before, so we have a better chance of actually executing
              ; on time.
              (->> (- (:t task) (linear-time-micros) 1000)
                   (max 10)
                   (min park-interval-micros)
                   (* 1000)
                   LockSupport/parkNanos))))

        ; No task available; park for a bit and try again.
        (LockSupport/parkNanos (* 1000 park-interval-micros)))
      (catch Exception e
      (warn e "tea-time task threw"))
    (catch AssertionError t
      (warn t "tea-time task threw")))))

(defn stop!
  "Stops the task threadpool. Waits for threads to exit. Repeated calls to stop
  are noops."
  []
  (locking threadpool
    (when @running
      (reset! running false)
      (while (some #(.isAlive ^Thread %) @threadpool)
        ; Allow at most 1/10th park-interval to pass after all threads exit.
        (Thread/sleep (/ park-interval-micros 10000)))
      (reset! threadpool []))))

(defn start!
  "Starts the threadpool to execute tasks on the queue automatically. Repeated
  calls to start are noops."
  []
  (locking threadpool
    (when-not @running
      (reset! running true)
      (reset! threadpool
              (map (fn [i]
                     (let [^Runnable f (bound-fn [] (run-tasks! i))]
                       (doto (Thread. f (str "Tea-Time " i))
                         (.start))))
                   (range thread-count))))))

(def threadpool-users
  "Number of callers who would like a threadpool open right now"
  (atom 0))

(defmacro with-threadpool
  "Ensures the threadpool is running within `body`, which is evaluated in an
  implicit `do`. Multiple threads can call with-threadpool
  concurrently. If any thread is within `with-threadpool`, the pool will run,
  and when no threads are within `with-threadpool`, the pool will shut down.

  You'll probably put this in the main entry points to your program, so the
  threadpool runs for the entire life of the program."
  [& body]
  `(try (when (= 1 (swap! threadpool-users inc))
          (start!))
        ~@body
        (finally
          (when (= 0 (swap! threadpool-users dec))
            (stop!)))))


================================================
FILE: src/tea_time/virtual.clj
================================================
(ns tea-time.virtual
  "Provides controllable periodic and deferred execution. Calling (advance!
  target-time-in-seconds) moves the clock forward, triggering events that would
  have occurred, in sequence. Each task executes exactly at its target time."
  (:require [tea-time.core :refer :all]
            [clojure.tools.logging :refer [info]]))

(def clock
  "Reference to the current time, in microseconds."
  (atom 0))

(defn reset-clock!
  []
  (reset! clock 0))

(defn reset-time!
  "Resets the clock and task queue. If a function is given, calls f after
  resetting the time and task list."
  ([f] (reset-time!) (f))
  ([]
   (reset-clock!)
   (reset-tasks!)))

(defn set-time!
  "Sets the current time in seconds, without triggering callbacks."
  [t]
  (reset! clock (seconds->micros t)))

(defn virtual-unix-time-micros
  []
  @clock)

(defn virtual-linear-time-micros
  []
  @clock)

(defn virtual-unix-time
  []
  (micros->seconds @clock))

(defn virtual-linear-time
  []
  (micros->seconds @clock))

(defn advance!
  "Advances the clock to t seconds, triggering side effects. Tasks are run
  synchronously on this thread, and their exceptions will be thrown here."
  [t]
  (let [t (seconds->micros t)]
    (when (< @clock t)
      (loop []
        (when-let [task (poll-task!)]
          (if (<= (:t task) t)
            (do
              ; Consume task
              (swap! clock max (:t task))
              (run task)
              (when-let [task' (succ task)]
                (schedule-sneaky! task'))
              (recur))
            ; Return task
            (schedule-sneaky! task))))
      (micros->seconds (swap! clock max t)))))

(defmacro with-virtual-time!
  "Switches time functions to virtual counterparts, evaluates body, and
  returns. Not at all threadsafe; bindings take effect globally. This is only
  for testing."
  [& body]
  ; Please forgive me
  `(with-redefs [tea-time.core/unix-time          virtual-unix-time
                 tea-time.core/unix-time-micros   virtual-unix-time-micros
                 tea-time.core/linear-time        virtual-linear-time
                 tea-time.core/linear-time-micros virtual-linear-time-micros]
     ~@body))

(defn call-with-virtual-time!
  "Switches time functions to time.controlled counterparts, invokes f,
  then restores them. Definitely not threadsafe. Not safe by any standard,
  come to think of it. Only for testing purposes."
  [f]
  (with-virtual-time! (f)))


================================================
FILE: test/tea_time/core_test.clj
================================================
(ns tea-time.core-test
  (:require [tea-time.core :refer :all]
            [clojure.test :refer :all]
            [clojure.tools.logging :refer [info]]))


(defn reset-time!
  [f]
  (stop!)
  (reset-tasks!)
  (start!)
  (f)
  (stop!)
  (reset-tasks!))
(use-fixtures :each reset-time!)

(deftest next-tick-test
         (are [anchor dt now next] (= (next-tick anchor dt now) next)
              0 1 0 1
              0 2 0 2
              1 1 0 1
              2 1 0 1
              0 2 0 2
              0 2 1 2
              0 2 2 4
              2 2 2 4
              4 2 2 4
              1 2 1 3
              1 2 2 3
              1 2 3 5))

(deftest ^:time clock-test
         (is (< -1
                (- (/ (System/currentTimeMillis) 1000) (unix-time))
                1)))

(deftest ^:time after-test
         "Run a function once, to verify that the threadpool works at all."
         (let [t0 (unix-time)
               results (atom [])]
           (after! 0.1 #(swap! results conj (- (unix-time) t0)))
           (Thread/sleep 300)
           (prn :dt @results)
           (is (<= 0.09 (first @results) 0.11))))

; LMAO if this test becomes hilariously unstable and/or exhibits genuine
; heisenbugs for any unit of time smaller than 250ms.
(deftest ^:time defer-cancel-test
         (let [x1 (atom 0)
               x2 (atom 0)
               t1 (every! 1 (fn [] (swap! x1 inc)))
               t2 (every! 1 1 #(swap! x2 inc))]
           (Thread/sleep 500)
           (is (= 1 @x1))
           (is (= 0 @x2))

           (Thread/sleep 1000)
           (is (= 2 @x1))
           (is (= 1 @x2))

           ; Defer
           (defer! t1 1.5)
           (Thread/sleep 1000)
           (is (= 2 @x1))
           (is (= 2 @x2))

           (Thread/sleep 1000)
           (is (= 3 @x1))
           (is (= 3 @x2))

           ; Cancel
           (cancel! t2)
           (Thread/sleep 1000)
           (is (= 4 @x1))
           (is (= 3 @x2))))

(deftest ^:time exception-recovery-test
         (let [x (atom 0)]
           (every! 0.1 (fn []
                         (swap! x inc)
                         (throw (IllegalStateException. "Test Exception"))))
           (Thread/sleep 150)
           (is (= 2 @x))))

(defn mapvals
  [f kv]
  (into {} (map (fn [[k v]] [k (f v)]) kv)))

(defn pairs
  [coll]
  (partition 2 1 coll))

(defn differences
  [coll]
  (map (fn [[x y]] (- y x)) (pairs coll)))

(deftest ^:time periodic-test
         "Run one function periodically."
         (let [results (atom [])]
           ; For a wide variety of intervals, start periodic jobs to record
           ; the time.
           (doseq [interval (range 1/10 5 1/10)]
             (every! interval #(swap! results conj [interval (unix-time)])))

           (Thread/sleep 20000)
           (stop!)

           (let [groups (mapvals (fn [vs] (map second vs))
                                 (group-by first @results))
                 differences (mapvals differences groups)]
             (doseq [[interval deltas] differences]
               ; First delta will be slightly smaller because the scheduler
               ; computed an absolute time in the *past*
               ; (is (<= -0.025 (- (first deltas) interval) 0))

               (let [deltas (drop 0 deltas)]
                 ; Remaining deltas should be accurate to within 5ms.
                 (is (every? (fn [delta]
                               (< -0.01 (- delta interval) 0.01)) deltas))
                 ; and moreover, there should be no cumulative drift.
                 (is (< -0.005
                        (- (/ (reduce + deltas) (count deltas)) interval)
                        0.005)))))))


================================================
FILE: test/tea_time/virtual_test.clj
================================================
(ns tea-time.virtual-test
  (:require [tea-time.core :refer :all]
            [tea-time.virtual :refer :all]
            [clojure.test :refer :all]))

(use-fixtures :once call-with-virtual-time!)
(use-fixtures :each reset-time!)

(deftest clock-test
         (is (= (virtual-unix-time) 0.0))
         (advance! -1)
         (is (= (virtual-unix-time) 0.0))
         (advance! 4.5)
         (is (= (virtual-unix-time) 4.5))
         (reset-time!)
         (is (= (virtual-unix-time) 0.0)))

(deftest at-test
         (let [x (atom 0)
               once1 (at-unix! 1 #(swap! x inc))
               once2 (at-unix! 2 #(swap! x inc))
               once3 (at-unix! 3 #(swap! x inc))]

           (advance! 0.5)
           (is (= @x 0))

           (advance! 2)
           (is (= @x 2))

           (cancel! once3)
           (advance! 3)
           (is (= @x 2))))

(deftest every-test
         (let [x (atom 0)
               bump #(swap! x inc)
               task (every! 1 2 bump)]

           (is (= @x 0))

           (advance! 1)
           (is (= @x 0))

           (advance! 2)
           (is (= @x 1))

           (advance! 3)
           (is (= @x 2))

           (advance! 4)
           (is (= @x 3))

           ; Double-down
           (defer! task -3)
           (is (= @x 3))
           (advance! 5)
           (is (= @x 8))

           ; Into the future!
           (defer! task 4)
           (advance! 8)
           (is (= @x 8))
           (advance! 9)
           (is (= @x 9))
           (advance! 10)
           (is (= @x 10))))