Showing preview only (251K chars total). Download the full file or copy to clipboard to get everything.
Repository: nox771/i2c_t3
Branch: master
Commit: 1a482d9f85bf
Files: 17
Total size: 241.2 KB
Directory structure:
gitextract_mjc7m6f3/
├── README.md
├── archive/
│ └── README.md
├── examples/
│ ├── advanced_loopback/
│ │ └── advanced_loopback.ino
│ ├── advanced_master/
│ │ └── advanced_master.ino
│ ├── advanced_scanner/
│ │ └── advanced_scanner.ino
│ ├── advanced_slave/
│ │ └── advanced_slave.ino
│ ├── basic_echo/
│ │ └── basic_echo.ino
│ ├── basic_interrupt/
│ │ └── basic_interrupt.ino
│ ├── basic_master/
│ │ └── basic_master.ino
│ ├── basic_master_callback/
│ │ └── basic_master_callback.ino
│ ├── basic_master_mux/
│ │ └── basic_master_mux.ino
│ ├── basic_scanner/
│ │ └── basic_scanner.ino
│ ├── basic_slave/
│ │ └── basic_slave.ino
│ └── basic_slave_range/
│ └── basic_slave_range.ino
├── i2c_t3.cpp
├── i2c_t3.h
└── keywords.txt
================================================
FILE CONTENTS
================================================
================================================
FILE: README.md
================================================
# i2c_t3
Enhanced I2C library for Teensy 3.x & LC devices
This is an enhanced I2C library for [Teensy 3.x/LC devices](http://pjrc.com/teensy/index.html).
Recent discussion and a usage summary can be found in the [PJRC forums here](https://forum.pjrc.com/threads/21680-New-I2C-library-for-Teensy3).
---
---
## **Description**
This library is designed to operate from the Arduino/Teensyduino development system. However this is not strictly required as the files can be used independently. Recent releases of the library are bundled with the Teensyduino software [available here](http://pjrc.com/teensy/td_download.html). Follow the instructions on that page for installation.
The library can also be downloaded separately (eg. for updates), and used by unpacking the library contents into your **sketchbook/libraries** folder.
To use with existing Arduino sketches, simply change the **#include \<Wire.h\>** to **#include \<i2c_t3.h\>**
Example sketches can be found in the Arduino menus at: **File->Examples->i2c_t3**
The latest version of the library provides the following:
* For **Teensy 3.0**, there is one I2C interface: **Wire**
* For **Teensy 3.1, 3.2, LC**, there are two I2C interfaces: **Wire**, **Wire1**
* For **Teensy 3.5**, there are three I2C interfaces: **Wire**, **Wire1**, **Wire2**
* For **Teensy 3.6**, there are four I2C interfaces: **Wire**, **Wire1**, **Wire2**, **Wire3**
---
---
## **Pins**
Some interfaces have multiple sets of pins that they can utilize. For a given interface only one set of pins can be used at a time, but for a device configured as a bus Master the pins can be changed on-the-fly when the bus is idle.
In functions that require a pin specification there are two ways to specify it. One is to use the pin enum as shown in the table below under "Pin Name". This will restrict the pin choices to the listed pin pairings. The other method is to specify the SCL, SDA pins directly (in that order), using any valid SCL or SDA pin given the device type and interface used. If pins are not given on initial setup then defaults are used as indicated below (based on device type and bus).
As an example the following functions are all valid:
```
Wire.begin(I2C_MASTER, 0x00, I2C_PINS_18_19, I2C_PULLUP_EXT, 400000); // Wire bus, SCL pin 19, SDA pin 18, ext pullup, 400kHz
Wire.begin(I2C_MASTER, 0x00, 19, 18); // equivalent to above, will default to ext pullup at 400kHz
Wire.begin(I2C_MASTER, 0x00, 16, 18); // similar to above, but using SCL pin 16 and SDA pin 18
```
The mapping of device types, available pins, and interfaces is as follows. Note that these are not physical pin numbers, they refer to the Teensy pin assignments, which can be viewed here: https://www.pjrc.com/teensy/pinout.html
```
Interface Devices Pin Name SCL SDA Default
--------- ------- -------------- ----- ----- -------
Wire All I2C_PINS_16_17 16 17
Wire All I2C_PINS_18_19 19* 18 +
Wire 3.5/3.6 I2C_PINS_7_8 7 8
Wire 3.5/3.6 I2C_PINS_33_34 33 34
Wire 3.5/3.6 I2C_PINS_47_48 47 48
Wire1 LC I2C_PINS_22_23 22 23 +
Wire1 3.1/3.2 I2C_PINS_26_31 26 31
Wire1 3.1/3.2 I2C_PINS_29_30 29 30 +
Wire1 3.5/3.6 I2C_PINS_37_38 37 38 +
Wire2 3.5/3.6 I2C_PINS_3_4 3 4 +
Wire3 3.6 I2C_PINS_56_57 57* 56 +
```
Note: in almost all cases SCL is the lower pin #, except cases marked *
On some devices the pins for the 2nd and higher number buses (Wire1, Wire2, Wire3) may reside on surface mount backside pads. It is recommended to use a breakout expansion board to access those, as the pads are likely not mechanically robust, with respect to soldered wires pulling on them. There are a number of breakout boards for this purpose such as these:
* Clever slotted board: https://www.oshpark.com/shared_projects/ttl7D5iT
* Full kit board: https://www.tindie.com/products/loglow/teensy-32-breakout/
---
---
## **Pullups**
The I2C bus is a two-wire interface where the SDA and SCL are active pulldown and passive pullup (resistor pullup). When the bus is not communicating both line voltages should be at the high level pullup voltage.
The pullup resistor needs to be low-enough resistance to pull the line voltage up given the capacitance of the wire and the transfer speed used. For a given line capacitance, higher speed transfers will necessitate a lower resistance pullup in order to make the rising-edge rate faster. Generally the falling-edge rates are not a problem since the active pulldowns (typically NMOS) are usually quite strong. This article illustrates the effect of varying pullup resistance:
http://dsscircuits.com/articles/86-articles/47-effects-of-varying-i2c-pull-up-resistors
However, if an excessively low resistance is used for the pullups then the pulldown devices may not be able to pull the line voltage low enough to be recognized as an low-level input signal. This can sometimes occur if multiple devices are connected on the bus, each with its own internal pullup. TI has a whitepaper on calculating pullup resistance here:
http://www.ti.com/lit/an/slva689/slva689.pdf
In general, for a majority of simple I2C bus configurations a pullup resistance value in the range of **2k to 5k** Ohms should work fine.
### **Teensy Pullups**
**_Due to the situation with internal pullups, it is recommended to use external pullups for all devices in all cases (except in special cases for the 3.0/3.1/3.2 devices)._**
Regarding the Teensy devices, the library provides an option to use either internal pullups or external pullups (by specifiying **I2C_PULLUP_INT** or **I2C_PULLUP_EXT** on the bus configuration functions). For most cases external pullups, **I2C_PULLUP_EXT**, is the preferred connection simply because it is easier to configure the bus for a particular resistance value, and for a particular pullup voltage (not necessarily the same as the device voltages, more below). Note, when using external pullups all devices should be configured for external.
That said, sometimes internal pullups, **I2C_PULLUP_INT**, are used to simplify wiring or for simple test scenarios. When using internal pullups, generally only one device is configured for internal (typically the Master), and Slave devices are configured for external (since they rely on the Master device to pullup). It is possible to have multiple devices configured for internal on the same bus, as long as the aggregate pullup resistance does not become excessively low (the resistances will be in parallel so the aggregate will be less than the lowest value).
The internal pullup resistances of the Teensy devices are as follows:
* Teensy LC - ~44k Ohms
* Teensy 3.0/3.1/3.2 - ~190 Ohms (this is believed to be a HW bug)
* Teensy 3.5 - ~150 Ohms (this is believed to be a HW bug)
* Teensy 3.6 - ~25 Ohms (this is believed to be a HW bug)
None of these internal pullups is a particularly good value.
The Teensy 3.0/3.1/3.2 value of ~190 Ohms is very strong (it is believed to be a HW bug), however in most cases it can work fine on a short bus with a few devices. It will work at most any speed, including the max library speeds (eg. breadboard with 3.0/3.1/3.2 device and a few Slave devices usually works fine with internal pullups). That said, multiple devices configured for internal pullups on the same bus will not work well, as the line impedance will be too low. If using internal pullups make sure at most one device is internal and the rest are external.
On the other hand, the Teensy LC value of ~44k Ohms is very weak. An LC configured for internal will have trouble running at high speeds in all configurations.
The Teensy 3.6 internal pullup is essentially a short, and is unusable.
### **Pullup Voltages**
Some consideration should be given when connecting 3.3V and 5V devices together on a common I2C bus. The bus voltage should be one or the other, and there should not be multiple pullups connecting to different voltages on a single line.
The voltage tolerance is as follows:
```
Voltage Devices
------- -----------
3.3V 3.0, 3.6, LC
5.0V 3.1, 3.2, 3.5
```
Sometimes devices supplied at 5V will communicate fine if the I2C bus is at 3.3V, because the logic high/low thresholds are biased towards ground more than supply. However if a 5V device truly requires a 5V I2C signal, whereas other devices on the bus require 3.3V signal, there is a method to accomplish this.
To connect 5V devices to 3.3V tolerant Teensy or to connect multiple voltage level I2C buses, refer to the following app note by NXP:
http://www.nxp.com/documents/application_note/AN10441.pdf
There are also many bidirectional I2C level-shifter ICs and breakout boards on the market which can simplify building such connections. Many implement exactly what is shown in the NXP app note.
---
---
## **Clocking**
The library now supports arbitrary I2C clock rate frequencies, which can be specified directly, eg. 400000 for 400kHz. The I2C clock rate is set via a divide ratio from the **F_BUS** frequency (except for Wire1 bus on LC device which uses **F_CPU**). There is a fixed list of divide ratios available, and the library will choose the nearest available ratio when attempting to produce a requested I2C rate.
The maximum I2C rate is 1/20th of F_BUS. Some examples relating F_CPU, F_BUS, and max I2C rate are below (actual device configuration depends on compile settings):
```
F_CPU F_BUS Max I2C
(MHz) (MHz) Rate
------------- ----- ----------
240/120 120 6.0M bus overclock
216 108 5.4M bus overclock
192/96 96 4.8M bus overclock
180 90 4.5M bus overclock
240 80 4.0M bus overclock
216/144/72 72 3.6M bus overclock
192 64 3.2M bus overclock
240/180/120 60 3.0M
168 56 2.8M
216 54 2.7M
192/144/96/48 48 2.4M
72 36 1.8M
24 24 1.2M
16 16 800k
8 8 400k
4 4 200k
2 2 100k
```
Previous library releases used **I2C_RATE_xxxx** enums. This is still supported, but is now deprecated, and specifying the frequency directly (as a uint32_t value) is now the preferred method.
Allowable I2C_RATE_xxxx enum list is as follows:
* I2C_RATE_100, I2C_RATE_200, I2C_RATE_300, I2C_RATE_400, I2C_RATE_600, I2C_RATE_800, I2C_RATE_1000, I2C_RATE_1200, I2C_RATE_1500, I2C_RATE_1800, I2C_RATE_2000, I2C_RATE_2400, I2C_RATE_2800, I2C_RATE_3000
Note that at high speeds the specified clock is not necessarily equivalent to actual SCL clock speeds. The peripheral limits the actual SCL speeds to well below the theoretical speeds (both in terms of actual bit clock frequency and throughput rates).
To get a better idea of throughput the transfer time for a 128 byte transfer across different F_CPU/F_BUS/I2C Rate combinations has been measured on a Teensy 3.1 device. This behavior generally applies to all devices. This is shown below.
---
---
## **Operational Modes**
There are three modes of operation: **Interrupt**, **DMA**, and **Immediate**. The operating mode of the I2C can be set in the **begin()** or **setOpMode()** functions, using the opMode parameter which can have the following values:
* **I2C_OP_MODE_ISR** - Interrupt
* **I2C_OP_MODE_DMA** - DMA
* **I2C_OP_MODE_IMM** - Immediate
**Interrupt** mode is the normal default mode (it was the only mode in library versions prior to v7). It supports both Master and Slave operation. The two other modes, **DMA** and **Immediate**, are for Master operation only.
DMA mode requires an available DMA channel to operate. In cases where DMA mode is specified, but there are no available channels, then the I2C will revert to operating in Interrupt mode.
Similarly, for Interrupt mode to work the I2C ISRs must run at a higher priority than the calling function. Where this is not the case, the library will first attempt to elevate the priority of the I2C ISR to a higher priority than the calling function. If that is not possible then it will revert to operating in Immediate mode.
---
---
## **Example List**
Examples are divided into two categories, **basic** and **advanced**. Basic examples are demonstrate basic "Arduino-like" function of the library. Advanced examples demonstrate more complex scenarios, such as multi-bus, concurrent Master/Slave, and background transfer (ISR or DMA) operations.
* **basic_master** - this creates a Master device which is setup to talk to the Slave device given in the **basic_slave** sketch.
* **basic_master_mux** - this creates a Master device which can communicate using the Wire bus on two sets of pins, and change pins on-the-fly. This type of operation is useful when communicating with Slaves with fixed, common addresses (allowing one common-address Slave on each set of pins).
* **basic_master_callback** - this creates a Master device which acts similar to the basic_master sketch, but it uses callbacks to handle transfer results and errors.
* **basic_slave** - this creates a Slave device which responds to the **basic_master** sketch.
* **basic_slave_range** - this creates a Slave device which will respond to a range of I2C addresses. A function exists to obtain the Rx address, therefore it can be used to make a single device act as multiple I2C Slaves.
* **basic_scanner** - this creates a Master device which will scan the address space and report all devices which ACK. It only scans the Wire bus.
* **basic_interrupt** - this creates a Master device which is setup to periodically read/write from a Slave device using a timer interrupt.
* **basic_echo** - this creates a device which listens on Wire1 and then echos that incoming data out on Wire. It demonstrates non-blocking nested Wire calls (calling Wire inside Wire1 ISR).
* **advanced_master** - this creates a Master device which is setup to talk to the Slave device given in the **advanced_slave** sketch. It adds a protocol layer on-top of basic I2C communication and has a series of more complex tests.
* **advanced_slave** - this creates a Slave device which responds to the **advanced_master** sketch. It responds to a protocol layer on-top of basic I2C communication.
* **advanced_scanner** - this creates a Master device which will scan the address space and report all devices which ACK. It scans all existing I2C buses.
* **advanced_loopback** - this creates a device using one bus as a Master (Wire) and all other buses as Slaves. When all buses are wired together (loopback) it creates a closed test environment, which is particularly useful for Master/Slave development on a single device.
---
---
## **Header Defines**
These defines can be modified at the top of the **i2c_t3.h** file.
* **I2C_BUS_ENABLE n** - this controls how many buses are enabled. When set as "I2C_BUS_ENABLE 1" only Wire will be active and code/ram size will be reduced. When set as "I2C_BUS_ENABLE 2" then both Wire and Wire1 will be active and code/ram usage will be increased. Specifying a higher number of buses than exists is allowed, as it will be automatically limited by what is available on the device. The default is "I2C_BUS_ENABLE 4", to enable all buses on all devices by default.
* **I2C_TX_BUFFER_LENGTH n**
* **I2C_RX_BUFFER_LENGTH n** - these two defines control the buffers allocated to transmit/receive functions. When dealing with Slaves which don't need large communication (eg. sensors or such), these buffers can be reduced to a smaller size. Buffers should be large enough to hold: Target Addr + Data payload. Default is: 259 bytes = 1 byte Addr + 258 byte Data, as that is what some examples use.
* **I2Cx_INTR_FLAG_PIN p** - these defines make the specified pin high whenever the I2C interrupt occurs (I2C0 == Wire, I2C1 == Wire1, and so on). This is useful as a trigger signal when using a logic analyzer. By default they are undefined (commented out).
* **I2C_AUTO_RETRY** - this define is used to make the library automatically call **resetBus()** if it has a timeout while trying to send a START. This is useful for clearing a hung Slave device from the bus. If successful it will try again to send the START, and proceed normally. If not then it will exit with a timeout. Note - this option is NOT compatible with multi-master buses. By default it is disabled.
* **I2C_ERROR_COUNTERS** - uncomment to make the library track error counts. Error counts can be retrieved or zeroed using the **getErrorCount()** and **zeroErrorCount()** functions respectively. When included, errors will be tracked on the following (Master-mode only): Reset Bus (auto-retry only), Timeout, Addr NAK, Data NAK, Arb Lost, Bus Not Acquired, DMA Errors. By default error counts are enabled.
* **I2C_DISABLE_PRIORITY_CHECK** - uncomment to entirely disable auto priority escalation. Normally priority escalation occurs to ensure I2C ISR operates at a higher priority than the calling function (to prevent ISR stall if the calling function blocks). Uncommenting this will disable the check and cause I2C ISR to remain at default priority. It is recommended to disable this check and manually set ISR priority levels when using complex configurations. By default priority checks are enabled (this define is commented out).
---
---
## **Function Summary**
The functions are divided into the following classifications:
* _**Italic**_ functions are compatible with the original Arduino Wire API. This allows existing Arduino sketches to compile without modification.
* **Bold** functions are the added enhanced functions. They utilize the advanced capabilities of the Teensy hardware. The library provides the greatest benefit when utilizing these functions (versus the standard Wire library).
* **'^'** indicates optional function arguments. When not specified default values will be used.
---
_**Wire.begin();**_ - initializes I2C as Master mode, external pullups, 100kHz rate, and default pin setting
* default pin setting SCL/SDA:
* Wire: 19/18
* Wire1: 29/30 (3.1/3.2), 22/23 (LC), 37/38 (3.5/3.6)
* Wire2: 3/4 (3.5/3.6)
* Wire3: 57/56 (3.6)
* return: none
---
_**Wire.begin(address);**_ - initializes I2C as Slave mode using address, external pullups, 100kHz rate, and default pin setting
* default pin setting SCL/SDA:
* Wire: 19/18
* Wire1: 29/30 (3.1/3.2), 22/23 (LC), 37/38 (3.5/3.6)
* Wire2: 3/4 (3.5/3.6)
* Wire3: 57/56 (3.6)
* return: none
* parameters:
* address = 7bit slave address of device
---
**Wire.begin(mode, address1, ^(pins_enum | pinSCL,pinSDA), ^pullup, ^rate, ^opMode);**
**Wire.begin(mode, address1, ^address2, ^(pins_enum | pinSCL,pinSDA), ^pullup, ^rate, ^opMode);** - these various forms initialize I2C as a Master or Slave device. When two addresses are used it will initialize an address-range Slave. Addresses are ignored for Master mode (however Master-mode must specify at least one 0x00 address placeholder to also specify pins/pullup/rate/opMode options).
* return: none
* parameters:
* mode = I2C_MASTER, I2C_SLAVE
* address1 = 1st 7bit address for specifying Slave address (ignored for Master mode)
* ^address2 = 2nd 7bit address for specifying Slave address range (ignored for Master mode)
* ^pins - pin setting to use, refer to **Pins Section** above. Can be specified as either of the following:
* pins_enum
* pinSCL, pinSDA
* ^pullup = I2C_PULLUP_EXT, I2C_PULLUP_INT (default I2C_PULLUP_EXT)
* ^rate = frequency of I2C clock to use in Hz, eg. 400000 for 400kHz. Can also be specified as a I2C_RATE_xxxx enum (deprecated), refer to **Clocking Section** above. (default 400kHz)
* ^opMode = I2C_OP_MODE_ISR, I2C_OP_MODE_DMA, I2C_OP_MODE_IMM. Optional setting to specify operating mode (ignored for Slave mode, defaults ISR mode)
---
**Wire.setOpMode(opMode);** - this configures operating mode of the I2C as either Immediate, ISR, or DMA. By default Arduino-style begin() calls will initialize to ISR mode. This can only be called when the bus is idle (no changing mode in the middle of Tx/Rx). Note that Slave mode can only use ISR operation.
* return: 1=success, 0=fail (bus busy)
* parameters:
* opMode = I2C_OP_MODE_ISR, I2C_OP_MODE_DMA, I2C_OP_MODE_IMM
---
_**Wire.setClock(i2cFreq);**_ - reconfigures I2C frequency divider to get desired I2C freq.
* return: none
* parameters:
* i2cFreq = desired I2C frequency in Hz, eg. 400000 for 400kHz.
---
**Wire.getClock();** - return current I2C clock setting (may differ from set frequency due to divide ratio quantization)
* return: bus frequency in Hz
---
**Wire.setRate(busFreq, rate);** - reconfigures I2C frequency divider based on supplied bus freq and desired rate. Rate is specified as a direct frequency value in Hz. The function will accept I2C_RATE_xxxx enums, but that form is now deprecated.
* return: 1=success, 0=fail (function can no longer fail, it will auto limit at min/max bounds)
* parameters:
* busFreq = bus frequency, typically F_BUS unless reconfigured
* rate = frequency of I2C clock to use in Hz, eg. 400000 for 400kHz. Can also be specified as a I2C_RATE_xxxx enum (deprecated), refer to **Clocking Section** above
---
**Wire.pinConfigure( (pins_enum | pinSCL,pinSDA), ^pullup);** - reconfigures active I2C pins on-the-fly (only works when bus is idle). Inactive pins will switch to input mode.
* return: 1=success, 0=fail
* parameters:
* pins - pin setting to use, refer to **Pins Section** above. Can be specified as either of the following:
* pins_enum
* pinSCL, pinSDA
* ^pullup = I2C_PULLUP_EXT, I2C_PULLUP_INT (default I2C_PULLUP_EXT)
---
**Wire.setSCL(pin);** - change the SCL pin
**Wire.setSDA(pin);** - change the SDA pin
* return: none
* parameters:
* pin - pin setting to use, refer to **Pins Section** above.
---
**Wire.getSCL();** - get the current SCL pin
**Wire.getSDA();** - get the current SDA pin
* return: pin used
---
**Wire.setDefaultTimeout(timeout);** - sets the default timeout applied to all function calls which do not explicitly set a timeout. The default is initially zero (infinite wait). Note that timeouts do not currently apply to background transfers, **sendTransmission()** and **sendRequest()**.
* return: none
* parameters:
* timeout = timeout in microseconds
---
**Wire.resetBus();** - this is used to try and reset the bus in cases of a hung Slave device (typically a Slave which is stuck outputting a low on SDA due to a lost clock). It will generate up to 9 clocks pulses on SCL in an attempt to get the Slave to release the SDA line. Once SDA is released it will restore I2C functionality.
* return: none
---
_**Wire.beginTransmission(address);**_ - initialize Tx buffer for transmit to Slave at address
* return: none
* parameters:
* address = target 7bit slave address
---
**Wire.endTransmission(^i2c_stop, ^timeout);** - blocking routine, transmits Tx buffer to Slave. **i2c_stop** parameter can be optionally specified to indicate if command should end with a STOP (I2C_STOP) or not (I2C_NOSTOP). **timeout** parameter can also be optionally specified.
* return: 0=success, 1=data too long, 2=recv addr NACK, 3=recv data NACK, 4=other error
* parameters:
* ^i2c_stop = I2C_NOSTOP, I2C_STOP (default STOP)
* ^timeout = timeout in microseconds (default 0 = infinite wait)
---
**Wire.sendTransmission(^i2c_stop);** - non-blocking routine, starts transmit of Tx buffer to slave. **i2c_stop** parameter can be optionally specified to indicate if command should end with a STOP (I2C_STOP) or not (I2C_NOSTOP). Use **done()**, **finish()**, or **onTransmitDone()** callback to determine completion and **status()** to determine success/fail. Note that **sendTransmission()** does not currently support timeouts (aside from initial bus acquisition which does support it).
* return: none
* parameters:
* ^i2c_stop = I2C_NOSTOP, I2C_STOP (default STOP)
---
**Wire.requestFrom(address, length, ^i2c_stop, ^timeout);** - blocking routine with timeout, requests length bytes from Slave at address. Receive data will be placed in the Rx buffer. **i2c_stop** parameter can be optionally specified to indicate if command should end with a STOP (I2C_STOP) or not (I2C_NOSTOP). **timeout** parameter can also be optionally specified.
* return: #bytes received = success, 0=fail
* parameters:
* address = target 7bit slave address
* length = number of bytes requested
* ^i2c_stop = I2C_NOSTOP, I2C_STOP (default STOP)
* ^timeout = timeout in microseconds (default 0 = infinite wait)
---
**Wire.sendRequest(address, length, ^i2c_stop);** - non-blocking routine, starts request for length bytes from slave at address. Receive data will be placed in the Rx buffer. **i2c_stop** parameter can be optionally specified to indicate if command should end with a STOP (I2C_STOP) or not (I2C_NOSTOP). Use **done()**, **finish()** or **onReqFromDone()** callback to determine completion and **status()** to determine success/fail.
* return: none
* parameters:
* address = target 7bit slave address
* length = number of bytes requested
* ^i2c_stop = I2C_NOSTOP, I2C_STOP (default STOP)
---
**Wire.getError();** - returns "Wire" error code from a failed Tx/Rx command
* return: 0=success, 1=data too long, 2=recv addr NACK, 3=recv data NACK, 4=other error
---
**Wire.status();** - returns current status of I2C (enum return value)
* return:
* I2C_WAITING
* I2C_TIMEOUT
* I2C_ADDR_NAK
* I2C_DATA_NAK
* I2C_ARB_LOST
* I2C_BUF_OVF
* I2C_NOT_ACQ
* I2C_DMA_ERR
* I2C_SENDING
* I2C_SEND_ADDR
* I2C_RECEIVING
* I2C_SLAVE_TX
* I2C_SLAVE_RX
---
**Wire.done();** - returns simple complete/not-complete value to indicate I2C status
* return: 1=Tx/Rx complete (with or without errors), 0=still running
---
**Wire.finish(^timeout);** - blocking routine, loops until Tx/Rx is complete. **timeout** parameter can be optionally specified.
* return: 1=Tx/Rx complete (Tx or Rx completed, no error), 0=fail (NAK, timeout or Arb lost)
* parameters:
* ^timeout = timeout in microseconds (default 0 = infinite wait)
---
_**Wire.write(data);**_ - write data byte to Tx buffer
* return: #bytes written = success, 0=fail
* parameters:
* data = data byte
---
_**Wire.write(data_array, count);**_ - write count number of bytes from data array to Tx buffer
* return: #bytes written = success, 0=fail
* parameters:
* data_array = pointer to uint8_t (or char) array of data
* count = number of bytes to write
---
_**Wire.available();**_ - returns number of remaining available bytes in Rx buffer
* return: #bytes available
---
_**Wire.read();**_ - returns next data byte (signed int) from Rx buffer
* return: data, -1 if buffer empty
---
**Wire.read(data_array, count);** - read count number of bytes from Rx buffer to data array
* return: #bytes read
* parameters:
* data_array = pointer to uint8_t (or char) array of data
* count = number of bytes to read
---
_**Wire.peek();**_ - returns next data byte (signed int) from Rx buffer without removing it from Rx buffer
* return: data, -1 if buffer empty
---
**Wire.readByte();** - returns next data byte (uint8_t) from Rx buffer
* return: data, 0 if buffer empty
---
**Wire.peekByte();** - returns next data byte (uint8_t) from Rx buffer without removing it from Rx buffer
* return: data, 0 if buffer empty
---
_**Wire.flush();**_ - does nothing
---
**Wire.getRxAddr();** - returns target address of incoming I2C command. Used for Slaves operating over an address range.
* return: rxAddr of last received command
---
**Wire.onTransmitDone(function);** - used to set Master Tx complete callback. Function must be of the form `void function(void)`, refer to code examples
---
**Wire.onReqFromDone(function);** - used to set Master Rx complete callback. Function must be of the form `void function(void)`, refer to code examples
---
_**Wire.onReceive(function);**_ - used to set Slave Rx callback. Function must be of the form `void function(size_t len)`, refer to code examples
---
_**Wire.onRequest(function);**_ - used to set Slave Tx callback. Function must be of the form `void function(void)`, refer to code examples
---
**Wire.onError(function);** - used to set callback for bus Tx/Rx errors (Master-mode only). Function must be of the form `void function(void)`, refer to code examples
---
**Wire.getErrorCount(counter);** - Get error count from specified counter.
**Wire.zeroErrorCount(counter);** - Zero error count of specified counter.
* return: error count / none
* parameters:
* counter
* I2C_ERRCNT_RESET_BUS
* I2C_ERRCNT_TIMEOUT
* I2C_ERRCNT_ADDR_NAK
* I2C_ERRCNT_DATA_NAK
* I2C_ERRCNT_ARBL
* I2C_ERRCNT_NOT_ACQ
* I2C_ERRCNT_DMA_ERR
---
---
## **Compatible Libraries**
These are libraries which are known to be compatible with this I2C library. They may have been possibly modified to utilize enhanced functions (higher speed, timeouts, etc), or perhaps for general compatibility. Please contact their respective authors for questions regarding their usage.
* Arduino sketch for MPU-9250 9DoF with AHRS sensor fusion - https://github.com/kriswiner/MPU-9250
* LSM9DS0 9DOF sensor AHRS sketch - https://github.com/kriswiner/LSM9DS0
* Adafruit FRAM board - https://bitbucket.org/JezWeston/adafruit_fram_i2c_t3
* Adafruit BNO055 library - http://forums.adafruit.com/viewtopic.php?f=19&t=92153&sid=883bc291b6b08f4a51e018675e15dd69
* Micro Crystal Real Time Clock Module RV-3029-C2 - https://mega.nz/#!NRsGBbwT!ImKEaTJhMQPQYlgDswXHYw7203Hw25h0yY6zY7MStmc
* MPU-9250 - https://github.com/bolderflight/MPU9250
* BME280 - https://github.com/bolderflight/BME280
* AMS5812 - https://github.com/bolderflight/AMS5812
* AMS5915 - https://github.com/bolderflight/AMS5915
================================================
FILE: archive/README.md
================================================
# i2c_t3 Archive
This folder contains all older releases of the library.
================================================
FILE: examples/advanced_loopback/advanced_loopback.ino
================================================
// -------------------------------------------------------------------------------------------
// Loopback
// -------------------------------------------------------------------------------------------
//
// This creates a device using one I2C bus as a Master and one or more I2C buses as Slaves.
// When the buses are connected together in closed loopback, then it creates a closed test
// environment which allows Master/Slave development on a single device.
//
// Wire will act as the Master device, and Wire1/2/3 will act as the Slave device(s).
//
// Pulling pin12 low will initiate a WRITE then READ transfer between Master and Slave(s).
//
// This example code is in the public domain.
//
// -------------------------------------------------------------------------------------------
#include <i2c_t3.h>
// -------------------------------------------------------------------------------------------
// Defines - modify as needed for pin config
//
#define WIRE_PINS I2C_PINS_18_19
#if defined(__MKL26Z64__) // LC
#define WIRE1_PINS I2C_PINS_22_23
#endif
#if defined(__MK20DX256__) // 3.1-3.2
#define WIRE1_PINS I2C_PINS_29_30
#endif
#if defined(__MK64FX512__) || defined(__MK66FX1M0__) // 3.5/3.6
#define WIRE1_PINS I2C_PINS_37_38
#define WIRE2_PINS I2C_PINS_3_4
#endif
#if defined(__MK66FX1M0__) // 3.6
#define WIRE3_PINS I2C_PINS_56_57
#endif
// Function prototypes and variables
//
void rwSlave(uint8_t target);
void printWireStatus(void);
void printStatus(i2c_status status);
#define MEM_LEN 16
uint8_t mem[MEM_LEN];
#if I2C_BUS_NUM >= 2
void receiveEvent1(size_t len);
void requestEvent1(void);
void printWire1Status(void);
uint8_t mem1[MEM_LEN];
#define TARGET1 0x1A
#endif
#if I2C_BUS_NUM >= 3
void receiveEvent2(size_t len);
void requestEvent2(void);
void printWire2Status(void);
uint8_t mem2[MEM_LEN];
#define TARGET2 0x2B
#endif
#if I2C_BUS_NUM >= 4
void receiveEvent3(size_t len);
void requestEvent3(void);
void printWire3Status(void);
uint8_t mem3[MEM_LEN];
#define TARGET3 0x3C
#endif
void setup()
{
pinMode(LED_BUILTIN,OUTPUT); // LED
pinMode(12,INPUT_PULLUP); // Control for Test1
// Wire - Setup for Master mode, external pullup, 400kHz, 200ms default timeout
Wire.begin(I2C_MASTER, 0x00, WIRE_PINS, I2C_PULLUP_EXT, 400000);
Wire.setDefaultTimeout(200000);
memset(mem, 0, sizeof(mem));
#if I2C_BUS_NUM >= 2
// Wire1 - Setup for Slave mode, external pullup, 400kHz
Wire1.begin(I2C_SLAVE, TARGET1, WIRE1_PINS, I2C_PULLUP_EXT, 400000);
Wire1.onReceive(receiveEvent1);
Wire1.onRequest(requestEvent1);
memset(mem1, 0, sizeof(mem1));
#endif
#if I2C_BUS_NUM >= 3
// Wire2 - Setup for Slave mode, external pullup, 400kHz
Wire2.begin(I2C_SLAVE, TARGET2, WIRE2_PINS, I2C_PULLUP_EXT, 400000);
Wire2.onReceive(receiveEvent2);
Wire2.onRequest(requestEvent2);
memset(mem2, 0, sizeof(mem2));
#endif
#if I2C_BUS_NUM >= 4
// Wire3 - Setup for Slave mode, external pullup, 400kHz
Wire3.begin(I2C_SLAVE, TARGET3, WIRE3_PINS, I2C_PULLUP_EXT, 400000);
Wire3.onReceive(receiveEvent3);
Wire3.onRequest(requestEvent3);
memset(mem3, 0, sizeof(mem3));
#endif
Serial.begin(115200);
}
//
// Master Loop
//
void loop()
{
if(digitalRead(12) == LOW)
{
Serial.print("------------------------------------------------------------\n");
Serial.printf("Writing then reading a %d byte block from Slave device(s)\n", MEM_LEN);
Serial.print("------------------------------------------------------------\n");
digitalWrite(LED_BUILTIN,HIGH); // LED on
#if I2C_BUS_NUM >= 2
rwSlave(TARGET1);
#endif
#if I2C_BUS_NUM >= 3
rwSlave(TARGET2);
#endif
#if I2C_BUS_NUM >= 4
rwSlave(TARGET3);
#endif
delay(100); // delay to space out tests
digitalWrite(LED_BUILTIN,LOW); // LED off
}
}
//
// Write/Read to Slave
//
void rwSlave(uint8_t target)
{
uint8_t fail=0, count, data;
// Writing to Slave ------------------------------------------------------
Wire.beginTransmission(target); // slave addr
Serial.printf("I2C WRITE %d bytes to Slave 0x%0X : ", MEM_LEN, target);
for(count = 0; count < MEM_LEN; count++) // prepare data to send
{
mem[count] = random(0xFF); // set random data
Serial.printf("%02X ",mem[count]);
Wire.write(mem[count]);
}
fail = Wire.endTransmission(); // blocking write
Serial.print(" ");
printWireStatus(); // print I2C final status
// Reading from Slave ------------------------------------------------------
if(!fail)
{
Wire.requestFrom(target,(size_t)MEM_LEN); // blocking read
fail = Wire.getError();
Serial.printf("I2C READ %d bytes from Slave 0x%0X : ", Wire.available(), target);
for(count = 0; count < MEM_LEN && Wire.available(); count++) // verify block
{
data = Wire.readByte();
Serial.printf("%02X ", data);
if(mem[count] != data) fail++;
}
if(!fail)
Serial.print(" OK ");
else
Serial.print(" FAIL ");
printWireStatus(); // print I2C final status
}
}
//
// Slave ISR handlers
//
#if I2C_BUS_NUM >= 2
void receiveEvent1(size_t count) // Handle Wire1 Slave Rx Event (incoming I2C request/data)
{
Wire1.read(mem1, count); // copy Rx data to databuf
}
void requestEvent1(void) // Handle Wire1 Tx Event (outgoing I2C data)
{
Wire1.write(mem1, MEM_LEN); // fill Tx buffer (send full mem)
}
#endif
#if I2C_BUS_NUM >= 3
void receiveEvent2(size_t count) // Handle Wire2 Slave Rx Event (incoming I2C request/data)
{
Wire2.read(mem2, count); // copy Rx data to databuf
}
void requestEvent2(void) // Handle Wire2 Tx Event (outgoing I2C data)
{
Wire2.write(mem2, MEM_LEN); // fill Tx buffer (send full mem)
}
#endif
#if I2C_BUS_NUM >= 4
void receiveEvent3(size_t count) // Handle Wire3 Slave Rx Event (incoming I2C request/data)
{
Wire3.read(mem3, count); // copy Rx data to databuf
}
void requestEvent3(void) // Handle Wire3 Tx Event (outgoing I2C data)
{
Wire3.write(mem3, MEM_LEN); // fill Tx buffer (send full mem)
}
#endif
//
// print I2C status
//
void printWireStatus(void) { printStatus(Wire.status()); }
#if I2C_BUS_NUM >= 2
void printWire1Status(void) { printStatus(Wire1.status()); }
#endif
#if I2C_BUS_NUM >= 3
void printWire2Status(void) { printStatus(Wire2.status()); }
#endif
#if I2C_BUS_NUM >= 4
void printWire3Status(void) { printStatus(Wire3.status()); }
#endif
void printStatus(i2c_status status)
{
switch(status)
{
case I2C_WAITING: Serial.print("I2C waiting, no errors\n"); break;
case I2C_ADDR_NAK: Serial.print("Slave addr not acknowledged\n"); break;
case I2C_DATA_NAK: Serial.print("Slave data not acknowledged\n"); break;
case I2C_ARB_LOST: Serial.print("Bus Error: Arbitration Lost\n"); break;
case I2C_TIMEOUT: Serial.print("I2C timeout\n"); break;
case I2C_BUF_OVF: Serial.print("I2C buffer overflow\n"); break;
default: Serial.print("I2C busy\n"); break;
}
}
================================================
FILE: examples/advanced_master/advanced_master.ino
================================================
// -------------------------------------------------------------------------------------------
// I2C Advanced Master
// -------------------------------------------------------------------------------------------
//
// This creates an I2C master device with simple read/write commands and a small
// addressable memory. Note that this communication adds a protocol layer on top of
// normal I2C read/write procedures. As such, it is meant to pair with the advanced_slave
// sketch. The read/write commands are described below.
//
// This code assumes the slave config has 256 byte memory and I2C addr is 0x44.
//
// Tests are as follows:
// Pull pin12 input low to send/receive 256 bytes to/from slave in 32 byte blocks.
// Pull pin11 input low to send/receive 256 bytes to/from slave in single block.
// Pull pin10 input low to send/receive 256 bytes to/from slave in single block, using
// non-blocking commands.
// Pull pin9 input low to send/receive 256 bytes to/from slave in single block, using
// non-blocking commands in DMA mode.
// Pull pin8 input low to run I2C rate sweep test. This sweeps the I2C rates on both master
// and slave and times the duration of a 256 byte transfer at each rate.
//
// For basic I2C communication only, refer to basic_master and basic_slave example sketches.
//
// This example code is in the public domain.
//
// -------------------------------------------------------------------------------------------
// Slave protocol is as follows:
// -------------------------------------------------------------------------------------------
// WRITE - The I2C Master can write to the device by transmitting the WRITE command,
// a memory address to store to, and a sequence of data to store.
// The command sequence is:
//
// START|I2CADDR+W|WRITE|MEMADDR|DATA0|DATA1|DATA2|...|STOP
//
// where START = I2C START sequence
// I2CADDR+W = I2C Slave address + I2C write flag
// WRITE = WRITE command
// MEMADDR = memory address to store data to
// DATAx = data byte to store, multiple bytes are stored to increasing address
// STOP = I2C STOP sequence
// -------------------------------------------------------------------------------------------
// READ - The I2C Master can read data from the device by transmitting the READ command,
// a memory address to read from, and then issuing a STOP/START or Repeated-START,
// followed by reading the data. The command sequence is:
//
// START|I2CADDR+W|READ|MEMADDR|REPSTART|I2CADDR+R|DATA0|DATA1|DATA2|...|STOP
//
// where START = I2C START sequence
// I2CADDR+W = I2C Slave address + I2C write flag
// READ = READ command
// MEMADDR = memory address to read data from
// REPSTART = I2C Repeated-START sequence (or STOP/START if single Master)
// I2CADDR+R = I2C Slave address + I2C read flag
// DATAx = data byte read by Master, multiple bytes are read from increasing address
// STOP = I2C STOP sequence
// -------------------------------------------------------------------------------------------
// SETRATE - The I2C Master can adjust the Slave configured I2C rate with this command
// The command sequence is:
//
// START|I2CADDR+W|SETRATE|RATE0|RATE1|RATE2|RATE3|STOP
//
// where START = I2C START sequence
// I2CADDR+W = I2C Slave address + I2C write flag
// SETRATE = SETRATE command
// RATE0-3 = I2C frequency (uint32_t) LSB-to-MSB format
// -------------------------------------------------------------------------------------------
#include <i2c_t3.h>
// Command definitions
#define WRITE 0x10
#define READ 0x20
#define SETRATE 0x30
// Function prototypes
void print_i2c_setup(void);
void print_i2c_status(void);
void test_rate(uint8_t target, uint32_t rate);
// Memory
#define MEM_LEN 256
uint8_t databuf[MEM_LEN];
void setup()
{
pinMode(LED_BUILTIN,OUTPUT); // LED
digitalWrite(LED_BUILTIN,LOW); // LED off
pinMode(12,INPUT_PULLUP); // Control for Test1
pinMode(11,INPUT_PULLUP); // Control for Test2
pinMode(10,INPUT_PULLUP); // Control for Test3
pinMode(9,INPUT_PULLUP); // Control for Test4
pinMode(8,INPUT_PULLUP); // Control for Test5
Serial.begin(115200);
// Setup for Master mode, pins 18/19, external pullups, 400kHz
Wire.begin(I2C_MASTER, 0x00, I2C_PINS_18_19, I2C_PULLUP_EXT, 400000);
Wire.setDefaultTimeout(250000); // 250ms default timeout
}
void loop()
{
size_t addr, len;
uint8_t target = 0x44; // slave addr
uint32_t count;
//
// A sequence of different read/write techniques.
// Pull respective control pin low to initiate sequence.
//
// All tests will first write values to the slave, then read back the values.
// The readback values should match.
//
// The LED is turned on during I2C operations. If it gets stuck on then the
// ISR likely had a problem. This can happen with excessive baud rate.
//
// Various forms of the Wire calls (blocking/non-blocking/STOP/NOSTOP) are
// used in the different tests.
//
if(digitalRead(12) == LOW)
{
digitalWrite(LED_BUILTIN,HIGH); // LED on
Serial.print("---------------------------------------------------------\n");
Serial.print("Test1 : Using blocking commands:\n");
Serial.print(" 1) WRITE memory in 32 byte blocks\n");
Serial.print(" 2) READ back memory in 32 byte blocks\n");
Serial.print("---------------------------------------------------------\n");
// Writing to Slave --------------------------------------------------------
for(addr = 0; addr < 256; addr += 32) // sweep addr in 32byte blocks
{
for(len = 0; len < 32; len++) // prepare data to send
databuf[len] = (addr+len)^0xFF; // set data (equal to bit inverse of memory address)
Serial.printf("I2C WRITE 32 bytes to Slave 0x%0X at MemAddr %d\n", target, addr);
Serial.print("Writing: ");
for(len = 0; len < 32; len++) { Serial.printf("%d ",databuf[len]); }
Serial.print("\n");
Wire.beginTransmission(target); // slave addr
Wire.write(WRITE); // WRITE command
Wire.write(addr); // memory address
Wire.write(databuf, 32); // write 32 byte block
Wire.endTransmission(); // blocking write (when not specified I2C_STOP is implicit)
print_i2c_status(); // print I2C final status
}
// Reading from Slave ------------------------------------------------------
for(addr = 0; addr < 256; addr += 32) // sweep addr in 32byte blocks
{
Wire.beginTransmission(target); // slave addr
Wire.write(READ); // READ command
Wire.write(addr); // memory address
Wire.endTransmission(I2C_NOSTOP); // blocking write (NOSTOP triggers RepSTART on next I2C command)
Wire.requestFrom(target,32,I2C_STOP);// blocking read (request 32 bytes)
Serial.printf("I2C READ 32 bytes from Slave 0x%0X at MemAddr %d\n", target, addr);
Serial.print("Received: "); // print received bytes
while(Wire.available()) { Serial.printf("%d ", Wire.readByte()); }
Serial.print("\n");
print_i2c_status(); // print I2C final status
}
digitalWrite(LED_BUILTIN,LOW); // LED off
delay(500); // delay to space out tests
}
if(digitalRead(11) == LOW)
{
digitalWrite(LED_BUILTIN,HIGH); // LED on
Serial.print("---------------------------------------------------------\n");
Serial.print("Test2 : Using blocking commands:\n");
Serial.print(" 1) WRITE entire memory in a single 256 byte block\n");
Serial.print(" 2) READ back entire memory in a single 256 byte block\n");
Serial.print("---------------------------------------------------------\n");
// Writing to Slave --------------------------------------------------------
addr = 0;
for(len = 0; len < 256; len++) // prepare data to send
databuf[len] = (addr+len)^0xFF; // set data (equal to bit inverse of memory address)
Serial.printf("I2C WRITE 256 bytes to Slave 0x%0X at MemAddr %d\n", target, addr);
Serial.print("Writing: ");
for(len = 0; len < 256; len++) { Serial.printf("%d ",databuf[len]); }
Serial.print("\n");
Wire.beginTransmission(target); // slave addr
Wire.write(WRITE); // WRITE command
Wire.write(addr); // memory address
Wire.write(databuf, 256); // write 256 byte block
Wire.endTransmission(I2C_STOP); // blocking write (using explicit I2C_STOP)
print_i2c_status(); // print I2C final status
// Reading from Slave ------------------------------------------------------
Wire.beginTransmission(target); // slave addr
Wire.write(READ); // READ command
Wire.write(addr); // memory address
Wire.endTransmission(I2C_NOSTOP); // blocking write (NOSTOP triggers RepSTART on next I2C command)
Wire.requestFrom(target,256,I2C_STOP); // blocking read (request 256 bytes)
Serial.printf("I2C READ %d bytes from Slave 0x%0X at MemAddr %d\n", Wire.available(), target, addr);
Serial.print("Received: "); // print received bytes
while(Wire.available()) { Serial.printf("%d ", Wire.readByte()); }
Serial.print("\n");
print_i2c_status(); // print I2C final status
Serial.printf("Rate (Hz): %d\n", Wire.i2c->currentRate);
digitalWrite(LED_BUILTIN,LOW); // LED off
delay(500); // delay to space out tests
}
if(digitalRead(10) == LOW)
{
digitalWrite(LED_BUILTIN,HIGH); // LED on
Serial.print("---------------------------------------------------------\n");
Serial.print("Test3 : Using ISR NON-blocking commands:\n");
Serial.print(" 1) WRITE a 256 byte block to Slave. While block is\n");
Serial.print(" transferring, perform other commands.\n");
Serial.print(" 2) READ back the 256 byte block from Slave. While\n");
Serial.print(" block is transferring, perform other commands.\n");
Serial.print("---------------------------------------------------------\n");
// Set operating mode to ISR
Wire.setOpMode(I2C_OP_MODE_ISR);
// Writing to Slave --------------------------------------------------------
addr = 0;
for(len = 0; len < 256; len++) // prepare data to send
databuf[len] = (addr+len)^0xFF; // set data (equal to bit inverse of memory address)
Serial.printf("I2C WRITE 256 bytes to Slave 0x%0X at MemAddr %d\n", target, addr);
Serial.print("Writing: ");
for(len = 0; len < 256; len++) { Serial.printf("%d ",databuf[len]); }
Serial.print("\n");
Wire.beginTransmission(target); // slave addr
Wire.write(WRITE); // WRITE command
Wire.write(addr); // memory address
Wire.write(databuf, 256); // write 256 byte block
Wire.sendTransmission(); // NON-blocking write (when not specified I2C_STOP is implicit)
Serial.print("...write sent, counting while waiting for Wire.done()...\n");
count = 1;
while(!Wire.done()) count++; // Since write is non-blocking, do some counting while waiting
Serial.printf("Counted to: %d\n", count++);
print_i2c_status(); // print I2C final status
// Reading from Slave ------------------------------------------------------
Wire.beginTransmission(target); // slave addr
Wire.write(READ); // READ command
Wire.write(addr); // memory address
Wire.endTransmission(I2C_NOSTOP); // blocking write (NOSTOP triggers RepSTART on next I2C command)
Wire.sendRequest(target,256,I2C_STOP); // NON-blocking read (request 256 bytes)
// Since request is non-blocking, do some other things.
Serial.print("...request sent, doing one thing then waiting for Wire.finish()...\n");
// After doing something, use finish() to wait until I2C done
Wire.finish();
Serial.printf("I2C READ %d bytes from Slave 0x%0X at MemAddr %d\n", Wire.available(), target, addr);
Serial.print("Received: "); // print received bytes
while(Wire.available()) { Serial.printf("%d ", Wire.readByte()); }
Serial.print("\n");
print_i2c_status(); // print I2C final status
digitalWrite(LED_BUILTIN,LOW); // LED off
delay(500); // delay to space out tests
}
if(digitalRead(9) == LOW)
{
digitalWrite(LED_BUILTIN,HIGH); // LED on
Serial.print("---------------------------------------------------------\n");
Serial.print("Test4 : Using DMA NON-blocking commands:\n");
Serial.print(" 1) WRITE a 256 byte block to Slave. While block is\n");
Serial.print(" transferring, perform other commands.\n");
Serial.print(" 2) READ back the 256 byte block from Slave. While\n");
Serial.print(" block is transferring, perform other commands.\n");
Serial.print("---------------------------------------------------------\n");
// Set operating mode to DMA
Serial.print("Trying to set DMA mode : ");
Wire.setOpMode(I2C_OP_MODE_DMA);
if(Wire.i2c->opMode == I2C_OP_MODE_DMA)
Serial.printf("OK (Channel %d)\n",Wire.i2c->DMA->channel);
else
Serial.print("Failed, using ISR\n");
// Writing to Slave --------------------------------------------------------
addr = 0;
for(len = 0; len < 256; len++) // prepare data to send
databuf[len] = (addr+len)^0xFF; // set data (equal to bit inverse of memory address)
Serial.printf("I2C WRITE 256 bytes to Slave 0x%0X at MemAddr %d\n", target, addr);
Serial.print("Writing: ");
for(len = 0; len < 256; len++) { Serial.printf("%d ",databuf[len]); }
Serial.print("\n");
Wire.beginTransmission(target); // slave addr
Wire.write(WRITE); // WRITE command
Wire.write(addr); // memory address
Wire.write(databuf, 256); // write 256 byte block
Wire.sendTransmission(); // NON-blocking write (when not specified I2C_STOP is implicit)
Serial.print("...write sent, counting while waiting for Wire.done()...\n");
count = 1;
while(!Wire.done()) count++; // Since write is non-blocking, do some counting while waiting
Serial.printf("Counted to: %d\n", count++);
print_i2c_status(); // print I2C final status
// Reading from Slave ------------------------------------------------------
Wire.beginTransmission(target); // slave addr
Wire.write(READ); // READ command
Wire.write(addr); // memory address
Wire.endTransmission(I2C_NOSTOP); // blocking write (NOSTOP triggers RepSTART on next I2C command)
Wire.sendRequest(target,256,I2C_STOP); // NON-blocking read (request 256 bytes)
// Since request is non-blocking, do some other things.
Serial.print("...request sent, doing one thing then waiting for Wire.finish()...\n");
// After doing something, use finish() to wait until I2C done
Wire.finish();
Serial.printf("I2C READ %d bytes from Slave 0x%0X at MemAddr %d\n", Wire.available(), target, addr);
Serial.print("Received: "); // print received bytes
while(Wire.available()) { Serial.printf("%d ", Wire.readByte()); }
Serial.print("\n");
print_i2c_status(); // print I2C final status
digitalWrite(LED_BUILTIN,LOW); // LED off
delay(500); // delay to space out tests
}
if(digitalRead(8) == LOW)
{
uint8_t fail=0;
digitalWrite(LED_BUILTIN,HIGH); // LED on
Serial.print("---------------------------------------------------------\n");
Serial.print("Test5 : Rate adjustment tests. This sweeps the I2C rates\n");
Serial.print(" on both Master and Slave and times the duration \n");
Serial.print(" of a 256 byte transfer at each rate.\n");
Serial.print("---------------------------------------------------------\n");
for(uint8_t opMode = I2C_OP_MODE_IMM; opMode <= I2C_OP_MODE_DMA; opMode++)
{
Wire.setOpMode((i2c_op_mode)opMode); // set op mode
test_rate(target, 10000, fail);
test_rate(target, 100000, fail);
test_rate(target, 200000, fail);
test_rate(target, 300000, fail);
test_rate(target, 400000, fail);
test_rate(target, 600000, fail);
test_rate(target, 800000, fail);
test_rate(target, 1000000, fail);
test_rate(target, 1200000, fail);
test_rate(target, 1500000, fail);
test_rate(target, 1800000, fail);
test_rate(target, 2000000, fail);
test_rate(target, 2400000, fail);
test_rate(target, 2800000, fail);
test_rate(target, 3000000, fail);
test_rate(target, 4000000, fail);
test_rate(target, 5000000, fail);
test_rate(target, 6000000, fail);
// Restore normal settings
// Change Slave rate
Wire.beginTransmission(target); // slave addr
Wire.write(SETRATE); // SETRATE command
Wire.write((uint8_t)400000&0xFF); // rate LSB
Wire.write((uint8_t)(400000>>8)&0xFF);
Wire.write((uint8_t)(400000>>16)&0xFF);
Wire.write((uint8_t)(400000>>24)&0xFF); // rate MSB
Wire.endTransmission(); // blocking write
// Change Master rate
Wire.setClock(400000);
fail = 0; // reset flag
}
Wire.setOpMode(I2C_OP_MODE_ISR); // restore default ISR mode
print_i2c_status(); // print I2C final status
// Restore normal settings (400kHz)
// Change Slave rate
Wire.beginTransmission(target); // slave addr
Wire.write(SETRATE); // SETRATE command
Wire.write((uint8_t)400000&0xFF); // rate LSB
Wire.write((uint8_t)(400000>>8)&0xFF);
Wire.write((uint8_t)(400000>>16)&0xFF);
Wire.write((uint8_t)(400000>>24)&0xFF); // rate MSB
Wire.endTransmission(); // blocking write
// Change Master rate
Wire.setClock(400000);
digitalWrite(LED_BUILTIN,LOW); // LED off
delay(500); // delay to space out tests
}
}
//
// print current setup
//
void print_i2c_setup()
{
Serial.print("Mode:");
switch(Wire.i2c->opMode)
{
case I2C_OP_MODE_IMM: Serial.print("IMM "); break;
case I2C_OP_MODE_ISR: Serial.print("ISR "); break;
case I2C_OP_MODE_DMA: Serial.printf("DMA[%d] ",Wire.i2c->DMA->channel); break;
}
Serial.printf("Pins: %d/%d ", Wire.i2c->currentSCL, Wire.i2c->currentSDA);
}
//
// print I2C status
//
void print_i2c_status(void)
{
switch(Wire.status())
{
case I2C_WAITING: Serial.print("I2C waiting, no errors\n"); break;
case I2C_ADDR_NAK: Serial.print("Slave addr not acknowledged\n"); break;
case I2C_DATA_NAK: Serial.print("Slave data not acknowledged\n"); break;
case I2C_ARB_LOST: Serial.print("Bus Error: Arbitration Lost\n"); break;
case I2C_TIMEOUT: Serial.print("I2C timeout\n"); break;
case I2C_BUF_OVF: Serial.print("I2C buffer overflow\n"); break;
default: Serial.print("I2C busy\n"); break;
}
}
//
// print I2C rate
//
void print_rate(uint32_t rate)
{
Serial.printf("%d Hz ", rate);
}
//
// test rate
//
void test_rate(uint8_t target, uint32_t rate, uint8_t& fail)
{
uint32_t deltatime=0;
size_t len;
if(!fail)
{
for(len = 0; len < 256; len++) // prepare data to send
databuf[len] = len; // set data (equal to addr)
// Change Slave rate
Wire.beginTransmission(target); // slave addr
Wire.write(SETRATE); // SETRATE command
Wire.write((uint8_t)rate&0xFF); // rate LSB
Wire.write((uint8_t)(rate>>8)&0xFF);
Wire.write((uint8_t)(rate>>16)&0xFF);
Wire.write((uint8_t)(rate>>24)&0xFF); // rate MSB
Wire.endTransmission(); // blocking write
fail = Wire.getError();
if(!fail)
{
// Change Master rate
Wire.setClock(rate);
// Setup write buffer
Wire.beginTransmission(target); // slave addr
Wire.write(WRITE); // WRITE command
Wire.write(0); // memory address
Wire.write(databuf, 256); // write 256 byte block
// Write to Slave
elapsedMicros deltaT;
Wire.endTransmission(); // blocking write
deltatime = deltaT;
fail = Wire.getError();
if(!fail)
{
Wire.beginTransmission(target); // slave addr
Wire.write(READ); // READ command
Wire.write(0); // memory address
Wire.endTransmission(I2C_NOSTOP); // blocking write (NOSTOP triggers RepSTART on next I2C command)
Wire.requestFrom(target,256,I2C_STOP);// blocking read
fail = Wire.getError();
if(!fail)
{
for(len = 0; len < 256; len++) // verify block
if(databuf[len] != Wire.readByte()) { fail=1; break; }
}
}
}
print_i2c_setup();
if(!fail)
{
// Print result
Serial.print("256 byte transfer at ");
print_rate(rate);
Serial.printf(" (Actual Rate (Hz): %d) : %d us : ", Wire.getClock(), deltatime);
print_i2c_status();
}
else
{
Serial.printf("Transfer fail : %d us : ",deltatime);
print_i2c_status();
}
}
}
================================================
FILE: examples/advanced_scanner/advanced_scanner.ino
================================================
// -------------------------------------------------------------------------------------------
// I2C Advanced Bus Scanner
// -------------------------------------------------------------------------------------------
//
// This creates an I2C master device which will scan the address space and report all
// devices which ACK. It does not attempt to transfer data, it only reports which devices
// ACK their address.
//
// This version will sweep all existing I2C buses (eg. Wire, Wire1, Wire2, Wire3).
//
// Pull the control pin low to initiate the scan. Result will output to Serial.
//
// This example code is in the public domain.
// -------------------------------------------------------------------------------------------
#include <i2c_t3.h>
// -------------------------------------------------------------------------------------------
// Defines - modify as needed for sweep range and bus pin config
//
#define TARGET_START 0x01
#define TARGET_END 0x7F
#define WIRE_PINS I2C_PINS_18_19
#if defined(__MKL26Z64__) // LC
#define WIRE1_PINS I2C_PINS_22_23
#endif
#if defined(__MK20DX256__) // 3.1-3.2
#define WIRE1_PINS I2C_PINS_29_30
#endif
#if defined(__MK64FX512__) || defined(__MK66FX1M0__) // 3.5/3.6
#define WIRE1_PINS I2C_PINS_37_38
#define WIRE2_PINS I2C_PINS_3_4
#endif
#if defined(__MK66FX1M0__) // 3.6
#define WIRE3_PINS I2C_PINS_56_57
#endif
// -------------------------------------------------------------------------------------------
// Function prototypes
void scan_bus(i2c_t3& Wire, uint8_t all);
void print_bus_status(i2c_t3& Wire);
void print_scan_status(struct i2cStruct* i2c, uint8_t target, uint8_t& found, uint8_t all);
// -------------------------------------------------------------------------------------------
void setup()
{
pinMode(LED_BUILTIN,OUTPUT); // LED
pinMode(12,INPUT_PULLUP); // pull pin 12 low to show ACK only results
pinMode(11,INPUT_PULLUP); // pull pin 11 low for a more verbose result (shows both ACK and NACK)
// Setup for Master mode, all buses, external pullups, 400kHz, 10ms default timeout
//
Wire.begin(I2C_MASTER, 0x00, WIRE_PINS, I2C_PULLUP_EXT, 400000);
Wire.setDefaultTimeout(10000); // 10ms
#if I2C_BUS_NUM >= 2
Wire1.begin(I2C_MASTER, 0x00, WIRE1_PINS, I2C_PULLUP_EXT, 400000);
Wire1.setDefaultTimeout(10000); // 10ms
#endif
#if I2C_BUS_NUM >= 3
Wire2.begin(I2C_MASTER, 0x00, WIRE2_PINS, I2C_PULLUP_EXT, 400000);
Wire2.setDefaultTimeout(10000); // 10ms
#endif
#if I2C_BUS_NUM >= 4
Wire3.begin(I2C_MASTER, 0x00, WIRE3_PINS, I2C_PULLUP_EXT, 400000);
Wire3.setDefaultTimeout(10000); // 10ms
#endif
Serial.begin(115200);
}
// -------------------------------------------------------------------------------------------
void loop()
{
// Scan I2C addresses
//
if(digitalRead(12) == LOW || digitalRead(11) == LOW)
{
uint8_t all = (digitalRead(11) == LOW);
Serial.print("---------------------------------------------------\n");
Serial.print("Bus Status Summary\n");
Serial.print("==================\n");
Serial.print(" Bus Mode SCL SDA Pullup Clock\n");
print_bus_status(Wire);
#if I2C_BUS_NUM >= 2
print_bus_status(Wire1);
#endif
#if I2C_BUS_NUM >= 3
print_bus_status(Wire2);
#endif
#if I2C_BUS_NUM >= 4
print_bus_status(Wire3);
#endif
scan_bus(Wire, all);
#if I2C_BUS_NUM >= 2
scan_bus(Wire1, all);
#endif
#if I2C_BUS_NUM >= 3
scan_bus(Wire2, all);
#endif
#if I2C_BUS_NUM >= 4
scan_bus(Wire3, all);
#endif
Serial.print("---------------------------------------------------\n\n\n");
delay(500); // delay to space out tests
}
}
// -------------------------------------------------------------------------------------------
// scan bus
//
void scan_bus(i2c_t3& Wire, uint8_t all)
{
uint8_t target, found = 0;
Serial.print("---------------------------------------------------\n");
if(Wire.bus == 0)
Serial.print("Starting scan: Wire\n");
else
Serial.printf("Starting scan: Wire%d\n",Wire.bus);
digitalWrite(LED_BUILTIN,HIGH); // LED on
for(target = TARGET_START; target <= TARGET_END; target++) // sweep addr, skip general call
{
Wire.beginTransmission(target); // slave addr
Wire.endTransmission(); // no data, just addr
print_scan_status(Wire.i2c, target, found, all);
}
digitalWrite(LED_BUILTIN,LOW); // LED off
if(!found) Serial.print("No devices found.\n");
}
// -------------------------------------------------------------------------------------------
// print bus status
//
void print_bus_status(i2c_t3& Wire)
{
struct i2cStruct* i2c = Wire.i2c;
if(Wire.bus == 0)
Serial.print("Wire ");
else
Serial.printf("Wire%d ",Wire.bus);
switch(i2c->currentMode)
{
case I2C_MASTER: Serial.print("MASTER "); break;
case I2C_SLAVE: Serial.print(" SLAVE "); break;
}
Serial.printf(" %2d %2d ", Wire.i2c->currentSCL, Wire.i2c->currentSDA);
switch(i2c->currentPullup)
{
case I2C_PULLUP_EXT: Serial.print("External "); break;
case I2C_PULLUP_INT: Serial.print("Internal "); break;
}
Serial.printf("%d Hz\n",i2c->currentRate);
}
// -------------------------------------------------------------------------------------------
// print scan status
//
void print_scan_status(struct i2cStruct* i2c, uint8_t target, uint8_t& found, uint8_t all)
{
switch(i2c->currentStatus)
{
case I2C_WAITING: Serial.printf("Addr: 0x%02X ACK\n",target); found=1; break;
case I2C_ADDR_NAK: if(all) { Serial.printf("Addr: 0x%02X\n",target); } break;
case I2C_TIMEOUT: if(all) { Serial.printf("Addr: 0x%02X Timeout\n",target); } break;
default: break;
}
}
================================================
FILE: examples/advanced_slave/advanced_slave.ino
================================================
// -------------------------------------------------------------------------------------------
// I2C Advanced Slave
// -------------------------------------------------------------------------------------------
//
// This creates an I2C slave device with simple read/write commands and a small
// addressable memory. Note that this communication adds a protocol layer on top of
// normal I2C read/write procedures. As such, it is meant to pair with the advanced_master
// sketch. The read/write commands are described below.
//
// For basic I2C communication only, refer to basic_master and basic_slave example sketches.
//
// This example code is in the public domain.
//
// -------------------------------------------------------------------------------------------
// WRITE - The I2C Master can write to the device by transmitting the WRITE command,
// a memory address to store to, and a sequence of data to store.
// The command sequence is:
//
// START|I2CADDR+W|WRITE|MEMADDR|DATA0|DATA1|DATA2|...|STOP
//
// where START = I2C START sequence
// I2CADDR+W = I2C Slave address + I2C write flag
// WRITE = WRITE command
// MEMADDR = memory address to store data to
// DATAx = data byte to store, multiple bytes are stored to increasing address
// STOP = I2C STOP sequence
// -------------------------------------------------------------------------------------------
// READ - The I2C Master can read data from the device by transmitting the READ command,
// a memory address to read from, and then issuing a STOP/START or Repeated-START,
// followed by reading the data. The command sequence is:
//
// START|I2CADDR+W|READ|MEMADDR|REPSTART|I2CADDR+R|DATA0|DATA1|DATA2|...|STOP
//
// where START = I2C START sequence
// I2CADDR+W = I2C Slave address + I2C write flag
// READ = READ command
// MEMADDR = memory address to read data from
// REPSTART = I2C Repeated-START sequence (or STOP/START if single Master)
// I2CADDR+R = I2C Slave address + I2C read flag
// DATAx = data byte read by Master, multiple bytes are read from increasing address
// STOP = I2C STOP sequence
// -------------------------------------------------------------------------------------------
// SETRATE - The I2C Master can adjust the Slave configured I2C rate with this command
// The command sequence is:
//
// START|I2CADDR+W|SETRATE|RATE0|RATE1|RATE2|RATE3|STOP
//
// where START = I2C START sequence
// I2CADDR+W = I2C Slave address + I2C write flag
// SETRATE = SETRATE command
// RATE0-3 = I2C frequency (uint32_t) LSB-to-MSB format
// -------------------------------------------------------------------------------------------
#include <i2c_t3.h>
// Command definitions
#define WRITE 0x10
#define READ 0x20
#define SETRATE 0x30
// Function prototypes
void receiveEvent(size_t count);
void requestEvent(void);
// Memory
#define MEM_LEN 256
uint8_t mem[MEM_LEN];
volatile uint8_t cmd;
volatile size_t addr;
volatile uint32_t rate;
//
// Setup
//
void setup()
{
pinMode(LED_BUILTIN,OUTPUT); // LED
// Setup for Slave mode, address 0x44, pins 18/19, external pullups, 400kHz
Wire.begin(I2C_SLAVE, 0x44, I2C_PINS_18_19, I2C_PULLUP_EXT, 400000);
// init vars
cmd = 0;
addr = 0;
memset(mem, 0, sizeof(mem));
rate = 400000;
// register events
Wire.onReceive(receiveEvent);
Wire.onRequest(requestEvent);
Serial.begin(115200);
}
void loop()
{
digitalWrite(LED_BUILTIN,HIGH); // double pulse LED while waiting for I2C requests
delay(10); // if the LED stops the slave is probably stuck in an ISR
digitalWrite(LED_BUILTIN,LOW);
delay(100);
digitalWrite(LED_BUILTIN,HIGH);
delay(10);
digitalWrite(LED_BUILTIN,LOW);
delay(880);
}
//
// handle Rx Event (incoming I2C request/data)
//
void receiveEvent(size_t count)
{
if(count)
{
// grab command
cmd = Wire.readByte();
switch(cmd)
{
case WRITE:
addr = Wire.readByte(); // grab addr
Wire.read(&mem[addr], count-2); // copy Rx data to databuf
break;
case READ:
addr = Wire.readByte(); // grab addr
break;
case SETRATE:
if(Wire.available() >= 4)
{
rate = Wire.readByte(); // grab rate
rate |= Wire.readByte() << 8;
rate |= Wire.readByte() << 16;
rate |= Wire.readByte() << 24;
Wire.setClock(rate); // set rate
}
break;
}
}
}
//
// handle Tx Event (outgoing I2C data)
//
void requestEvent(void)
{
switch(cmd)
{
case READ:
Wire.write(&mem[addr], MEM_LEN-addr); // fill Tx buffer (from addr location to end of mem)
break;
}
}
================================================
FILE: examples/basic_echo/basic_echo.ino
================================================
// -------------------------------------------------------------------------------------------
// Basic Echo
// -------------------------------------------------------------------------------------------
//
// This creates a simple I2C Slave device which will read whatever data is sent to it
// on Wire1 and output that same data on Wire. It will retain the data in memory and will
// send it back to a Master device if requested.
//
// This code demonstrates non-blocking nested operation - calling Wire in a non-blocking way
// inside of Wire1 receive ISR.
//
// Wire1 bus is intended to pair with a Master device running the basic_master sketch.
// Wire bus is intended to pair with a Slave device running the basic_slave sketch.
//
// This code is setup for a Teensy 3.5/3.6 device.
//
// This example code is in the public domain.
//
// -------------------------------------------------------------------------------------------
#include <i2c_t3.h>
// Function prototypes
void receiveEvent(size_t count);
void requestEvent(void);
// Memory
#define MEM_LEN 256
uint8_t databuf[MEM_LEN];
volatile uint8_t received;
//
// Setup
//
void setup()
{
pinMode(LED_BUILTIN,OUTPUT); // LED
// Setup for Master mode, pins 18/19, external pullups, 400kHz, 200ms default timeout
Wire.begin(I2C_MASTER, 0x00, I2C_PINS_18_19, I2C_PULLUP_EXT, 400000);
Wire.setDefaultTimeout(200000); // 200ms
// Setup for Slave mode, address 0x66, pins 37/38, external pullups, 400kHz
Wire1.begin(I2C_SLAVE, 0x66, I2C_PINS_37_38, I2C_PULLUP_EXT, 400000); // 3.5/3.6
// Data init
received = 0;
memset(databuf, 0, sizeof(databuf));
// register events
Wire1.onReceive(receiveEvent);
Wire1.onRequest(requestEvent);
Serial.begin(115200);
}
void loop()
{
// print received data - this is done in main loop to keep time spent in I2C ISR to minimum
if(received)
{
digitalWrite(LED_BUILTIN,HIGH);
Serial.printf("Echoing data received: '%s'\n", databuf);
received = 0;
digitalWrite(LED_BUILTIN,LOW);
}
}
//
// handle Rx Event (incoming I2C data)
//
void receiveEvent(size_t count)
{
digitalWrite(LED_BUILTIN,HIGH); // LED on
Wire1.read(databuf, count); // copy Rx data to databuf
Wire.finish(); // finish any prev non-blocking Tx
Wire.beginTransmission(0x66); // init for Tx send
Wire.write(databuf, count); // send to Tx buffer
Wire.sendTransmission(); // Send Tx data to Slave (non-blocking)
received = count; // set received flag to count, this triggers print in main loop
digitalWrite(LED_BUILTIN,LOW); // LED off
}
//
// handle Tx Event (outgoing I2C data)
//
void requestEvent(void)
{
Wire1.write(databuf, MEM_LEN); // fill Tx buffer (send full mem)
}
================================================
FILE: examples/basic_interrupt/basic_interrupt.ino
================================================
// -------------------------------------------------------------------------------------------
// Interrupt
// -------------------------------------------------------------------------------------------
//
// This creates an I2C master device which will issue I2C commands from inside a periodic
// interrupt (eg. similar to reading a sensor at regular time intervals). For this test the
// Slave device will be assumed to be that given in the basic_slave sketch.
//
// The test will start when the Serial monitor opens.
//
// This example code is in the public domain.
//
// -------------------------------------------------------------------------------------------
#include <i2c_t3.h>
// Function prototypes
void rwSlave(void);
// Timer
IntervalTimer slaveTimer;
// Memory
#define MEM_LEN 32
char databuf[MEM_LEN];
size_t count=0;
uint8_t target=0x66;
void setup()
{
pinMode(LED_BUILTIN,OUTPUT); // LED
// Setup for Master mode, pins 18/19, external pullups, 400kHz, 10ms default timeout
Wire.begin(I2C_MASTER, 0x00, I2C_PINS_18_19, I2C_PULLUP_EXT, 400000);
Wire.setDefaultTimeout(10000);
// Data init
memset(databuf, 0, sizeof(databuf));
count = 0;
// setup Serial and wait for monitor to start
Serial.begin(115200);
while(!Serial);
// Start reading Slave device
slaveTimer.begin(rwSlave,1000000); // 1s timer
}
void loop()
{
delay(1);
}
void rwSlave(void)
{
digitalWrite(LED_BUILTIN,HIGH); // pulse LED when reading
// Construct data message
sprintf(databuf, "Msg #%d", count++);
// Transmit to Slave
Wire.beginTransmission(target); // Slave address
Wire.write(databuf,strlen(databuf)+1); // Write string to I2C Tx buffer (incl. string null at end)
Wire.endTransmission(); // Transmit to Slave
// Check if error occured
if(Wire.getError())
Serial.print("Write FAIL\n");
else
{
// Read from Slave
Wire.requestFrom(target, (size_t)MEM_LEN); // Read from Slave (string len unknown, request full buffer)
// Check if error occured
if(Wire.getError())
Serial.print("Read FAIL\n");
else
{
// If no error then read Rx data into buffer and print
Wire.read(databuf, Wire.available());
Serial.printf("'%s' OK\n",databuf);
}
}
digitalWrite(LED_BUILTIN,LOW);
}
================================================
FILE: examples/basic_master/basic_master.ino
================================================
// -------------------------------------------------------------------------------------------
// Basic Master
// -------------------------------------------------------------------------------------------
//
// This creates a simple I2C Master device which when triggered will send/receive a text
// string to/from a Slave device. It is intended to pair with a Slave device running the
// basic_slave sketch.
//
// Pull pin12 input low to send.
// Pull pin11 input low to receive.
//
// This example code is in the public domain.
//
// -------------------------------------------------------------------------------------------
#include <i2c_t3.h>
// Memory
#define MEM_LEN 256
char databuf[MEM_LEN];
int count;
void setup()
{
pinMode(LED_BUILTIN,OUTPUT); // LED
digitalWrite(LED_BUILTIN,LOW); // LED off
pinMode(12,INPUT_PULLUP); // Control for Send
pinMode(11,INPUT_PULLUP); // Control for Receive
// Setup for Master mode, pins 18/19, external pullups, 400kHz, 200ms default timeout
Wire.begin(I2C_MASTER, 0x00, I2C_PINS_18_19, I2C_PULLUP_EXT, 400000);
Wire.setDefaultTimeout(200000); // 200ms
// Data init
memset(databuf, 0, sizeof(databuf));
count = 0;
Serial.begin(115200);
}
void loop()
{
uint8_t target = 0x66; // target Slave address
// Send string to Slave
//
if(digitalRead(12) == LOW)
{
digitalWrite(LED_BUILTIN,HIGH); // LED on
// Construct data message
sprintf(databuf, "Data Message #%d", count++);
// Print message
Serial.printf("Sending to Slave: '%s' ", databuf);
// Transmit to Slave
Wire.beginTransmission(target); // Slave address
Wire.write(databuf,strlen(databuf)+1); // Write string to I2C Tx buffer (incl. string null at end)
Wire.endTransmission(); // Transmit to Slave
// Check if error occured
if(Wire.getError())
Serial.print("FAIL\n");
else
Serial.print("OK\n");
digitalWrite(LED_BUILTIN,LOW); // LED off
delay(100); // Delay to space out tests
}
// Read string from Slave
//
if(digitalRead(11) == LOW)
{
digitalWrite(LED_BUILTIN,HIGH); // LED on
// Print message
Serial.print("Reading from Slave: ");
// Read from Slave
Wire.requestFrom(target, (size_t)MEM_LEN); // Read from Slave (string len unknown, request full buffer)
// Check if error occured
if(Wire.getError())
Serial.print("FAIL\n");
else
{
// If no error then read Rx data into buffer and print
Wire.read(databuf, Wire.available());
Serial.printf("'%s' OK\n",databuf);
}
digitalWrite(LED_BUILTIN,LOW); // LED off
delay(100); // Delay to space out tests
}
}
================================================
FILE: examples/basic_master_callback/basic_master_callback.ino
================================================
// -------------------------------------------------------------------------------------------
// Basic Master Callback
// -------------------------------------------------------------------------------------------
//
// This creates a simple I2C Master device which when triggered will send/receive a text
// string to/from a Slave device. It is intended to pair with a Slave device running the
// basic_slave sketch.
//
// Functionally this sketch is similar to the basic_master sketch, except for three things:
// 1) It uses callbacks to handle the results and errors, instead of explicitly coding such
// routines after each send/receive call.
// 2) It can optionally demonstrate background transfers by setting the NONBLOCKING flag (from
// external observation these transfers will appear similar, but the LED duration will
// be shorter as they exit immediately after initiating the transfer).
// 3) There is an added test to dump error diagnostics from the error counting system.
//
// Pull pin12 input low to send.
// Pull pin11 input low to receive.
// Pull pin10 input low to dump error diagnostics.
//
// This example code is in the public domain.
//
// -------------------------------------------------------------------------------------------
#include <i2c_t3.h>
// Memory
#define MEM_LEN 256
char databuf[MEM_LEN];
int count;
#define NONBLOCKING
void setup()
{
pinMode(LED_BUILTIN,OUTPUT); // LED
digitalWrite(LED_BUILTIN,LOW); // LED off
pinMode(12,INPUT_PULLUP); // Control for Send
pinMode(11,INPUT_PULLUP); // Control for Receive
pinMode(10,INPUT_PULLUP); // Control for Diagnostics
// Setup for Master mode, pins 18/19, external pullups, 400kHz, 50ms default timeout
Wire.begin(I2C_MASTER, 0x00, I2C_PINS_18_19, I2C_PULLUP_EXT, 400000);
Wire.setDefaultTimeout(50000); // 50ms
// Data init
memset(databuf, 0, sizeof(databuf));
count = 0;
Serial.begin(115200);
Wire.onTransmitDone(transmitDone);
Wire.onReqFromDone(requestDone);
Wire.onError(errorEvent);
}
void loop()
{
uint8_t target = 0x66; // target Slave address
// Send string to Slave
//
if(digitalRead(12) == LOW)
{
digitalWrite(LED_BUILTIN,HIGH); // LED on
// Construct data message
sprintf(databuf, "Data Message #%d", count++);
// Print message
Serial.printf("Sending to Slave: '%s' ", databuf);
// Transmit to Slave
Wire.beginTransmission(target); // Slave address
Wire.write(databuf,strlen(databuf)+1); // Write string to I2C Tx buffer (incl. string null at end)
#if defined(NONBLOCKING)
Wire.sendTransmission(); // Transmit to Slave, non-blocking
#else
Wire.endTransmission(); // Transmit to Slave, blocking
#endif
// After send complete, callback will print result
digitalWrite(LED_BUILTIN,LOW); // LED off
delay(100); // 100ms delay
}
// Read string from Slave
//
if(digitalRead(11) == LOW)
{
digitalWrite(LED_BUILTIN,HIGH); // LED on
// Print message
Serial.print("Reading from Slave: ");
// Read from Slave
#if defined(NONBLOCKING)
Wire.sendRequest(target, (size_t)MEM_LEN); // Read from Slave (string len unknown, request full buffer), non-blocking
#else
Wire.requestFrom(target, (size_t)MEM_LEN); // Read from Slave (string len unknown, request full buffer), blocking
#endif
// After request complete, callback will print result
digitalWrite(LED_BUILTIN,LOW); // LED off
delay(100); // 100ms delay
}
// Diagnostics - print error count summary
//
if(digitalRead(10) == LOW)
{
digitalWrite(LED_BUILTIN,HIGH); // LED on
// Print errors
Serial.print("\n");
Serial.printf("I2C_ERRCNT_RESET_BUS: %d\n", Wire.getErrorCount(I2C_ERRCNT_RESET_BUS));
Serial.printf("I2C_ERRCNT_TIMEOUT: %d\n", Wire.getErrorCount(I2C_ERRCNT_TIMEOUT));
Serial.printf("I2C_ERRCNT_ADDR_NAK: %d\n", Wire.getErrorCount(I2C_ERRCNT_ADDR_NAK));
Serial.printf("I2C_ERRCNT_DATA_NAK: %d\n", Wire.getErrorCount(I2C_ERRCNT_DATA_NAK));
Serial.printf("I2C_ERRCNT_ARBL: %d\n", Wire.getErrorCount(I2C_ERRCNT_ARBL));
Serial.printf("I2C_ERRCNT_NOT_ACQ: %d\n", Wire.getErrorCount(I2C_ERRCNT_NOT_ACQ));
Serial.printf("I2C_ERRCNT_DMA_ERR: %d\n", Wire.getErrorCount(I2C_ERRCNT_DMA_ERR));
// uncomment to zero all errors after dumping
//for(uint8_t i=0; i < I2C_ERRCNT_DMA_ERR; i++) Wire.zeroErrorCount((i2c_err_count)i);
digitalWrite(LED_BUILTIN,LOW); // LED off
delay(100); // 100ms delay
}
}
//
// Trigger after Tx complete (outgoing I2C data)
//
void transmitDone(void)
{
Serial.print("OK\n");
}
//
// Trigger after Rx complete (incoming I2C data)
//
void requestDone(void)
{
Wire.read(databuf, Wire.available());
Serial.printf("'%s' OK\n",databuf);
}
//
// Trigger on I2C Error
//
void errorEvent(void)
{
Serial.print("FAIL - ");
switch(Wire.status())
{
case I2C_TIMEOUT: Serial.print("I2C timeout\n"); Wire.resetBus(); break;
case I2C_ADDR_NAK: Serial.print("Slave addr not acknowledged\n"); break;
case I2C_DATA_NAK: Serial.print("Slave data not acknowledged\n"); break;
case I2C_ARB_LOST: Serial.print("Arbitration Lost, possible pullup problem\n"); Wire.resetBus(); break;
case I2C_BUF_OVF: Serial.print("I2C buffer overflow\n"); break;
case I2C_NOT_ACQ: Serial.print("Cannot acquire bus, possible stuck SDA/SCL\n"); Wire.resetBus(); break;
case I2C_DMA_ERR: Serial.print("DMA Error\n"); break;
default: break;
}
}
================================================
FILE: examples/basic_master_mux/basic_master_mux.ino
================================================
// -------------------------------------------------------------------------------------------
// Basic Master Multiplexed
// -------------------------------------------------------------------------------------------
//
// This creates an I2C multiplexed master device which talks to the simple I2C slave device
// given in the basic_slave sketch. It is different than the basic_master sketch because it can
// output I2C commands on either pins 18/19 or pins 16/17 (both using the same I2C bus - Wire),
// and change pins on-the-fly.
//
// The purpose of this sketch is to demonstrate how the pins can be reconfigured on-the-fly
// when the bus is idle.
//
// Pull pin12 low to send command to slave on bus1 (pins 16/17)
// Pull pin11 low to send command to slave on bus2 (pins 18/19)
//
// This example code is in the public domain.
//
// -------------------------------------------------------------------------------------------
#include <i2c_t3.h>
// Memory
#define MEM_LEN 256
char databuf[MEM_LEN];
int count;
uint8_t pin12, pin11, target = 0x66; // target Slave address
size_t idx;
void setup()
{
pinMode(LED_BUILTIN,OUTPUT); // LED
digitalWrite(LED_BUILTIN,LOW); // LED off
pinMode(12,INPUT_PULLUP); // Control for Test1
pinMode(11,INPUT_PULLUP); // Control for Test2
// Setup for Master mode, pins 18/19, external pullups, 400kHz, 200ms default timeout
Wire.begin(I2C_MASTER, 0x00, I2C_PINS_18_19, I2C_PULLUP_EXT, 400000);
Wire.setDefaultTimeout(200000); // 200ms
// Data init
memset(databuf, 0, sizeof(databuf));
count = 0;
Serial.begin(115200);
}
void loop()
{
// Send string to Slave
//
pin12 = (digitalRead(12) == LOW); // latch pin values
pin11 = (digitalRead(11) == LOW);
if(pin12 || pin11)
{
// Construct data message
sprintf(databuf, "Data Message #%d", count++);
// Change pins
if(pin12)
{
Wire.pinConfigure(I2C_PINS_16_17, I2C_PULLUP_EXT);
Serial.printf("Sending to Slave 0x%02X on pins 16/17: '%s' ", target, databuf);
}
else
{
Wire.pinConfigure(I2C_PINS_18_19, I2C_PULLUP_EXT);
Serial.printf("Sending to Slave 0x%02X on pins 18/19: '%s' ", target, databuf);
}
digitalWrite(LED_BUILTIN,HIGH); // LED on
// Transmit to Slave
Wire.beginTransmission(target); // Slave address
Wire.write(databuf,strlen(databuf)+1); // Write string to I2C Tx buffer (incl. string null at end)
Wire.endTransmission(); // Transmit to Slave
// Check if error occured
if(Wire.getError())
Serial.print("FAIL\n");
else
Serial.print("OK\n");
digitalWrite(LED_BUILTIN,LOW); // LED off
delay(100); // Delay to space out tests
}
}
================================================
FILE: examples/basic_scanner/basic_scanner.ino
================================================
// -------------------------------------------------------------------------------------------
// I2C Bus Scanner
// -------------------------------------------------------------------------------------------
//
// This creates an I2C master device which will scan the address space and report all
// devices which ACK. It does not attempt to transfer data, it only reports which devices
// ACK their address.
//
// Pull the control pin low to initiate the scan. Result will output to Serial.
//
// This example code is in the public domain.
// -------------------------------------------------------------------------------------------
#include <i2c_t3.h>
// Function prototypes
void print_scan_status(uint8_t target, uint8_t all);
uint8_t found, target, all;
void setup()
{
pinMode(LED_BUILTIN,OUTPUT); // LED
pinMode(12,INPUT_PULLUP); // pull pin 12 low to show ACK only results
pinMode(11,INPUT_PULLUP); // pull pin 11 low for a more verbose result (shows both ACK and NACK)
// Setup for Master mode, pins 18/19, external pullups, 400kHz, 10ms default timeout
Wire.begin(I2C_MASTER, 0x00, I2C_PINS_18_19, I2C_PULLUP_EXT, 400000);
Wire.setDefaultTimeout(10000); // 10ms
Serial.begin(115200);
}
void loop()
{
// Scan I2C addresses
//
if(digitalRead(12) == LOW || digitalRead(11) == LOW)
{
all = (digitalRead(11) == LOW);
found = 0;
Serial.print("---------------------------------------------------\n");
Serial.print("Starting scan...\n");
digitalWrite(LED_BUILTIN,HIGH); // LED on
for(target = 1; target <= 0x7F; target++) // sweep addr, skip general call
{
Wire.beginTransmission(target); // slave addr
Wire.endTransmission(); // no data, just addr
print_scan_status(target, all);
}
digitalWrite(LED_BUILTIN,LOW); // LED off
if(!found) Serial.print("No devices found.\n");
delay(500); // delay to space out tests
}
}
//
// print scan status
//
void print_scan_status(uint8_t target, uint8_t all)
{
switch(Wire.status())
{
case I2C_WAITING:
Serial.printf("Addr: 0x%02X ACK\n", target);
found = 1;
break;
case I2C_ADDR_NAK:
if(all) Serial.printf("Addr: 0x%02X\n", target);
break;
default:
break;
}
}
================================================
FILE: examples/basic_slave/basic_slave.ino
================================================
// -------------------------------------------------------------------------------------------
// Basic Slave
// -------------------------------------------------------------------------------------------
//
// This creates a simple I2C Slave device which will print whatever text string is sent to it.
// It will retain the text string in memory and will send it back to a Master device if
// requested. It is intended to pair with a Master device running the basic_master sketch.
//
// This example code is in the public domain.
//
// -------------------------------------------------------------------------------------------
#include <i2c_t3.h>
// Function prototypes
void receiveEvent(size_t count);
void requestEvent(void);
// Memory
#define MEM_LEN 256
char databuf[MEM_LEN];
volatile uint8_t received;
//
// Setup
//
void setup()
{
pinMode(LED_BUILTIN,OUTPUT); // LED
// Setup for Slave mode, address 0x66, pins 18/19, external pullups, 400kHz
Wire.begin(I2C_SLAVE, 0x66, I2C_PINS_18_19, I2C_PULLUP_EXT, 400000);
// Data init
received = 0;
memset(databuf, 0, sizeof(databuf));
// register events
Wire.onReceive(receiveEvent);
Wire.onRequest(requestEvent);
Serial.begin(115200);
}
void loop()
{
// print received data - this is done in main loop to keep time spent in I2C ISR to minimum
if(received)
{
digitalWrite(LED_BUILTIN,HIGH);
Serial.printf("Slave received: '%s'\n", databuf);
received = 0;
digitalWrite(LED_BUILTIN,LOW);
}
}
//
// handle Rx Event (incoming I2C data)
//
void receiveEvent(size_t count)
{
Wire.read(databuf, count); // copy Rx data to databuf
received = count; // set received flag to count, this triggers print in main loop
}
//
// handle Tx Event (outgoing I2C data)
//
void requestEvent(void)
{
Wire.write(databuf, MEM_LEN); // fill Tx buffer (send full mem)
}
================================================
FILE: examples/basic_slave_range/basic_slave_range.ino
================================================
// -------------------------------------------------------------------------------------------
// Basic Slave with Address Range
// -------------------------------------------------------------------------------------------
//
// This creates a simple I2C Slave device which will print whatever text string is sent to it.
// It will retain the text string in memory and will send it back to a Master device if
// requested. It is intended to pair with a Master device running the basic_master sketch.
//
// The Slave will respond to a range of I2C addresses. It demonstrates use of the getRxAddr()
// function which can be used to obtain the Slave address. This allows a single device to
// act as multiple different Slave targets.
//
// This example code is in the public domain.
//
// -------------------------------------------------------------------------------------------
#include <i2c_t3.h>
// Function prototypes
void receiveEvent(size_t len);
void requestEvent(void);
// Memory
#define MEM_LEN 256
uint8_t databuf[MEM_LEN];
volatile uint8_t target;
volatile uint8_t received;
//
// Setup
//
void setup()
{
pinMode(LED_BUILTIN,OUTPUT); // LED
// Setup for Slave mode, addresses 0x08 to 0x77, pins 18/19, external pullups, 400kHz
Wire.begin(I2C_SLAVE, 0x08, 0x77, I2C_PINS_18_19, I2C_PULLUP_EXT, 400000);
// Data init
received = 0;
target = 0;
memset(databuf, 0, sizeof(databuf));
// register events
Wire.onReceive(receiveEvent);
Wire.onRequest(requestEvent);
Serial.begin(115200);
}
void loop()
{
// print received data
if(received)
{
digitalWrite(LED_BUILTIN,HIGH);
Serial.printf("Slave 0x%02X received: '%s'\n", target, (char*)databuf);
received = 0;
digitalWrite(LED_BUILTIN,LOW);
}
}
//
// handle Rx Event (incoming I2C data)
//
void receiveEvent(size_t count)
{
target = Wire.getRxAddr(); // getRxAddr() is used to obtain Slave address
Wire.read(databuf, count); // copy Rx data to databuf
received = count; // set received flag to count, this triggers print in main loop
}
//
// handle Tx Event (outgoing I2C data)
//
void requestEvent(void)
{
Wire.write(databuf, MEM_LEN); // fill Tx buffer (send full mem)
}
================================================
FILE: i2c_t3.cpp
================================================
/*
------------------------------------------------------------------------------------------------------
i2c_t3 - I2C library for Teensy 3.x & LC
- (v11.0) Modified 01Dec18 by Brian (nox771 at gmail.com)
Full changelog at end of file
------------------------------------------------------------------------------------------------------
Copyright (c) 2013-2018, Brian (nox771 at gmail.com)
Permission is hereby granted, free of charge, to any person obtaining a copy of this software and
associated documentation files (the "Software"), to deal in the Software without restriction,
including without limitation the rights to use, copy, modify, merge, publish, distribute, sublicense,
and/or sell copies of the Software, and to permit persons to whom the Software is furnished to do so,
subject to the following conditions:
The above copyright notice and this permission notice shall be included in all copies or substantial
portions of the Software.
THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR IMPLIED, INCLUDING BUT NOT
LIMITED TO THE WARRANTIES OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.
IN NO EVENT SHALL THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION
WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.
------------------------------------------------------------------------------------------------------
*/
#if defined(__MK20DX128__) || defined(__MK20DX256__) || defined(__MKL26Z64__) || \
defined(__MK64FX512__) || defined(__MK66FX1M0__) // 3.0/3.1-3.2/LC/3.5/3.6
#include "i2c_t3.h"
// ------------------------------------------------------------------------------------------------------
// Static inits
//
#define I2C_STRUCT(a1,f,c1,s,d,c2,flt,ra,smb,a2,slth,sltl,scl,sda) \
{a1, f, c1, s, d, c2, flt, ra, smb, a2, slth, sltl, {}, 0, 0, {}, 0, 0, I2C_OP_MODE_ISR, I2C_MASTER, scl, sda, I2C_PULLUP_EXT, 100000, \
I2C_STOP, I2C_WAITING, 0, 0, 0, 0, I2C_DMA_OFF, nullptr, nullptr, nullptr, nullptr, nullptr, nullptr, 0, {}, 0, 0 }
struct i2cStruct i2c_t3::i2cData[] =
{
I2C_STRUCT(&I2C0_A1, &I2C0_F, &I2C0_C1, &I2C0_S, &I2C0_D, &I2C0_C2, &I2C0_FLT, &I2C0_RA, &I2C0_SMB, &I2C0_A2, &I2C0_SLTH, &I2C0_SLTL, 19, 18)
#if (I2C_BUS_NUM >= 2) && defined(__MK20DX256__) // 3.1/3.2
,I2C_STRUCT(&I2C1_A1, &I2C1_F, &I2C1_C1, &I2C1_S, &I2C1_D, &I2C1_C2, &I2C1_FLT, &I2C1_RA, &I2C1_SMB, &I2C1_A2, &I2C1_SLTH, &I2C1_SLTL, 29, 30)
#elif (I2C_BUS_NUM >= 2) && defined(__MKL26Z64__) // LC
,I2C_STRUCT(&I2C1_A1, &I2C1_F, &I2C1_C1, &I2C1_S, &I2C1_D, &I2C1_C2, &I2C1_FLT, &I2C1_RA, &I2C1_SMB, &I2C1_A2, &I2C1_SLTH, &I2C1_SLTL, 22, 23)
#elif (I2C_BUS_NUM >= 2) && (defined(__MK64FX512__) || defined(__MK66FX1M0__)) // 3.5/3.6
,I2C_STRUCT(&I2C1_A1, &I2C1_F, &I2C1_C1, &I2C1_S, &I2C1_D, &I2C1_C2, &I2C1_FLT, &I2C1_RA, &I2C1_SMB, &I2C1_A2, &I2C1_SLTH, &I2C1_SLTL, 37, 38)
#endif
#if (I2C_BUS_NUM >= 3) && (defined(__MK64FX512__) || defined(__MK66FX1M0__)) // 3.5/3.6
,I2C_STRUCT(&I2C2_A1, &I2C2_F, &I2C2_C1, &I2C2_S, &I2C2_D, &I2C2_C2, &I2C2_FLT, &I2C2_RA, &I2C2_SMB, &I2C2_A2, &I2C2_SLTH, &I2C2_SLTL, 3, 4)
#endif
#if (I2C_BUS_NUM >= 4) && defined(__MK66FX1M0__) // 3.6
,I2C_STRUCT(&I2C3_A1, &I2C3_F, &I2C3_C1, &I2C3_S, &I2C3_D, &I2C3_C2, &I2C3_FLT, &I2C3_RA, &I2C3_SMB, &I2C3_A2, &I2C3_SLTH, &I2C3_SLTL, 57, 56)
#endif
};
volatile uint8_t i2c_t3::isrActive = 0;
// ------------------------------------------------------------------------------------------------------
// Constructor/Destructor
//
i2c_t3::i2c_t3(uint8_t i2c_bus)
{
bus = i2c_bus;
i2c = &i2cData[bus];
}
i2c_t3::~i2c_t3()
{
// if DMA active, delete DMA object
if(i2c->opMode == I2C_OP_MODE_DMA)
delete i2c->DMA;
}
// ------------------------------------------------------------------------------------------------------
// Initialize I2C - initializes I2C as Master or address range Slave
// return: none
// parameters (optional parameters marked '^'):
// mode = I2C_MASTER, I2C_SLAVE
// address1 = 7bit slave address when configured as Slave (ignored for Master mode)
// ^ address2 = 2nd 7bit address for specifying Slave address range (ignored for Master mode)
// ^ pins = pins to use, can be specified as 'i2c_pins' enum,
// or as 'SCL,SDA' pair (using any valid SCL or SDA), options are:
// Pin Name
// Interface Devices (deprecated) SCL SDA
// --------- ------- -------------- ----- ----- (note: in almost all cases SCL is the
// Wire All I2C_PINS_16_17 16 17 lower pin #, except cases marked *)
// Wire All I2C_PINS_18_19 19 18 *
// Wire 3.5/3.6 I2C_PINS_7_8 7 8
// Wire 3.5/3.6 I2C_PINS_33_34 33 34
// Wire 3.5/3.6 I2C_PINS_47_48 47 48
// Wire1 LC I2C_PINS_22_23 22 23
// Wire1 3.1/3.2 I2C_PINS_26_31 26 31
// Wire1 3.1/3.2 I2C_PINS_29_30 29 30
// Wire1 3.5/3.6 I2C_PINS_37_38 37 38
// Wire2 3.5/3.6 I2C_PINS_3_4 3 4
// Wire3 3.6 I2C_PINS_56_57 57 56 *
// ^ pullup = I2C_PULLUP_EXT, I2C_PULLUP_INT
// ^ rate = I2C frequency to use, can be specified directly in Hz, eg. 400000 for 400kHz, or using one of the
// following enum values (deprecated):
// I2C_RATE_100, I2C_RATE_200, I2C_RATE_300, I2C_RATE_400,
// I2C_RATE_600, I2C_RATE_800, I2C_RATE_1000, I2C_RATE_1200,
// I2C_RATE_1500, I2C_RATE_1800, I2C_RATE_2000, I2C_RATE_2400,
// I2C_RATE_2800, I2C_RATE_3000
// ^ opMode = I2C_OP_MODE_IMM, I2C_OP_MODE_ISR, I2C_OP_MODE_DMA (ignored for Slave mode, defaults to ISR)
//
void i2c_t3::begin_(struct i2cStruct* i2c, uint8_t bus, i2c_mode mode, uint8_t address1, uint8_t address2,
uint8_t pinSCL, uint8_t pinSDA, i2c_pullup pullup, uint32_t rate, i2c_op_mode opMode)
{
// Enable I2C internal clock
if(bus == 0)
SIM_SCGC4 |= SIM_SCGC4_I2C0;
#if I2C_BUS_NUM >= 2
if(bus == 1)
SIM_SCGC4 |= SIM_SCGC4_I2C1;
#endif
#if I2C_BUS_NUM >= 3
if(bus == 2)
SIM_SCGC1 |= SIM_SCGC1_I2C2;
#endif
#if I2C_BUS_NUM >= 4
if(bus == 3)
SIM_SCGC1 |= SIM_SCGC1_I2C3;
#endif
i2c->currentMode = mode; // Set mode
i2c->currentStatus = I2C_WAITING; // reset status
// Set Master/Slave address
if(i2c->currentMode == I2C_MASTER)
{
*(i2c->C2) = I2C_C2_HDRS; // Set high drive select
//*(i2c->A1) = 0;
//*(i2c->RA) = 0;
}
else
{
*(i2c->C2) = (address2) ? (I2C_C2_HDRS|I2C_C2_RMEN) // Set high drive select and range-match enable
: I2C_C2_HDRS; // Set high drive select
// set Slave address, if two addresses are given, setup range and put lower address in A1, higher in RA
*(i2c->A1) = (address2) ? ((address1 < address2) ? (address1<<1) : (address2<<1))
: (address1<<1);
*(i2c->RA) = (address2) ? ((address1 < address2) ? (address2<<1) : (address1<<1))
: 0;
}
// Setup pins - As noted in original TwoWire.cpp, internal 3.0/3.1/3.2 pullup is strong (about 190 ohms),
// but it can work if other devices on bus have strong enough pulldowns.
//
if(!pinSCL) pinSCL = i2c->currentSCL; // if either pin specified as 0, then use current settings
if(!pinSDA) pinSDA = i2c->currentSDA;
pinConfigure_(i2c, bus, pinSCL, pinSDA, pullup, i2c->configuredSCL, i2c->configuredSDA);
// Set I2C rate
#if defined(__MKL26Z64__) // LC
if(bus == 1)
setRate_(i2c, (uint32_t)F_CPU, rate); // LC Wire1 bus uses system clock (F_CPU) instead of bus clock (F_BUS)
else
setRate_(i2c, (uint32_t)F_BUS, rate);
#else
setRate_(i2c, (uint32_t)F_BUS, rate);
#endif
// Set config registers and operating mode
setOpMode_(i2c, bus, opMode);
if(i2c->currentMode == I2C_MASTER)
*(i2c->C1) = I2C_C1_IICEN; // Master - enable I2C (hold in Rx mode, intr disabled)
else
*(i2c->C1) = I2C_C1_IICEN|I2C_C1_IICIE; // Slave - enable I2C and interrupts
}
// ------------------------------------------------------------------------------------------------------
// Valid pin checks - verify if SCL or SDA pin is valid on given bus, intended for internal use only
// return: alt setting, 0=not valid
// parameters:
// bus = bus number
// pin = pin number to check
// offset = array offset
//
uint8_t i2c_t3::validPin_(uint8_t bus, uint8_t pin, uint8_t offset)
{
for(uint8_t idx=0; idx < I2C_PINS_COUNT-1; idx++)
if(i2c_valid_pins[idx*4] == bus && i2c_valid_pins[idx*4+offset] == pin) return i2c_valid_pins[idx*4+3];
return 0;
}
// Set Operating Mode - this configures operating mode of the I2C as either Immediate, ISR, or DMA.
// By default Arduino-style begin() calls will initialize to ISR mode. This can
// only be called when the bus is idle (no changing mode in the middle of Tx/Rx).
// Note that Slave mode can only use ISR operation.
// return: 1=success, 0=fail (bus busy)
// parameters:
// opMode = I2C_OP_MODE_ISR, I2C_OP_MODE_DMA, I2C_OP_MODE_IMM
//
uint8_t i2c_t3::setOpMode_(struct i2cStruct* i2c, uint8_t bus, i2c_op_mode opMode)
{
if(*(i2c->S) & I2C_S_BUSY) return 0; // return immediately if bus busy
*(i2c->C1) = I2C_C1_IICEN; // reset I2C modes, stop intr, stop DMA
*(i2c->S) = I2C_S_IICIF | I2C_S_ARBL; // clear status flags just in case
// Slaves can only use ISR
if(i2c->currentMode == I2C_SLAVE) opMode = I2C_OP_MODE_ISR;
if(opMode == I2C_OP_MODE_IMM)
{
i2c->opMode = I2C_OP_MODE_IMM;
}
if(opMode == I2C_OP_MODE_ISR || opMode == I2C_OP_MODE_DMA)
{
// Nested Vec Interrupt Ctrl - enable I2C interrupt
if(bus == 0)
{
NVIC_ENABLE_IRQ(IRQ_I2C0);
I2C0_INTR_FLAG_INIT; // init I2C0 interrupt flag if used
}
#if I2C_BUS_NUM >= 2
if(bus == 1)
{
NVIC_ENABLE_IRQ(IRQ_I2C1);
I2C1_INTR_FLAG_INIT; // init I2C1 interrupt flag if used
}
#endif
#if I2C_BUS_NUM >= 3
if(bus == 2)
{
NVIC_ENABLE_IRQ(IRQ_I2C2);
I2C2_INTR_FLAG_INIT; // init I2C2 interrupt flag if used
}
#endif
#if I2C_BUS_NUM >= 4
if(bus == 3)
{
NVIC_ENABLE_IRQ(IRQ_I2C3);
I2C3_INTR_FLAG_INIT; // init I2C3 interrupt flag if used
}
#endif
if(opMode == I2C_OP_MODE_DMA)
{
// attempt to get a DMA Channel (if not already allocated)
if(i2c->DMA == nullptr)
i2c->DMA = new DMAChannel();
// check if object created but no available channel
if(i2c->DMA != nullptr && i2c->DMA->channel == DMA_NUM_CHANNELS)
{
// revert to ISR mode if no DMA channels avail
delete i2c->DMA;
i2c->DMA = nullptr;
i2c->opMode = I2C_OP_MODE_ISR;
}
else
{
// DMA object has valid channel
if(bus == 0)
{
// setup static DMA settings
i2c->DMA->disableOnCompletion();
i2c->DMA->attachInterrupt(i2c0_isr);
i2c->DMA->interruptAtCompletion();
i2c->DMA->triggerAtHardwareEvent(DMAMUX_SOURCE_I2C0);
}
#if I2C_BUS_NUM >= 2
if(bus == 1)
{
// setup static DMA settings
i2c->DMA->disableOnCompletion();
i2c->DMA->attachInterrupt(i2c1_isr);
i2c->DMA->interruptAtCompletion();
i2c->DMA->triggerAtHardwareEvent(DMAMUX_SOURCE_I2C1);
}
#endif
#if I2C_BUS_NUM >= 3
// note: on T3.6 I2C2 shares DMAMUX with I2C1
if(bus == 2)
{
// setup static DMA settings
i2c->DMA->disableOnCompletion();
i2c->DMA->attachInterrupt(i2c2_isr);
i2c->DMA->interruptAtCompletion();
i2c->DMA->triggerAtHardwareEvent(DMAMUX_SOURCE_I2C2);
}
#endif
#if I2C_BUS_NUM >= 4
// note: on T3.6 I2C3 shares DMAMUX with I2C0
if(bus == 3)
{
// setup static DMA settings
i2c->DMA->disableOnCompletion();
i2c->DMA->attachInterrupt(i2c3_isr);
i2c->DMA->interruptAtCompletion();
i2c->DMA->triggerAtHardwareEvent(DMAMUX_SOURCE_I2C3);
}
#endif
i2c->activeDMA = I2C_DMA_OFF;
i2c->opMode = I2C_OP_MODE_DMA;
}
}
else
i2c->opMode = I2C_OP_MODE_ISR;
}
return 1;
}
// Set I2C rate - reconfigures I2C frequency divider based on supplied bus freq and desired I2C freq.
// This will be done assuming an idealized I2C rate, even though at high I2C rates
// the actual throughput is much lower than theoretical value.
//
// Since the division ratios are quantized with non-uniform spacing, the selected rate
// will be the one using the nearest available divider.
// return: none
// parameters:
// busFreq = bus frequency, typically F_BUS unless reconfigured
// freq = desired I2C frequency (will be quantized to nearest rate), or can be I2C_RATE_XXX enum (deprecated),
// such as I2C_RATE_100, I2C_RATE_400, etc...
//
// Max I2C rate is 1/20th F_BUS. Some examples:
//
// F_CPU F_BUS Max I2C
// (MHz) (MHz) Rate
// ------------- ----- ----------
// 240/120 120 6.0M bus overclock
// 216 108 5.4M bus overclock
// 192/96 96 4.8M bus overclock
// 180 90 4.5M bus overclock
// 240 80 4.0M bus overclock
// 216/144/72 72 3.6M bus overclock
// 192 64 3.2M bus overclock
// 240/180/120 60 3.0M
// 168 56 2.8M
// 216 54 2.7M
// 192/144/96/48 48 2.4M
// 72 36 1.8M
// 24 24 1.2M
// 16 16 800k
// 8 8 400k
// 4 4 200k
// 2 2 100k
//
void i2c_t3::setRate_(struct i2cStruct* i2c, uint32_t busFreq, uint32_t i2cFreq)
{
int32_t target_div = ((busFreq/1000)<<8)/(i2cFreq/1000);
size_t idx;
// find closest divide ratio
for(idx=0; idx < sizeof(i2c_div_num)/sizeof(i2c_div_num[0]) && (i2c_div_num[idx]<<8) <= target_div; idx++);
if(idx && abs(target_div-(i2c_div_num[idx-1]<<8)) <= abs(target_div-(i2c_div_num[idx]<<8))) idx--;
// Set divider to set rate
*(i2c->F) = i2c_div_ratio[idx];
// save current rate setting
i2c->currentRate = busFreq/i2c_div_num[idx];
// Set filter
if(busFreq >= 48000000)
*(i2c->FLT) = 4;
else
*(i2c->FLT) = busFreq/12000000;
}
// ------------------------------------------------------------------------------------------------------
// Configure I2C pins - reconfigures active I2C pins on-the-fly (only works when bus is idle). If reconfig
// set then inactive pins will switch to input mode using same pullup configuration.
// return: 1=success, 0=fail (bus busy or incompatible pins)
// parameters:
// pins = pins to use, can be specified as 'i2c_pins' enum,
// or as 'SCL,SDA' pair (using any valid SCL or SDA), options are:
// Pin Name
// Interface Devices (deprecated) SCL SDA
// --------- ------- -------------- ----- ----- (note: in almost all cases SCL is the
// Wire All I2C_PINS_16_17 16 17 lower pin #, except cases marked *)
// Wire All I2C_PINS_18_19 19 18 *
// Wire 3.5/3.6 I2C_PINS_7_8 7 8
// Wire 3.5/3.6 I2C_PINS_33_34 33 34
// Wire 3.5/3.6 I2C_PINS_47_48 47 48
// Wire1 LC I2C_PINS_22_23 22 23
// Wire1 3.1/3.2 I2C_PINS_26_31 26 31
// Wire1 3.1/3.2 I2C_PINS_29_30 29 30
// Wire1 3.5/3.6 I2C_PINS_37_38 37 38
// Wire2 3.5/3.6 I2C_PINS_3_4 3 4
// Wire3 3.6 I2C_PINS_56_57 57 56 *
// pullup = I2C_PULLUP_EXT, I2C_PULLUP_INT
// reconfig = 1=reconfigure old pins, 0=do not reconfigure old pins (base routine only)
//
#define PIN_CONFIG_ALT(name,alt) uint32_t name = (pullup == I2C_PULLUP_EXT) ? (PORT_PCR_MUX(alt)|PORT_PCR_ODE|PORT_PCR_SRE|PORT_PCR_DSE) \
: (PORT_PCR_MUX(alt)|PORT_PCR_PE|PORT_PCR_PS)
uint8_t i2c_t3::pinConfigure_(struct i2cStruct* i2c, uint8_t bus, uint8_t pinSCL, uint8_t pinSDA, i2c_pullup pullup,
uint8_t configuredSCL, uint8_t configuredSDA)
{
uint8_t validAltSCL, validAltSDA;
volatile uint32_t* pcr;
if((configuredSCL && configuredSDA) && (*(i2c->S) & I2C_S_BUSY)) return 0; // if configured return immediately if bus busy
// Verify new SCL pin is different or not configured, and valid
//
validAltSCL = validPin_(bus, pinSCL, 1);
if((pinSCL != i2c->currentSCL || !configuredSCL) && validAltSCL)
{
// If configured, switch previous pin to non-I2C input
if(configuredSCL) pinMode(i2c->currentSCL, (i2c->currentPullup == I2C_PULLUP_EXT) ? INPUT : INPUT_PULLUP);
// Config new pin
PIN_CONFIG_ALT(configSCL, validAltSCL);
pcr = portConfigRegister(pinSCL);
*pcr = configSCL;
i2c->currentSCL = pinSCL;
i2c->currentPullup = pullup;
i2c->configuredSCL = 1;
}
// Verify new SDA pin is different or not configured, and valid
//
validAltSDA = validPin_(bus, pinSDA, 2);
if((pinSDA != i2c->currentSDA || !configuredSDA) && validAltSDA)
{
// If reconfig set, switch previous pin to non-I2C input
if(configuredSDA) pinMode(i2c->currentSDA, (i2c->currentPullup == I2C_PULLUP_EXT) ? INPUT : INPUT_PULLUP);
// Config new pin
PIN_CONFIG_ALT(configSDA, validAltSDA);
pcr = portConfigRegister(pinSDA);
*pcr = configSDA;
i2c->currentSDA = pinSDA;
i2c->currentPullup = pullup;
i2c->configuredSDA = 1;
}
return (validAltSCL && validAltSDA);
}
// ------------------------------------------------------------------------------------------------------
// Acquire Bus - acquires bus in Master mode and escalates priority as needed, intended
// for internal use only
// return: 1=success, 0=fail (cannot acquire bus)
// parameters:
// timeout = timeout in microseconds
// forceImm = flag to indicate if immediate mode is required
//
uint8_t i2c_t3::acquireBus_(struct i2cStruct* i2c, uint8_t bus, uint32_t timeout, uint8_t& forceImm)
{
elapsedMicros deltaT;
// update timeout
timeout = (timeout == 0) ? i2c->defTimeout : timeout;
// TODO may need to check bus busy before issuing START if multi-master
// start timer, then take control of the bus
deltaT = 0;
if(*(i2c->C1) & I2C_C1_MST)
{
// we are already the bus master, so send a repeated start
*(i2c->C1) = I2C_C1_IICEN | I2C_C1_MST | I2C_C1_RSTA | I2C_C1_TX;
}
else
{
while(timeout == 0 || deltaT < timeout)
{
// we are not currently the bus master, so check if bus ready
if(!(*(i2c->S) & I2C_S_BUSY))
{
// become the bus master in transmit mode (send start)
i2c->currentMode = I2C_MASTER;
*(i2c->C1) = I2C_C1_IICEN | I2C_C1_MST | I2C_C1_TX;
break;
}
}
#if defined(I2C_AUTO_RETRY)
// if not master and auto-retry set, then reset bus and try one last time
if(!(*(i2c->C1) & I2C_C1_MST))
{
resetBus_(i2c,bus);
I2C_ERR_INC(I2C_ERRCNT_RESET_BUS);
if(!(*(i2c->S) & I2C_S_BUSY))
{
// become the bus master in transmit mode (send start)
i2c->currentMode = I2C_MASTER;
*(i2c->C1) = I2C_C1_IICEN | I2C_C1_MST | I2C_C1_TX;
}
}
#endif
// check if not master
if(!(*(i2c->C1) & I2C_C1_MST))
{
i2c->currentStatus = I2C_NOT_ACQ; // bus not acquired
I2C_ERR_INC(I2C_ERRCNT_NOT_ACQ);
if(i2c->user_onError != nullptr) i2c->user_onError(); // run Error callback if cannot acquire bus
return 0;
}
}
#ifndef I2C_DISABLE_PRIORITY_CHECK
// For ISR operation, check if current routine has higher priority than I2C IRQ, and if so
// either escalate priority of I2C IRQ or send I2C using immediate mode.
//
// This check is disabled if the routine is called during an active I2C ISR (assumes it is
// called from ISR callback). This is to prevent runaway escalation with nested Wire calls.
//
int irqPriority, currPriority;
if(!i2c_t3::isrActive && (i2c->opMode == I2C_OP_MODE_ISR || i2c->opMode == I2C_OP_MODE_DMA))
{
currPriority = nvic_execution_priority();
switch(bus)
{
case 0: irqPriority = NVIC_GET_PRIORITY(IRQ_I2C0); break;
#if defined(__MKL26Z64__) || defined(__MK20DX256__) || defined(__MK64FX512__) || defined(__MK66FX1M0__) // LC/3.1/3.2/3.5/3.6
case 1: irqPriority = NVIC_GET_PRIORITY(IRQ_I2C1); break;
#endif
#if defined(__MK64FX512__) || defined(__MK66FX1M0__) // 3.5/3.6
case 2: irqPriority = NVIC_GET_PRIORITY(IRQ_I2C2); break;
#endif
#if defined(__MK66FX1M0__) // 3.6
case 3: irqPriority = NVIC_GET_PRIORITY(IRQ_I2C3); break;
#endif
default: irqPriority = NVIC_GET_PRIORITY(IRQ_I2C0); break;
}
if(currPriority <= irqPriority)
{
if(currPriority < 16)
forceImm = 1; // current priority cannot be surpassed, force Immediate mode
else
{
switch(bus)
{
case 0: NVIC_SET_PRIORITY(IRQ_I2C0, currPriority-16); break;
#if defined(__MKL26Z64__) || defined(__MK20DX256__) || defined(__MK64FX512__) || defined(__MK66FX1M0__) // LC/3.1/3.2/3.5/3.6
case 1: NVIC_SET_PRIORITY(IRQ_I2C1, currPriority-16); break;
#endif
#if defined(__MK64FX512__) || defined(__MK66FX1M0__) // 3.5/3.6
case 2: NVIC_SET_PRIORITY(IRQ_I2C2, currPriority-16); break;
#endif
#if defined(__MK66FX1M0__) // 3.6
case 3: NVIC_SET_PRIORITY(IRQ_I2C3, currPriority-16); break;
#endif
default: NVIC_SET_PRIORITY(IRQ_I2C0, currPriority-16); break;
}
}
}
}
#endif
return 1;
}
// ------------------------------------------------------------------------------------------------------
// Reset Bus - toggles SCL until SDA line is released (9 clocks max). This is used to correct
// a hung bus in which a Slave device missed some clocks and remains stuck outputting
// a low signal on SDA (thereby preventing START/STOP signaling).
// return: none
//
void i2c_t3::resetBus_(struct i2cStruct* i2c, uint8_t bus)
{
uint8_t scl = i2c->currentSCL;
uint8_t sda = i2c->currentSDA;
// change pin mux to digital I/O
pinMode(sda,((i2c->currentPullup == I2C_PULLUP_EXT) ? INPUT : INPUT_PULLUP));
digitalWrite(scl,HIGH);
pinMode(scl,OUTPUT);
for(uint8_t count=0; digitalRead(sda) == 0 && count < 9; count++)
{
digitalWrite(scl,LOW);
delayMicroseconds(5); // 10us period == 100kHz
digitalWrite(scl,HIGH);
delayMicroseconds(5);
}
// reconfigure pins for I2C
pinConfigure_(i2c, bus, scl, sda, i2c->currentPullup, 0, 0);
// reset config and status
if(*(i2c->S) & 0x7F) // reset config if any residual status bits are set
{
*(i2c->C1) = 0x00; // disable I2C, intr disabled
delayMicroseconds(5);
*(i2c->C1) = I2C_C1_IICEN; // enable I2C, intr disabled, Rx mode
delayMicroseconds(5);
}
i2c->currentStatus = I2C_WAITING;
}
// ------------------------------------------------------------------------------------------------------
// Setup Master Transmit - initialize Tx buffer for transmit to slave at address
// return: none
// parameters:
// address = target 7bit slave address
//
void i2c_t3::beginTransmission(uint8_t address)
{
i2c->txBuffer[0] = (address << 1); // store target addr
i2c->txBufferLength = 1;
clearWriteError(); // clear any previous write error
i2c->currentStatus = I2C_WAITING; // reset status
}
// ------------------------------------------------------------------------------------------------------
// Master Transmit - blocking routine with timeout, transmits Tx buffer to slave. i2c_stop parameter can be used
// to indicate if command should end with a STOP(I2C_STOP) or not (I2C_NOSTOP).
// return: 0=success, 1=data too long, 2=recv addr NACK, 3=recv data NACK, 4=other error
// parameters:
// i2c_stop = I2C_NOSTOP, I2C_STOP
// timeout = timeout in microseconds
//
uint8_t i2c_t3::endTransmission(struct i2cStruct* i2c, uint8_t bus, i2c_stop sendStop, uint32_t timeout)
{
sendTransmission_(i2c, bus, sendStop, timeout);
// wait for completion or timeout
finish_(i2c, bus, timeout);
return getError();
}
// ------------------------------------------------------------------------------------------------------
// Send Master Transmit - non-blocking routine, starts transmit of Tx buffer to slave. i2c_stop parameter can be
// used to indicate if command should end with a STOP (I2C_STOP) or not (I2C_NOSTOP). Use
// done() or finish() to determine completion and status() to determine success/fail.
// return: none
// parameters:
// i2c_stop = I2C_NOSTOP, I2C_STOP
// timeout = timeout in microseconds (only used for Immediate operation)
//
void i2c_t3::sendTransmission_(struct i2cStruct* i2c, uint8_t bus, i2c_stop sendStop, uint32_t timeout)
{
uint8_t status, forceImm=0;
size_t idx;
// exit immediately if sending 0 bytes
if(i2c->txBufferLength == 0) return;
// update timeout
timeout = (timeout == 0) ? i2c->defTimeout : timeout;
// clear the status flags
#if defined(__MKL26Z64__) || defined(__MK64FX512__) || defined(__MK66FX1M0__) // LC/3.5/3.6
*(i2c->FLT) |= I2C_FLT_STOPF | I2C_FLT_STARTF; // clear STOP/START intr
*(i2c->FLT) &= ~I2C_FLT_SSIE; // disable STOP/START intr (not used in Master mode)
#endif
*(i2c->S) = I2C_S_IICIF | I2C_S_ARBL; // clear intr, arbl
// try to take control of the bus
if(!acquireBus_(i2c, bus, timeout, forceImm)) return;
//
// Immediate mode - blocking
//
if(i2c->opMode == I2C_OP_MODE_IMM || forceImm)
{
elapsedMicros deltaT;
i2c->currentStatus = I2C_SENDING;
i2c->currentStop = sendStop;
for(idx=0; idx < i2c->txBufferLength && (timeout == 0 || deltaT < timeout); idx++)
{
// send data, wait for done
*(i2c->D) = i2c->txBuffer[idx];
// wait for byte
while(!(*(i2c->S) & I2C_S_IICIF) && (timeout == 0 || deltaT < timeout));
*(i2c->S) = I2C_S_IICIF;
if(timeout && deltaT >= timeout) break;
status = *(i2c->S);
// check arbitration
if(status & I2C_S_ARBL)
{
i2c->currentStatus = I2C_ARB_LOST;
*(i2c->S) = I2C_S_ARBL; // clear arbl flag
// TODO: this is clearly not right, after ARBL it should drop into IMM slave mode if IAAS=1
// Right now Rx message would be ignored regardless of IAAS
*(i2c->C1) = I2C_C1_IICEN; // change to Rx mode, intr disabled (does this send STOP if ARBL flagged?)
I2C_ERR_INC(I2C_ERRCNT_ARBL);
if(i2c->user_onError != nullptr) i2c->user_onError(); // run Error callback if ARBL
return;
}
// check if slave ACK'd
else if(status & I2C_S_RXAK)
{
if(idx == 0)
{
i2c->currentStatus = I2C_ADDR_NAK; // NAK on Addr
I2C_ERR_INC(I2C_ERRCNT_ADDR_NAK);
}
else
{
i2c->currentStatus = I2C_DATA_NAK; // NAK on Data
I2C_ERR_INC(I2C_ERRCNT_DATA_NAK);
}
*(i2c->C1) = I2C_C1_IICEN; // send STOP, change to Rx mode, intr disabled
if(i2c->user_onError != nullptr) i2c->user_onError(); // run Error callback if NAK
return;
}
}
// send STOP if configured
if(i2c->currentStop == I2C_STOP)
*(i2c->C1) = I2C_C1_IICEN; // send STOP, change to Rx mode, intr disabled
else
*(i2c->C1) = I2C_C1_IICEN | I2C_C1_MST | I2C_C1_TX; // no STOP, stay in Tx mode, intr disabled
// Set final status
if(idx < i2c->txBufferLength)
{
i2c->currentStatus = I2C_TIMEOUT; // Tx incomplete, mark as timeout
I2C_ERR_INC(I2C_ERRCNT_TIMEOUT);
if(i2c->user_onError != nullptr) i2c->user_onError(); // run Error callback if timeout
}
else
{
i2c->currentStatus = I2C_WAITING; // Tx complete, change to waiting state
if(i2c->user_onTransmitDone != nullptr) i2c->user_onTransmitDone(); // Call Master Tx complete callback
}
}
//
// ISR/DMA mode - non-blocking
//
else if(i2c->opMode == I2C_OP_MODE_ISR || i2c->opMode == I2C_OP_MODE_DMA)
{
// send target addr and enable interrupts
i2c->currentStatus = I2C_SENDING;
i2c->currentStop = sendStop;
i2c->txBufferIndex = 0;
if(i2c->opMode == I2C_OP_MODE_DMA && i2c->txBufferLength >= 5) // limit transfers less than 5 bytes to ISR method
{
// init DMA, let the hack begin
i2c->activeDMA = I2C_DMA_ADDR;
i2c->DMA->sourceBuffer(&i2c->txBuffer[2],i2c->txBufferLength-3); // DMA sends all except first/second/last bytes
i2c->DMA->destination(*(i2c->D));
}
// start ISR
*(i2c->C1) = I2C_C1_IICEN | I2C_C1_IICIE | I2C_C1_MST | I2C_C1_TX; // enable intr
*(i2c->D) = i2c->txBuffer[0]; // writing first data byte will start ISR
}
}
// ------------------------------------------------------------------------------------------------------
// Master Receive - blocking routine with timeout, requests length bytes from slave at address. Receive data will
// be placed in the Rx buffer. i2c_stop parameter can be used to indicate if command should end
// with a STOP (I2C_STOP) or not (I2C_NOSTOP).
// return: #bytes received = success, 0=fail (0 length request, NAK, timeout, or bus error)
// parameters:
// address = target 7bit slave address
// length = number of bytes requested
// i2c_stop = I2C_NOSTOP, I2C_STOP
// timeout = timeout in microseconds
//
size_t i2c_t3::requestFrom_(struct i2cStruct* i2c, uint8_t bus, uint8_t addr, size_t len, i2c_stop sendStop, uint32_t timeout)
{
// exit immediately if request for 0 bytes
if(len == 0) return 0;
sendRequest_(i2c, bus, addr, len, sendStop, timeout);
// wait for completion or timeout
if(finish_(i2c, bus, timeout))
return i2c->rxBufferLength;
else
return 0; // NAK, timeout or bus error
}
// ------------------------------------------------------------------------------------------------------
// Start Master Receive - non-blocking routine, starts request for length bytes from slave at address. Receive
// data will be placed in the Rx buffer. i2c_stop parameter can be used to indicate if
// command should end with a STOP (I2C_STOP) or not (I2C_NOSTOP). Use done() or finish()
// to determine completion and status() to determine success/fail.
// return: none
// parameters:
// address = target 7bit slave address
// length = number of bytes requested
// i2c_stop = I2C_NOSTOP, I2C_STOP
// timeout = timeout in microseconds (only used for Immediate operation)
//
void i2c_t3::sendRequest_(struct i2cStruct* i2c, uint8_t bus, uint8_t addr, size_t len, i2c_stop sendStop, uint32_t timeout)
{
uint8_t status, data, chkTimeout=0, forceImm=0;
// exit immediately if request for 0 bytes or request too large
if(len == 0) return;
if(len > I2C_RX_BUFFER_LENGTH) { i2c->currentStatus=I2C_BUF_OVF; return; }
i2c->reqCount = len; // store request length
i2c->rxBufferIndex = 0; // reset buffer
i2c->rxBufferLength = 0;
timeout = (timeout == 0) ? i2c->defTimeout : timeout;
// clear the status flags
#if defined(__MKL26Z64__) || defined(__MK64FX512__) || defined(__MK66FX1M0__) // LC/3.5/3.6
*(i2c->FLT) |= I2C_FLT_STOPF | I2C_FLT_STARTF; // clear STOP/START intr
*(i2c->FLT) &= ~I2C_FLT_SSIE; // disable STOP/START intr (not used in Master mode)
#endif
*(i2c->S) = I2C_S_IICIF | I2C_S_ARBL; // clear intr, arbl
// try to take control of the bus
if(!acquireBus_(i2c, bus, timeout, forceImm)) return;
//
// Immediate mode - blocking
//
if(i2c->opMode == I2C_OP_MODE_IMM || forceImm)
{
elapsedMicros deltaT;
i2c->currentStatus = I2C_SEND_ADDR;
i2c->currentStop = sendStop;
// Send target address
*(i2c->D) = (addr << 1) | 1; // address + READ
// wait for byte
while(!(*(i2c->S) & I2C_S_IICIF) && (timeout == 0 || deltaT < timeout));
*(i2c->S) = I2C_S_IICIF;
if(timeout && deltaT >= timeout)
{
*(i2c->C1) = I2C_C1_IICEN; // send STOP, change to Rx mode, intr disabled
i2c->currentStatus = I2C_TIMEOUT; // Rx incomplete, mark as timeout
I2C_ERR_INC(I2C_ERRCNT_TIMEOUT);
if(i2c->user_onError != nullptr) i2c->user_onError(); // run Error callback if timeout
return;
}
status = *(i2c->S);
// check arbitration
if(status & I2C_S_ARBL)
{
i2c->currentStatus = I2C_ARB_LOST;
*(i2c->S) = I2C_S_ARBL; // clear arbl flag
// TODO: this is clearly not right, after ARBL it should drop into IMM slave mode if IAAS=1
// Right now Rx message would be ignored regardless of IAAS
*(i2c->C1) = I2C_C1_IICEN; // change to Rx mode, intr disabled (does this send STOP if ARBL flagged?)
I2C_ERR_INC(I2C_ERRCNT_ARBL);
if(i2c->user_onError != nullptr) i2c->user_onError(); // run Error callback if ARBL
return;
}
// check if slave ACK'd
else if(status & I2C_S_RXAK)
{
i2c->currentStatus = I2C_ADDR_NAK; // NAK on Addr
*(i2c->C1) = I2C_C1_IICEN; // send STOP, change to Rx mode, intr disabled
I2C_ERR_INC(I2C_ERRCNT_ADDR_NAK);
if(i2c->user_onError != nullptr) i2c->user_onError(); // run Error callback if NAK
return;
}
else
{
// Slave addr ACK, change to Rx mode
i2c->currentStatus = I2C_RECEIVING;
if(i2c->reqCount == 1)
*(i2c->C1) = I2C_C1_IICEN | I2C_C1_MST | I2C_C1_TXAK; // no STOP, Rx, NAK on recv
else
*(i2c->C1) = I2C_C1_IICEN | I2C_C1_MST; // no STOP, change to Rx
data = *(i2c->D); // dummy read
// Master receive loop
while(i2c->rxBufferLength < i2c->reqCount && i2c->currentStatus == I2C_RECEIVING)
{
while(!(*(i2c->S) & I2C_S_IICIF) && (timeout == 0 || deltaT < timeout));
*(i2c->S) = I2C_S_IICIF;
chkTimeout = (timeout != 0 && deltaT >= timeout);
// check if 2nd to last byte or timeout
if((i2c->rxBufferLength+2) == i2c->reqCount || (chkTimeout && !i2c->timeoutRxNAK))
{
*(i2c->C1) = I2C_C1_IICEN | I2C_C1_MST | I2C_C1_TXAK; // no STOP, Rx, NAK on recv
}
// if last byte or timeout send STOP
if((i2c->rxBufferLength+1) >= i2c->reqCount || (chkTimeout && i2c->timeoutRxNAK))
{
i2c->timeoutRxNAK = 0; // clear flag
// change to Tx mode
*(i2c->C1) = I2C_C1_IICEN | I2C_C1_MST | I2C_C1_TX;
// grab last data
data = *(i2c->D);
i2c->rxBuffer[i2c->rxBufferLength++] = data;
if(i2c->currentStop == I2C_STOP) // NAK then STOP
{
delayMicroseconds(1); // empirical patch, lets things settle before issuing STOP
*(i2c->C1) = I2C_C1_IICEN; // send STOP, change to Rx mode, intr disabled
}
// else NAK no STOP
// Set final status
if(chkTimeout)
{
i2c->currentStatus = I2C_TIMEOUT; // Rx incomplete, mark as timeout
I2C_ERR_INC(I2C_ERRCNT_TIMEOUT);
if(i2c->user_onError != nullptr) i2c->user_onError(); // run Error callback if timeout
}
else
{
i2c->currentStatus = I2C_WAITING; // Rx complete, change to waiting state
if(i2c->user_onReqFromDone != nullptr) i2c->user_onReqFromDone(); // Call Master Rx complete callback
}
}
else
{
// grab next data, not last byte, will ACK
i2c->rxBuffer[i2c->rxBufferLength++] = *(i2c->D);
}
if(chkTimeout) i2c->timeoutRxNAK = 1; // set flag to indicate NAK sent
}
}
}
//
// ISR/DMA mode - non-blocking
//
else if(i2c->opMode == I2C_OP_MODE_ISR || i2c->opMode == I2C_OP_MODE_DMA)
{
// send 1st data and enable interrupts
i2c->currentStatus = I2C_SEND_ADDR;
i2c->currentStop = sendStop;
if(i2c->opMode == I2C_OP_MODE_DMA && i2c->reqCount >= 5) // limit transfers less than 5 bytes to ISR method
{
// init DMA, let the hack begin
i2c->activeDMA = I2C_DMA_ADDR;
i2c->DMA->source(*(i2c->D));
i2c->DMA->destinationBuffer(&i2c->rxBuffer[0],i2c->reqCount-1); // DMA gets all except last byte
}
// start ISR
*(i2c->C1) = I2C_C1_IICEN | I2C_C1_IICIE | I2C_C1_MST | I2C_C1_TX; // enable intr
*(i2c->D) = (addr << 1) | 1; // address + READ
}
}
// ------------------------------------------------------------------------------------------------------
// Get Wire Error - returns "Wire" error code from a failed Tx/Rx command
// return: 0=success, 1=data too long, 2=recv addr NACK, 3=recv data NACK, 4=other error (timeout, arb lost)
//
uint8_t i2c_t3::getError(void)
{
// convert status to Arduino return values (give these a higher priority than buf overflow error)
switch(i2c->currentStatus)
{
case I2C_BUF_OVF: return 1;
case I2C_ADDR_NAK: return 2;
case I2C_DATA_NAK: return 3;
case I2C_ARB_LOST: return 4;
case I2C_TIMEOUT: return 4;
case I2C_NOT_ACQ: return 4;
default: break;
}
if(getWriteError()) return 1; // if write_error was set then flag as buffer overflow
return 0; // no errors
}
// ------------------------------------------------------------------------------------------------------
// Done Check - returns simple complete/not-complete value to indicate I2C status
// return: 1=Tx/Rx complete (with or without errors), 0=still running
//
uint8_t i2c_t3::done_(struct i2cStruct* i2c)
{
return (i2c->currentStatus < I2C_SENDING);
}
// ------------------------------------------------------------------------------------------------------
// Finish - blocking routine with timeout, loops until Tx/Rx is complete or timeout occurs
// return: 1=success (Tx or Rx completed, no error), 0=fail (NAK, timeout or Arb Lost)
// parameters:
// timeout = timeout in microseconds
//
uint8_t i2c_t3::finish_(struct i2cStruct* i2c, uint8_t bus, uint32_t timeout)
{
elapsedMicros deltaT;
// update timeout
timeout = (timeout == 0) ? i2c->defTimeout : timeout;
// wait for completion or timeout
deltaT = 0;
while(!done_(i2c) && (timeout == 0 || deltaT < timeout));
// DMA mode and timeout
if(timeout != 0 && deltaT >= timeout && i2c->opMode == I2C_OP_MODE_DMA && i2c->activeDMA != I2C_DMA_OFF)
{
// If DMA mode times out, then wait for transfer to end then mark it as timeout.
// This is done this way because abruptly ending the DMA seems to cause
// the I2C_S_BUSY flag to get stuck, and I cannot find a reliable way to clear it.
while(!done_(i2c));
i2c->currentStatus = I2C_TIMEOUT;
}
// check exit status, if not done then timeout occurred
if(!done_(i2c)) i2c->currentStatus = I2C_TIMEOUT; // set to timeout state
// delay to allow bus to settle - allow Timeout or STOP to complete and be recognized. Timeouts must
// propagate through ISR, and STOP must be recognized on both
// Master and Slave sides
delayMicroseconds(4);
// note that onTransmitDone, onReqFromDone, onError callbacks are handled in ISR, this is done
// because use of this function is optional on background transfers
if(i2c->currentStatus == I2C_WAITING) return 1;
return 0;
}
// ------------------------------------------------------------------------------------------------------
// Write - write data to Tx buffer
// return: #bytes written = success, 0=fail
// parameters:
// data = data byte
//
size_t i2c_t3::write(uint8_t data)
{
if(i2c->txBufferLength < I2C_TX_BUFFER_LENGTH)
{
i2c->txBuffer[i2c->txBufferLength++] = data;
return 1;
}
setWriteError();
return 0;
}
// ------------------------------------------------------------------------------------------------------
// Write Array - write count number of bytes from data array to Tx buffer
// return: #bytes written = success, 0=fail
// parameters:
// data = pointer to uint8_t array of data
// count = number of bytes to write
//
size_t i2c_t3::write(const uint8_t* data, size_t count)
{
if(i2c->txBufferLength < I2C_TX_BUFFER_LENGTH)
{
size_t avail = I2C_TX_BUFFER_LENGTH - i2c->txBufferLength;
uint8_t* dest = i2c->txBuffer + i2c->txBufferLength;
if(count > avail)
{
count = avail; // truncate to space avail if needed
setWriteError();
}
memcpy(dest, data, count);
i2c->txBufferLength += count;
return count;
}
setWriteError();
return 0;
}
// ------------------------------------------------------------------------------------------------------
// Read - returns next data byte (signed int) from Rx buffer
// return: data, -1 if buffer empty
//
int i2c_t3::read_(struct i2cStruct* i2c)
{
if(i2c->rxBufferIndex >= i2c->rxBufferLength) return -1;
return i2c->rxBuffer[i2c->rxBufferIndex++];
}
// ------------------------------------------------------------------------------------------------------
// Read Array - read count number of bytes from Rx buffer to data array
// return: #bytes read
// parameters:
// data = pointer to uint8_t array of data
// count = number of bytes to write
//
size_t i2c_t3::read_(struct i2cStruct* i2c, uint8_t* data, size_t count)
{
if(i2c->rxBufferLength > i2c->rxBufferIndex)
{
size_t avail = i2c->rxBufferLength - i2c->rxBufferIndex;
uint8_t* src = i2c->rxBuffer + i2c->rxBufferIndex;
if(count > avail) count = avail; // truncate to data avail if needed
memcpy(data, src, count);
i2c->rxBufferIndex += count;
return count;
}
return 0;
}
// ------------------------------------------------------------------------------------------------------
// Peek - returns next data byte (signed int) from Rx buffer without removing it from Rx buffer
// return: data, -1 if buffer empty
//
int i2c_t3::peek_(struct i2cStruct* i2c)
{
if(i2c->rxBufferIndex >= i2c->rxBufferLength) return -1;
return i2c->rxBuffer[i2c->rxBufferIndex];
}
// ------------------------------------------------------------------------------------------------------
// Read Byte - returns next data byte (uint8_t) from Rx buffer
// return: data, 0 if buffer empty
//
uint8_t i2c_t3::readByte_(struct i2cStruct* i2c)
{
if(i2c->rxBufferIndex >= i2c->rxBufferLength) return 0;
return i2c->rxBuffer[i2c->rxBufferIndex++];
}
// ------------------------------------------------------------------------------------------------------
// Peek Byte - returns next data byte (uint8_t) from Rx buffer without removing it from Rx buffer
// return: data, 0 if buffer empty
//
uint8_t i2c_t3::peekByte_(struct i2cStruct* i2c)
{
if(i2c->rxBufferIndex >= i2c->rxBufferLength) return 0;
return i2c->rxBuffer[i2c->rxBufferIndex];
}
// ======================================================================================================
// ------------------------------------------------------------------------------------------------------
// I2C Interrupt Service Routine
// ------------------------------------------------------------------------------------------------------
// ======================================================================================================
void i2c0_isr(void) // I2C0 ISR
{
I2C0_INTR_FLAG_ON;
i2c_isr_handler(&(i2c_t3::i2cData[0]),0);
I2C0_INTR_FLAG_OFF;
}
#if I2C_BUS_NUM >= 2
void i2c1_isr(void) // I2C1 ISR
{
I2C1_INTR_FLAG_ON;
i2c_isr_handler(&(i2c_t3::i2cData[1]),1);
I2C1_INTR_FLAG_OFF;
}
#endif
#if I2C_BUS_NUM >= 3
void i2c2_isr(void) // I2C2 ISR
{
I2C2_INTR_FLAG_ON;
i2c_isr_handler(&(i2c_t3::i2cData[2]),2);
I2C2_INTR_FLAG_OFF;
}
#endif
#if I2C_BUS_NUM >= 4
void i2c3_isr(void) // I2C3 ISR
{
I2C3_INTR_FLAG_ON;
i2c_isr_handler(&(i2c_t3::i2cData[3]),3);
I2C3_INTR_FLAG_OFF;
}
#endif
//
// I2C ISR base handler
//
void i2c_isr_handler(struct i2cStruct* i2c, uint8_t bus)
{
uint8_t status, c1, data;
i2c_t3::isrActive++;
status = *(i2c->S);
c1 = *(i2c->C1);
#if defined(__MKL26Z64__) || defined(__MK64FX512__) || defined(__MK66FX1M0__) // LC/3.5/3.6
uint8_t flt = *(i2c->FLT); // store flags
#endif
if(c1 & I2C_C1_MST)
{
//
// Master Mode
//
if(c1 & I2C_C1_TX)
{
if(i2c->activeDMA == I2C_DMA_BULK || i2c->activeDMA == I2C_DMA_LAST)
{
if(i2c->DMA->complete() && i2c->activeDMA == I2C_DMA_BULK)
{
// clear DMA interrupt, final byte should trigger another ISR
i2c->DMA->clearInterrupt();
*(i2c->C1) = I2C_C1_IICEN | I2C_C1_IICIE | I2C_C1_MST | I2C_C1_TX; // intr en, Tx mode, DMA disabled
// DMA says complete at the beginning of its last byte, need to
// wait until end of its last byte to re-engage ISR
i2c->activeDMA = I2C_DMA_LAST;
*(i2c->S) = I2C_S_IICIF; // clear intr
}
else if(i2c->activeDMA == I2C_DMA_LAST)
{
// wait for TCF
while(!(*(i2c->S) & I2C_S_TCF));
// clear DMA, only do this after TCF
i2c->DMA->clearComplete();
// re-engage ISR for last byte
i2c->activeDMA = I2C_DMA_OFF;
i2c->txBufferIndex = i2c->txBufferLength-1;
*(i2c->D) = i2c->txBuffer[i2c->txBufferIndex];
*(i2c->S) = I2C_S_IICIF; // clear intr
}
else if(i2c->DMA->error())
{
i2c->DMA->clearError();
i2c->DMA->clearInterrupt();
i2c->activeDMA = I2C_DMA_OFF;
i2c->currentStatus = I2C_DMA_ERR;
I2C_ERR_INC(I2C_ERRCNT_DMA_ERR);
// check arbitration
if(status & I2C_S_ARBL)
{
// Arbitration Lost
i2c->currentStatus = I2C_ARB_LOST;
I2C_ERR_INC(I2C_ERRCNT_ARBL);
*(i2c->S) = I2C_S_ARBL; // clear arbl flag
i2c->txBufferIndex = 0; // reset Tx buffer index to prepare for resend
// TODO does this need to check IAAS and drop to Slave Rx? if so set Rx + dummy read. not sure if this would work for DMA
}
*(i2c->C1) = I2C_C1_IICEN; // change to Rx mode, intr disabled, DMA disabled
*(i2c->S) = I2C_S_IICIF; // clear intr
if(i2c->user_onError != nullptr) i2c->user_onError(); // run Error callback if DMA error or ARBL
}
i2c_t3::isrActive--;
return;
} // end DMA Tx
else
{
// Continue Master Transmit
// check if Master Tx or Rx
if(i2c->currentStatus == I2C_SENDING)
{
// check arbitration
if(status & I2C_S_ARBL)
{
// Arbitration Lost
i2c->activeDMA = I2C_DMA_OFF; // clear pending DMA (if happens on address byte)
i2c->currentStatus = I2C_ARB_LOST;
*(i2c->S) = I2C_S_ARBL; // clear arbl flag
*(i2c->C1) = I2C_C1_IICEN; // change to Rx mode, intr disabled (does this send STOP if ARBL flagged?)
i2c->txBufferIndex = 0; // reset Tx buffer index to prepare for resend
// TODO does this need to check IAAS and drop to Slave Rx? if so set Rx + dummy read.
*(i2c->S) = I2C_S_IICIF; // clear intr
I2C_ERR_INC(I2C_ERRCNT_ARBL);
if(i2c->user_onError != nullptr) i2c->user_onError(); // run Error callback if ARBL
}
// check if slave ACK'd
else if(status & I2C_S_RXAK)
{
i2c->activeDMA = I2C_DMA_OFF; // clear pending DMA (if happens on address byte)
if(i2c->txBufferIndex == 0)
{
i2c->currentStatus = I2C_ADDR_NAK; // NAK on Addr
I2C_ERR_INC(I2C_ERRCNT_ADDR_NAK);
}
else
{
i2c->currentStatus = I2C_DATA_NAK; // NAK on Data
I2C_ERR_INC(I2C_ERRCNT_DATA_NAK);
}
// send STOP, change to Rx mode, intr disabled
// note: Slave NAK is an error, so send STOP regardless of setting
*(i2c->C1) = I2C_C1_IICEN;
*(i2c->S) = I2C_S_IICIF; // clear intr
if(i2c->user_onError != nullptr) i2c->user_onError(); // run Error callback if NAK
}
else
{
// check if last byte transmitted
if(++i2c->txBufferIndex >= i2c->txBufferLength)
{
// Tx complete, change to waiting state
i2c->currentStatus = I2C_WAITING;
// send STOP if configured
if(i2c->currentStop == I2C_STOP)
*(i2c->C1) = I2C_C1_IICEN; // send STOP, change to Rx mode, intr disabled
else
*(i2c->C1) = I2C_C1_IICEN | I2C_C1_MST | I2C_C1_TX; // no STOP, stay in Tx mode, intr disabled
// run TransmitDone callback when done
*(i2c->S) = I2C_S_IICIF; // clear intr
if(i2c->user_onTransmitDone != nullptr) i2c->user_onTransmitDone();
}
else if(i2c->activeDMA == I2C_DMA_ADDR)
{
// Start DMA
i2c->activeDMA = I2C_DMA_BULK;
*(i2c->C1) = I2C_C1_IICEN | I2C_C1_IICIE | I2C_C1_MST | I2C_C1_TX | I2C_C1_DMAEN; // intr en, Tx mode, DMA en
i2c->DMA->enable();
*(i2c->D) = i2c->txBuffer[1]; // DMA will start on next request
*(i2c->S) = I2C_S_IICIF; // clear intr
}
else
{
// ISR transmit next byte
*(i2c->D) = i2c->txBuffer[i2c->txBufferIndex];
*(i2c->S) = I2C_S_IICIF; // clear intr
}
}
i2c_t3::isrActive--;
return;
}
else if(i2c->currentStatus == I2C_SEND_ADDR)
{
// Master Receive, addr sent
if(status & I2C_S_ARBL)
{
// Arbitration Lost
i2c->currentStatus = I2C_ARB_LOST;
*(i2c->S) = I2C_S_ARBL; // clear arbl flag
*(i2c->C1) = I2C_C1_IICEN; // change to Rx mode, intr disabled (does this send STOP if ARBL flagged?)
// TODO does this need to check IAAS and drop to Slave Rx? if so set Rx + dummy read. not sure if this would work for DMA
*(i2c->S) = I2C_S_IICIF; // clear intr
I2C_ERR_INC(I2C_ERRCNT_ARBL);
if(i2c->user_onError != nullptr) i2c->user_onError(); // run Error callback if ARBL
}
else if(status & I2C_S_RXAK)
{
// Slave addr NAK
i2c->currentStatus = I2C_ADDR_NAK; // NAK on Addr
// send STOP, change to Rx mode, intr disabled
// note: Slave NAK is an error, so send STOP regardless of setting
*(i2c->C1) = I2C_C1_IICEN;
*(i2c->S) = I2C_S_IICIF; // clear intr
I2C_ERR_INC(I2C_ERRCNT_ADDR_NAK);
if(i2c->user_onError != nullptr) i2c->user_onError(); // run Error callback if NAK
}
else if(i2c->activeDMA == I2C_DMA_ADDR)
{
// Start DMA
i2c->activeDMA = I2C_DMA_BULK;
*(i2c->C1) = I2C_C1_IICEN | I2C_C1_IICIE | I2C_C1_MST | I2C_C1_DMAEN; // intr en, no STOP, change to Rx, DMA en
i2c->DMA->enable();
data = *(i2c->D); // dummy read
*(i2c->S) = I2C_S_IICIF; // clear intr
}
else
{
// Slave addr ACK, change to Rx mode
i2c->currentStatus = I2C_RECEIVING;
if(i2c->reqCount == 1)
*(i2c->C1) = I2C_C1_IICEN | I2C_C1_IICIE | I2C_C1_MST | I2C_C1_TXAK; // no STOP, Rx, NAK on recv
else
*(i2c->C1) = I2C_C1_IICEN | I2C_C1_IICIE | I2C_C1_MST; // no STOP, change to Rx
data = *(i2c->D); // dummy read
*(i2c->S) = I2C_S_IICIF; // clear intr
}
i2c_t3::isrActive--;
return;
}
else if(i2c->currentStatus == I2C_TIMEOUT)
{
// send STOP if configured
if(i2c->currentStop == I2C_STOP)
*(i2c->C1) = I2C_C1_IICEN; // send STOP, change to Rx mode, intr disabled
else
*(i2c->C1) = I2C_C1_IICEN | I2C_C1_MST | I2C_C1_TX; // no STOP, stay in Tx mode, intr disabled
*(i2c->S) = I2C_S_IICIF; // clear intr
I2C_ERR_INC(I2C_ERRCNT_TIMEOUT);
if(i2c->user_onError != nullptr) i2c->user_onError(); // run Error callback if timeout
i2c_t3::isrActive--;
return;
}
else
{
// Should not be in Tx mode if not sending
// send STOP, change to Rx mode, intr disabled
*(i2c->C1) = I2C_C1_IICEN;
*(i2c->S) = I2C_S_IICIF; // clear intr
i2c_t3::isrActive--;
return;
}
} // end ISR Tx
}
else
{
// Continue Master Receive
//
if(i2c->activeDMA == I2C_DMA_BULK || i2c->activeDMA == I2C_DMA_LAST)
{
if(i2c->DMA->complete() && i2c->activeDMA == I2C_DMA_BULK) // 2nd to last byte
{
// clear DMA interrupt, final byte should trigger another ISR
i2c->DMA->clearInterrupt();
*(i2c->C1) = I2C_C1_IICEN | I2C_C1_IICIE | I2C_C1_MST | I2C_C1_TXAK; // intr en, Rx mode, DMA disabled, NAK on recv
i2c->activeDMA = I2C_DMA_LAST;
*(i2c->S) = I2C_S_IICIF; // clear intr
}
else if(i2c->activeDMA == I2C_DMA_LAST) // last byte
{
// clear DMA
i2c->DMA->clearComplete();
i2c->activeDMA = I2C_DMA_OFF;
// change to Tx mode
*(i2c->C1) = I2C_C1_IICEN | I2C_C1_MST | I2C_C1_TX;
// grab last data
i2c->rxBufferLength = i2c->reqCount-1;
i2c->rxBuffer[i2c->rxBufferLength++] = *(i2c->D);
if(i2c->currentStop == I2C_STOP) // NAK then STOP
{
delayMicroseconds(1); // empirical patch, lets things settle before issuing STOP
*(i2c->C1) = I2C_C1_IICEN; // send STOP, change to Rx mode, intr disabled
}
// else NAK no STOP
*(i2c->S) = I2C_S_IICIF; // clear intr
i2c->currentStatus = I2C_WAITING; // Rx complete, change to waiting state
if(i2c->user_onReqFromDone != nullptr) i2c->user_onReqFromDone(); // Call Master Rx complete callback
}
else if(i2c->DMA->error()) // not sure what would cause this...
{
i2c->DMA->clearError();
i2c->DMA->clearInterrupt();
i2c->activeDMA = I2C_DMA_OFF;
i2c->currentStatus = I2C_DMA_ERR;
*(i2c->C1) = I2C_C1_IICEN; // change to Rx mode, intr disabled, DMA disabled
*(i2c->S) = I2C_S_IICIF; // clear intr
I2C_ERR_INC(I2C_ERRCNT_DMA_ERR);
if(i2c->user_onError != nullptr) i2c->user_onError(); // run Error callback if DMA error
}
i2c_t3::isrActive--;
return;
}
else
{
// check if 2nd to last byte or timeout
if((i2c->rxBufferLength+2) == i2c->reqCount || (i2c->currentStatus == I2C_TIMEOUT && !i2c->timeoutRxNAK))
{
*(i2c->C1) = I2C_C1_IICEN | I2C_C1_IICIE | I2C_C1_MST | I2C_C1_TXAK; // no STOP, Rx, NAK on recv
}
// if last byte or timeout send STOP
if((i2c->rxBufferLength+1) >= i2c->reqCount || (i2c->currentStatus == I2C_TIMEOUT && i2c->timeoutRxNAK))
{
i2c->timeoutRxNAK = 0; // clear flag
// change to Tx mode
*(i2c->C1) = I2C_C1_IICEN | I2C_C1_MST | I2C_C1_TX;
// grab last data
i2c->rxBuffer[i2c->rxBufferLength++] = *(i2c->D);
if(i2c->currentStop == I2C_STOP) // NAK then STOP
{
delayMicroseconds(1); // empirical patch, lets things settle before issuing STOP
*(i2c->C1) = I2C_C1_IICEN; // send STOP, change to Rx mode, intr disabled
}
// else NAK no STOP
*(i2c->S) = I2C_S_IICIF; // clear intr
// Rx complete
if(i2c->currentStatus == I2C_TIMEOUT)
{
I2C_ERR_INC(I2C_ERRCNT_TIMEOUT);
if(i2c->user_onError != nullptr) i2c->user_onError(); // run Error callback if timeout
}
else
{
i2c->currentStatus = I2C_WAITING;
if(i2c->user_onReqFromDone != nullptr) i2c->user_onReqFromDone(); // Call Master Rx complete callback
}
}
else
{
// grab next data, not last byte, will ACK
i2c->rxBuffer[i2c->rxBufferLength++] = *(i2c->D);
*(i2c->S) = I2C_S_IICIF; // clear intr
}
if(i2c->currentStatus == I2C_TIMEOUT && !i2c->timeoutRxNAK)
i2c->timeoutRxNAK = 1; // set flag to indicate NAK sent
i2c_t3::isrActive--;
return;
}
}
}
else
{
//
// Slave Mode
//
// ARBL makes no sense on Slave, but this might get set if there is a pullup problem and
// SCL/SDA get stuck. This is primarily to guard against ARBL flag getting stuck.
if(status & I2C_S_ARBL)
{
// Arbitration Lost
*(i2c->S) = I2C_S_ARBL; // clear arbl flag
if(!(status & I2C_S_IAAS))
{
#if defined(__MKL26Z64__) || defined(__MK64FX512__) || defined(__MK66FX1M0__) // LC/3.5/3.6
*(i2c->FLT) |= I2C_FLT_STOPF | I2C_FLT_STARTF; // clear STOP/START intr
#endif
*(i2c->S) = I2C_S_IICIF; // clear intr
i2c_t3::isrActive--;
return;
}
}
if(status & I2C_S_IAAS)
{
// If in Slave Rx already, then RepSTART occured, run callback
if(i2c->currentStatus == I2C_SLAVE_RX && i2c->user_onReceive != nullptr)
{
i2c->rxBufferIndex = 0;
i2c->user_onReceive(i2c->rxBufferLength);
}
// Is Addressed As Slave
if(status & I2C_S_SRW)
{
// Addressed Slave Transmit
//
i2c->currentStatus = I2C_SLAVE_TX;
i2c->txBufferLength = 0;
*(i2c->C1) = I2C_C1_IICEN | I2C_C1_IICIE | I2C_C1_TX;
i2c->rxAddr = (*(i2c->D) >> 1); // read to get target addr
if(i2c->user_onRequest != nullptr) i2c->user_onRequest(); // load Slave Tx buffer with data
if(i2c->txBufferLength == 0) i2c->txBuffer[0] = 0; // send 0's if buffer empty
*(i2c->D) = i2c->txBuffer[0]; // send first data
i2c->txBufferIndex = 1;
}
else
{
// Addressed Slave Receive
//
// setup SDA-rising ISR - required for STOP detection in Slave Rx mode for 3.0/3.1/3.2
#if defined(__MK20DX256__) && I2C_BUS_NUM == 2 // 3.1/3.2 (dual-bus)
i2c->irqCount = 0;
attachInterrupt(i2c->currentSDA, (bus == 0) ? i2c_t3::sda0_rising_isr : i2c_t3::sda1_rising_isr, RISING);
#elif defined(__MK20DX128__) || defined(__MK20DX256__) // 3.0/3.1/3.2 (single-bus)
i2c->irqCount = 0;
attachInterrupt(i2c->currentSDA, i2c_t3::sda0_rising_isr, RISING);
#elif defined(__MKL26Z64__) || defined(__MK64FX512__) || defined(__MK66FX1M0__)
*(i2c->FLT) |= I2C_FLT_SSIE; // enable START/STOP intr for LC/3.5/3.6
#endif
i2c->currentStatus = I2C_SLAVE_RX;
i2c->rxBufferLength = 0;
*(i2c->C1) = I2C_C1_IICEN | I2C_C1_IICIE;
i2c->rxAddr = (*(i2c->D) >> 1); // read to get target addr
}
#if defined(__MKL26Z64__) || defined(__MK64FX512__) || defined(__MK66FX1M0__) // LC/3.5/3.6
*(i2c->FLT) |= I2C_FLT_STOPF | I2C_FLT_STARTF; // clear STOP/START intr
#endif
*(i2c->S) = I2C_S_IICIF; // clear intr
i2c_t3::isrActive--;
return;
}
if(c1 & I2C_C1_TX)
{
// Continue Slave Transmit
if((status & I2C_S_RXAK) == 0)
{
// Master ACK'd previous byte
if(i2c->txBufferIndex < i2c->txBufferLength)
data = i2c->txBuffer[i2c->txBufferIndex++];
else
data = 0; // send 0's if buffer empty
*(i2c->D) = data;
*(i2c->C1) = I2C_C1_IICEN | I2C_C1_IICIE | I2C_C1_TX;
}
else
{
// Master did not ACK previous byte
*(i2c->C1) = I2C_C1_IICEN | I2C_C1_IICIE; // switch to Rx mode
data = *(i2c->D); // dummy read
i2c->currentStatus = I2C_WAITING;
}
}
else if(i2c->currentStatus == I2C_SLAVE_RX)
{
#if defined(__MKL26Z64__) || defined(__MK64FX512__) || defined(__MK66FX1M0__) // LC/3.5/3.6
if(flt & (I2C_FLT_STOPF|I2C_FLT_STARTF)) // STOP/START detected, run callback
{
// LC (MKL26) appears to have the same I2C_FLT reg definition as 3.6 (K66)
// There is both STOPF and STARTF and they are both enabled via SSIE, and they must both
// be cleared in order to work
*(i2c->FLT) |= I2C_FLT_STOPF | I2C_FLT_STARTF; // clear STOP/START intr
*(i2c->FLT) &= ~I2C_FLT_SSIE; // disable STOP/START intr (will re-enable on next IAAS)
*(i2c->S) = I2C_S_IICIF; // clear intr
i2c->currentStatus = I2C_WAITING;
// Slave Rx complete, run callback
if(i2c->user_onReceive != nullptr)
{
i2c->rxBufferIndex = 0;
i2c->user_onReceive(i2c->rxBufferLength);
}
i2c_t3::isrActive--;
return;
}
#endif
// Continue Slave Receive
//
// setup SDA-rising ISR - required for STOP detection in Slave Rx mode for 3.0/3.1/3.2
#if defined(__MK20DX256__) && I2C_BUS_NUM == 2 // 3.1/3.2 (dual-bus)
i2c->irqCount = 0;
attachInterrupt(i2c->currentSDA, (bus == 0) ? i2c_t3::sda0_rising_isr : i2c_t3::sda1_rising_isr, RISING);
#elif defined(__MK20DX128__) || defined(__MK20DX256__) // 3.0/3.1/3.2 (single-bus)
i2c->irqCount = 0;
attachInterrupt(i2c->currentSDA, i2c_t3::sda0_rising_isr, RISING);
#endif
data = *(i2c->D);
if(i2c->rxBufferLength < I2C_RX_BUFFER_LENGTH)
i2c->rxBuffer[i2c->rxBufferLength++] = data;
}
#if defined(__MKL26Z64__) || defined(__MK64FX512__) || defined(__MK66FX1M0__) // LC/3.5/3.6
*(i2c->FLT) |= I2C_FLT_STOPF | I2C_FLT_STARTF; // clear STOP/START intr
#endif
*(i2c->S) = I2C_S_IICIF; // clear intr
}
}
#if defined(__MK20DX128__) || defined(__MK20DX256__) // 3.0/3.1/3.2
// ------------------------------------------------------------------------------------------------------
// SDA-Rising Interrupt Service Routine - 3.0/3.1/3.2 only
//
// Detects the stop condition that terminates a slave receive transfer.
//
// I2C0 SDA ISR
void i2c_t3::sda0_rising_isr(void)
{
i2c_t3::sda_rising_isr_handler(&(i2c_t3::i2cData[0]),0);
}
#if I2C_BUS_NUM >= 2
// I2C1 SDA ISR
void i2c_t3::sda1_rising_isr(void)
{
i2c_t3::sda_rising_isr_handler(&(i2c_t3::i2cData[1]),1);
}
#endif
//
// SDA ISR base handler
//
void i2c_t3::sda_rising_isr_handler(struct i2cStruct* i2c, uint8_t bus)
{
uint8_t status = *(i2c->S); // capture status first, can change if ISR is too slow
if(!(status & I2C_S_BUSY))
{
i2c->currentStatus = I2C_WAITING;
detachInterrupt(i2c->currentSDA);
if(i2c->user_onReceive != nullptr)
{
i2c->rxBufferIndex = 0;
i2c->user_onReceive(i2c->rxBufferLength);
}
}
else
{
if(++(i2c->irqCount) >= 2 || !(i2c->currentMode == I2C_SLAVE))
detachInterrupt(i2c->currentSDA);
}
}
#endif // sda_rising_isr
// ------------------------------------------------------------------------------------------------------
// Instantiate
//
i2c_t3 Wire = i2c_t3(0); // I2C0
#if I2C_BUS_NUM >= 2
i2c_t3 Wire1 = i2c_t3(1); // I2C1
#endif
#if I2C_BUS_NUM >= 3
i2c_t3 Wire2 = i2c_t3(2); // I2C2
#endif
#if I2C_BUS_NUM >= 4
i2c_t3 Wire3 = i2c_t3(3); // I2C3
#endif
#endif // i2c_t3
/*
------------------------------------------------------------------------------------------------------
Changelog
------------------------------------------------------------------------------------------------------
- (v11.0) Modified 01Dec18 by Brian (nox771 at gmail.com)
- Added state variables and modified pinConfigure_() to recognize unconfigured SCL/SDA pins,
allowing for setSCL()/setSDA() prior to begin(), which was previously blocked by bus busy
check on unconfigured pins.
- Header change to MIT permissive license
- (v10.1) Modified 02Jan18 by Brian (nox771 at gmail.com)
- Added User #define to disable priority checks entirely
- Added i2c_t3::isrActive flag to dynamically disable priority checks during ISR & callbacks.
This is to prevent runaway priority escalation in cases of callbacks with nested Wire calls.
- (v10.0) Modified 21Oct17 by Brian (nox771 at gmail.com)
- Default assignments have been added to many functions for pins/pullup/rate/op_mode, so
all those parameters are now optional in many function calls (marked ^ below)
- Unbound SCL/SDA pin assignment. Pins can be specified with either i2c_pins enum or by direct
SCL,SDA pin definition (using any valid SCL and SDA pin). New function summary is:
- begin(mode, address1, ^i2c_pins, ^i2c_pullup, ^rate, ^i2c_op_mode)
- begin(mode, address1, ^pinSCL, ^pinSDA, ^i2c_pullup, ^rate, ^i2c_op_mode)
- pinConfigure(i2c_pins, ^pullup)
- pinConfigure(pinSCL, pinSDA, ^pullup)
- setSCL(pin)
- setSDA(pin)
- getSCL()
- getSDA()
Note: internal to i2c structure, currentPins has been replaced by currentSCL and currentSDA
- Added Master callback functions for completion of transfers. Primarily for
sendTransmission/sendRequest, but these will also work on foreground commands
endTransmission/requestFrom. Also added an Error callback for Master bus errors.
- onTransmitDone(function) - where function() is called when Master Transmit is complete
- onReqFromDone(function) - where function() is called when Master Receive is complete
- onError(function) - where function() is called upon any I2C error which terminates the
Master bus operation (eg. NAK, timeout, acquire fail, etc)
- Fixed blocking conditions that could occur in immediate mode
- Added error counters which may be optionally enabled via I2C_ERROR_COUNTERS define. When
enabled it will track (Master mode only): Reset Bus (auto-retry only), Timeout, Addr NAK,
Data NAK, Arb Lost, Bus Not Acquired, DMA Errors.
- i2c_err_count enum, getErrorCount(), and zeroErrorCount() functions added
- (v9.4) Modified 01Oct17 by Brian (nox771 at gmail.com)
- Fixed Slave ISR for LC/3.5/3.6 not properly recognizing RepSTART
- Fixed nested Wire calls during Slave ISR receive (calling Wire inside Wire1 Slave ISR)
- Added uint8_t and char array read functions - Wire.read(databuf, count);
- (v9.3) Modified 20Sep17 by Brian (nox771 at gmail.com)
- Fixed Slave ISR for LC/3.5/3.6
- (v9.2) Modified 29Dec16 by Brian (nox771 at gmail.com)
- improved resetBus() function to reset C1 state (thanks hw999)
- (v9.1) Modified 16Oct16 by Brian (nox771 at gmail.com)
- applied two fixes due to bug reports:
- removed I2C_F_DIV120 setting (120 divide-ratio) for I2C clock
- disabled I2C_AUTO_RETRY by default (setting remains but must be manually enabled)
- (v9) Modified 01Jul16 by Brian (nox771 at gmail.com)
- Added support for Teensy 3.5/3.6:
- fully supported (Master/Slave modes, IMM/ISR/DMA operation)
- supports all available pin/bus options on Wire/Wire1/Wire2/Wire3
- Fixed LC slave bug, whereby it was incorrectly detecting STOPs directed to other slaves
- I2C rate is now set using a much more flexible method than previously used (this is partially
motivated by increasing device count and frequencies). As a result, the fixed set of rate
enums are no longer needed (however they are currently still supported), and desired I2C
frequency can be directly specified, eg. for 400kHz, I2C_RATE_400 can be replaced by 400000.
Some setRate() functions are deprecated due to these changes.
- (v8) Modified 02Apr15 by Brian (nox771 at gmail.com)
- added support for Teensy LC:
- fully supported (Master/Slave modes, IMM/ISR/DMA operation)
- Wire: pins 16/17 or 18/19, rate limited to I2C_RATE_1200
- Wire1: pins 22/23, rate limited to I2C_RATE_2400
- added timeout on acquiring bus (prevents lockup when bus cannot be acquired)
- added setDefaultTimeout() function for setting the default timeout to apply to all commands
- added resetBus() function for toggling SCL to release stuck Slave devices
- added setRate(rate) function, similar to setClock(freq), but using rate specifiers (does not
require specifying busFreq)
- added I2C_AUTO_RETRY user define
- (v7) Modified 09Jan15 by Brian (nox771 at gmail.com)
- added support for F_BUS frequencies: 60MHz, 56MHz, 48MHz, 36MHz, 24MHz, 16MHz, 8MHz, 4MHz, 2MHz
- added new rates: I2C_RATE_1800, I2C_RATE_2800, I2C_RATE_3000
- added new priority escalation - in cases where I2C ISR is blocked by having a lower priority than
calling function, the I2C will either adjust I2C ISR to a higher
priority, or switch to Immediate mode as needed.
- added new operating mode control - I2C can be set to operate in ISR mode, DMA mode (Master only),
or Immediate Mode (Master only)
- added new begin() functions to allow setting the initial operating mode:
- begin(i2c_mode mode, uint8_t address, i2c_pins pins, i2c_pullup pullup, i2c_rate rate,
i2c_op_mode opMode)
- begin(i2c_mode mode, uint8_t address1, uint8_t address2, i2c_pins pins, i2c_pullup pullup,
i2c_rate rate, i2c_op_mode opMode)
- added new functions:
- uint8_t setOpMode(i2c_op_mode opMode) - used to change operating mode on the fly
(only when bus is idle)
- void sendTransmission() - non-blocking Tx with implicit I2C_STOP, added for symmetry
with endTransmission()
- uint8_t setRate(uint32_t busFreq, i2c_rate rate) - used to set I2C clock dividers to get
desired rate, i2c_rate argument
- uint8_t setRate(uint32_t busFreq, uint32_t i2cFreq) - used to set I2C clock dividers to get
desired SCL freq, uint32_t argument
(quantized to nearest i2c_rate)
- added new Wire compatibility functions:
- void setClock(uint32_t i2cFreq) - (note: degenerate form of setRate() with busFreq == F_BUS)
- uint8_t endTransmission(uint8_t sendStop)
- uint8_t requestFrom(uint8_t addr, uint8_t len)
- uint8_t requestFrom(uint8_t addr, uint8_t len, uint8_t sendStop)
- fixed bug in Slave Range code whereby onRequest() callback occurred prior to updating rxAddr
instead of after
- fixed bug in arbitration, was missing from Master Tx mode
- removed I2C1 defines (now included in kinetis.h)
- removed all debug code (eliminates rbuf dependency)
- (v6) Modified 16Jan14 by Brian (nox771 at gmail.com)
- all new structure using dereferenced pointers instead of hardcoding. This allows functions
(including ISRs) to be reused across multiple I2C buses. Most functions moved to static,
which in turn are called by inline user functions. Added new struct (i2cData) for holding all
bus information.
- added support for Teensy 3.1 and I2C1 interface on pins 29/30 and 26/31.
- added header define (I2C_BUS_ENABLE n) to control number of enabled buses (eg. both I2C0 & I2C1
or just I2C0). When using only I2C0 the code and ram usage will be lower.
- added interrupt flag (toggles pin high during ISR) with independent defines for I2C0 and
I2C1 (refer to header file), useful for logic analyzer trigger
- (v5) Modified 09Jun13 by Brian (nox771 at gmail.com)
- fixed bug in ISR timeout code in which timeout condition could fail to reset in certain cases
- fixed bug in Slave mode in sda_rising_isr attach, whereby it was not getting attached on the addr byte
- moved debug routines so they are entirely defined internal to the library (no end user code req'd)
- debug routines now use IntervalTimer library
- added support for range of Slave addresses
- added getRxAddr() for Slave using addr range to determine its called address
- removed virtual keyword from all functions (is not a base class)
- (v1-v4) Modified 26Feb13 by Brian (nox771 at gmail.com)
- Reworked begin function:
- added option for pins to use (SCL:SDA on 19:18 or 16:17 - note pin order difference)
- added option for internal pullup - as mentioned in previous code pullup is very strong,
approx 190 ohms, but is possibly useful for high speed I2C
- added option for rates - 100kHz, 200kHz, 300kHz, 400kHz, 600kHz, 800kHz, 1MHz, 1.2MHz, <-- 24/48MHz bus
1.5MHz, 2.0MHz, 2.4MHz <-- 48MHz bus only
- Removed string.h dependency (memcpy)
- Changed Master modes to interrupt driven
- Added non-blocking Tx/Rx routines, and status/done/finish routines:
- sendTransmission() - non-blocking transmit
- sendRequest() - non-blocking receive
- status() - reports current status
- done() - indicates Tx/Rx complete (for main loop polling if I2C is running in background)
- finish() - loops until Tx/Rx complete or bus error
- Added readByte()/peekByte() for uint8_t return values (note: returns 0 instead of -1 if buf empty)
- Added fixes for Slave Rx mode - in short Slave Rx on this part is fubar
(as proof, notice the difference in the I2Cx_FLT register in the KL25 Sub-Family parts)
- the SDA-rising ISR hack can work but only detects STOP conditons.
A slave Rx followed by RepSTART won't be detected since bus remains busy.
To fix this if IAAS occurs while already in Slave Rx mode then it will
assume RepSTART occurred and trigger onReceive callback.
- Separated Tx/Rx buffer sizes for asymmetric devices (adjustable in i2c_t3.h)
- Changed Tx/Rx buffer indicies to size_t to allow for large (>256 byte) buffers
- Left debug routines in place (controlled via header defines - default is OFF). If debug is
enabled, note that it can easily overrun the Debug queue on large I2C transfers, yielding
garbage output. Adjust ringbuf size (in rbuf.h) and possibly PIT interrupt rate to adjust
data flow to Serial (note also the buffer in Serial can overflow if written too quickly).
- Added getError() function to return Wire error code
- Added pinConfigure() function for changing pins on the fly (only when bus not busy)
- Added timeouts to endTransmission(), requestFrom(), and finish()
------------------------------------------------------------------------------------------------------
*/
================================================
FILE: i2c_t3.h
================================================
/*
------------------------------------------------------------------------------------------------------
i2c_t3 - I2C library for Teensy 3.x & LC
- (v11.0) Modified 01Dec18 by Brian (nox771 at gmail.com)
Full changelog at end of file
------------------------------------------------------------------------------------------------------
Copyright (c) 2013-2018, Brian (nox771 at gmail.com)
Permission is hereby granted, free of charge, to any person obtaining a copy of this software and
associated documentation files (the "Software"), to deal in the Software without restriction,
including without limitation the rights to use, copy, modify, merge, publish, distribute, sublicense,
and/or sell copies of the Software, and to permit persons to whom the Software is furnished to do so,
subject to the following conditions:
The above copyright notice and this permission notice shall be included in all copies or substantial
portions of the Software.
THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR IMPLIED, INCLUDING BUT NOT
LIMITED TO THE WARRANTIES OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.
IN NO EVENT SHALL THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION
WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.
------------------------------------------------------------------------------------------------------
*/
#if defined(__AVR__)
#error "Sorry, i2c_t3 only works on Teensy LC and 3.x boards. Use Wire for Teensy 2.0."
#endif
#if !defined(I2C_T3_H) && (defined(__MK20DX128__) || defined(__MK20DX256__) || defined(__MKL26Z64__) || \
defined(__MK64FX512__) || defined(__MK66FX1M0__)) // 3.0/3.1-3.2/LC/3.5/3.6
#define I2C_T3_H
#include <inttypes.h>
#include <stdio.h> // for size_t
#include "Arduino.h"
#include <DMAChannel.h>
// TODO missing kinetis.h defs
#ifndef I2C_F_DIV52
#define I2C_F_DIV52 ((uint8_t)0x43)
#define I2C_F_DIV60 ((uint8_t)0x45)
#define I2C_F_DIV136 ((uint8_t)0x4F)
#define I2C_F_DIV176 ((uint8_t)0x55)
#define I2C_F_DIV352 ((uint8_t)0x95)
#define I2C_FLT_SSIE ((uint8_t)0x20) // Start/Stop Interrupt Enable
#define I2C_FLT_STARTF ((uint8_t)0x10) // Start Detect Flag
#endif
// ======================================================================================================
// == Start User Define Section =========================================================================
// ======================================================================================================
// ------------------------------------------------------------------------------------------------------
// I2C Bus Enable control - change to enable buses as follows. The number of buses will be limited to the
// lower of this setting or what is available on the device.
//
// Teensy Max #Buses
// ------ ----------
// LC 2
// 3.0 1
// 3.1 2
// 3.2 2
// 3.5 3
// 3.6 4
//
// I2C_BUS_ENABLE 1 (enable Wire only)
// I2C_BUS_ENABLE 2 (enable Wire & Wire1)
// I2C_BUS_ENABLE 3 (enable Wire & Wire1 & Wire2)
// I2C_BUS_ENABLE 4 (enable Wire & Wire1 & Wire2 & Wire3)
//
#define I2C_BUS_ENABLE 4
// ------------------------------------------------------------------------------------------------------
// Tx/Rx buffer sizes - modify these as needed. Buffers should be large enough to hold:
// Target Addr + Data payload. Default is: 1byte Addr + 258byte Data
// (this can be substantially reduced if working with sensors or small data packets)
//
#define I2C_TX_BUFFER_LENGTH 259
#define I2C_RX_BUFFER_LENGTH 259
// ------------------------------------------------------------------------------------------------------
// Interrupt flag - uncomment and set below to make the specified pin high whenever the
// I2C interrupt occurs (modify pin number as needed). This is useful as a
// trigger signal when using a logic analyzer.
//
//#define I2C0_INTR_FLAG_PIN 5
//#define I2C1_INTR_FLAG_PIN 6
//#define I2C2_INTR_FLAG_PIN 9
//#define I2C3_INTR_FLAG_PIN 10
// ------------------------------------------------------------------------------------------------------
// Auto retry - uncomment to make the library automatically call resetBus() if it has a timeout while
// trying to send a START (occurs at the beginning of any endTransmission() or requestFrom()
// call). This will toggle SCL to try and get a hung Slave device to release the SDA line.
// If successful then it will try again to send a START, if not then it will return a timeout
// error (same as if auto retry was not defined).
//
// Note: this is incompatible with multi-master buses, only use in single-master configurations
//
//#define I2C_AUTO_RETRY
// ------------------------------------------------------------------------------------------------------
// Error counters - uncomment to make the library track error counts. Error counts can be retrieved or
// zeroed using the getErrorCount() and zeroErrorCount() functions respectively.
// When included, errors will be tracked on the following (Master-mode only):
// Reset Bus (auto-retry only), Timeout, Addr NAK, Data NAK, Arb Lost, Bus Not Acquired,
// DMA Errors
//
#define I2C_ERROR_COUNTERS
// ------------------------------------------------------------------------------------------------------
// Disable priority check - uncomment this to entirely disable auto priority escalation. Normally
// priority escalation occurs to ensure I2C ISR operates at a higher priority
// than the calling function (to prevent ISR stall if the calling function
// blocks). Uncommenting this will disable the check and cause I2C ISR to
// remain at default priority. It is recommended to disable this check and
// manually set ISR priority levels when using complex configurations.
//
//#define I2C_DISABLE_PRIORITY_CHECK
// ======================================================================================================
// == End User Define Section ===========================================================================
// ======================================================================================================
// ------------------------------------------------------------------------------------------------------
// Set number of enabled buses
//
#if defined(__MK20DX128__) // 3.0
#define I2C_BUS_NUM 1
#elif (defined(__MK20DX256__) || defined(__MKL26Z64__)) && (I2C_BUS_ENABLE >= 2) // 3.1/3.2/LC
#define I2C_BUS_NUM 2
#elif defined(__MK64FX512__) && (I2C_BUS_ENABLE >= 3) // 3.5
#define I2C_BUS_NUM 3
#elif defined(__MK66FX1M0__) && (I2C_BUS_ENABLE >= 4) // 3.6
#define I2C_BUS_NUM 4
#else
#define I2C_BUS_NUM I2C_BUS_ENABLE
#endif
// ------------------------------------------------------------------------------------------------------
// Interrupt flag setup
//
#if defined(I2C0_INTR_FLAG_PIN)
#define I2C0_INTR_FLAG_INIT do \
{ \
pinMode(I2C0_INTR_FLAG_PIN, OUTPUT); \
digitalWrite(I2C0_INTR_FLAG_PIN, LOW); \
} while(0)
#define I2C0_INTR_FLAG_ON do {digitalWrite(I2C0_INTR_FLAG_PIN, HIGH);} while(0)
#define I2C0_INTR_FLAG_OFF do {digitalWrite(I2C0_INTR_FLAG_PIN, LOW);} while(0)
#else
#define I2C0_INTR_FLAG_INIT do{}while(0)
#define I2C0_INTR_FLAG_ON do{}while(0)
#define I2C0_INTR_FLAG_OFF do{}while(0)
#endif
#if defined(I2C1_INTR_FLAG_PIN)
#define I2C1_INTR_FLAG_INIT do \
{ \
pinMode(I2C1_INTR_FLAG_PIN, OUTPUT); \
digitalWrite(I2C1_INTR_FLAG_PIN, LOW); \
} while(0)
#define I2C1_INTR_FLAG_ON do {digitalWrite(I2C1_INTR_FLAG_PIN, HIGH);} while(0)
#define I2C1_INTR_FLAG_OFF do {digitalWrite(I2C1_INTR_FLAG_PIN, LOW);} while(0)
#else
#define I2C1_INTR_FLAG_INIT do{}while(0)
#define I2C1_INTR_FLAG_ON do{}while(0)
#define I2C1_INTR_FLAG_OFF do{}while(0)
#endif
#if defined(I2C2_INTR_FLAG_PIN)
#define I2C2_INTR_FLAG_INIT do \
{ \
pinMode(I2C2_INTR_FLAG_PIN, OUTPUT); \
digitalWrite(I2C2_INTR_FLAG_PIN, LOW); \
} while(0)
#define I2C2_INTR_FLAG_ON do {digitalWrite(I2C2_INTR_FLAG_PIN, HIGH);} while(0)
#define I2C2_INTR_FLAG_OFF do {digitalWrite(I2C2_INTR_FLAG_PIN, LOW);} while(0)
#else
#define I2C2_INTR_FLAG_INIT do{}while(0)
#define I2C2_INTR_FLAG_ON do{}while(0)
#define I2C2_INTR_FLAG_OFF do{}while(0)
#endif
#if defined(I2C3_INTR_FLAG_PIN)
#define I2C3_INTR_FLAG_INIT do \
{ \
pinMode(I2C3_INTR_FLAG_PIN, OUTPUT); \
digitalWrite(I2C3_INTR_FLAG_PIN, LOW); \
} while(0)
#define I2C3_INTR_FLAG_ON do {digitalWrite(I2C3_INTR_FLAG_PIN, HIGH);} while(0)
#define I2C3_INTR_FLAG_OFF do {digitalWrite(I2C3_INTR_FLAG_PIN, LOW);} while(0)
#else
#define I2C3_INTR_FLAG_INIT do{}while(0)
#define I2C3_INTR_FLAG_ON do{}while(0)
#define I2C3_INTR_FLAG_OFF do{}while(0)
#endif
// ------------------------------------------------------------------------------------------------------
// Error counters setup
//
#if defined(I2C_ERROR_COUNTERS)
#define I2C_ERR_INC(i2c_err_count) do {if(i2c->errCounts[i2c_err_count] < UINT32_MAX) i2c->errCounts[i2c_err_count]++;} while(0)
#else
#define I2C_ERR_INC(i2c_err_count) do{}while(0)
#endif
// ------------------------------------------------------------------------------------------------------
// Function argument enums
//
enum i2c_op_mode {I2C_OP_MODE_IMM, I2C_OP_MODE_ISR, I2C_OP_MODE_DMA};
enum i2c_mode {I2C_MASTER, I2C_SLAVE};
enum i2c_pullup {I2C_PULLUP_EXT, I2C_PULLUP_INT};
enum i2c_rate {I2C_RATE_100 = 100000,
I2C_RATE_200 = 200000,
I2C_RATE_300 = 300000,
I2C_RATE_400 = 400000,
I2C_RATE_600 = 600000,
I2C_RATE_800 = 800000,
I2C_RATE_1000 = 1000000,
I2C_RATE_1200 = 1200000,
I2C_RATE_1500 = 1500000,
I2C_RATE_1800 = 1800000,
I2C_RATE_2000 = 2000000,
I2C_RATE_2400 = 2400000,
I2C_RATE_2800 = 2800000,
I2C_RATE_3000 = 3000000};
enum i2c_stop {I2C_NOSTOP, I2C_STOP};
enum i2c_status {I2C_WAITING, // stopped states
I2C_TIMEOUT, // |
I2C_ADDR_NAK, // |
I2C_DATA_NAK, // |
I2C_ARB_LOST, // |
I2C_BUF_OVF, // |
I2C_NOT_ACQ, // |
I2C_DMA_ERR, // V
I2C_SENDING, // active states
I2C_SEND_ADDR, // |
I2C_RECEIVING, // |
I2C_SLAVE_TX, // |
I2C_SLAVE_RX}; // V
enum i2c_dma_state {I2C_DMA_OFF,
I2C_DMA_ADDR,
I2C_DMA_BULK,
I2C_DMA_LAST};
#if defined(__MKL26Z64__) // LC
enum i2c_pins {I2C_PINS_16_17 = 0, // 16 SCL0 17 SDA0
I2C_PINS_18_19, // 19 SCL0 18 SDA0
I2C_PINS_22_23, // 22 SCL1 23 SDA1
I2C_PINS_DEFAULT,
I2C_PINS_COUNT};
const uint8_t i2c_valid_pins[] = { 0, 16, 17, 2, // bus, scl, sda, alt
0, 19, 18, 2,
1, 22, 23, 2,
0, 0, 0, 0 };
#elif defined(__MK20DX128__) // 3.0
enum i2c_pins {I2C_PINS_16_17 = 0, // 16 SCL0 17 SDA0
I2C_PINS_18_19, // 19 SCL0 18 SDA0
I2C_PINS_DEFAULT,
I2C_PINS_COUNT};
const uint8_t i2c_valid_pins[] = { 0, 16, 17, 2, // bus, scl, sda, alt
0, 19, 18, 2,
0, 0, 0, 0 };
#elif defined(__MK20DX256__) // 3.1/3.2
enum i2c_pins {I2C_PINS_16_17 = 0, // 16 SCL0 17 SDA0
I2C_PINS_18_19, // 19 SCL0 18 SDA0
I2C_PINS_29_30, // 29 SCL1 30 SDA1
I2C_PINS_26_31, // 26 SCL1 31 SDA1
I2C_PINS_DEFAULT,
I2C_PINS_COUNT};
const uint8_t i2c_valid_pins[] = { 0, 16, 17, 2, // bus, scl, sda, alt
0, 19, 18, 2,
1, 29, 30, 2,
1, 26, 31, 6,
0, 0, 0, 0 };
#elif defined(__MK64FX512__) // 3.5
enum i2c_pins {I2C_PINS_3_4 = 0, // 3 SCL2 4 SDA2
I2C_PINS_7_8, // 7 SCL0 8 SDA0
I2C_PINS_16_17, // 16 SCL0 17 SDA0
I2C_PINS_18_19, // 19 SCL0 18 SDA0
I2C_PINS_33_34, // 33 SCL0 34 SDA0
I2C_PINS_37_38, // 37 SCL1 38 SDA1
I2C_PINS_47_48, // 47 SCL0 48 SDA0
I2C_PINS_DEFAULT,
I2C_PINS_COUNT};
const uint8_t i2c_valid_pins[] = { 2, 3, 4, 5, // bus, scl, sda, alt
0, 7, 8, 7,
0, 16, 17, 2,
0, 19, 18, 2,
0, 33, 34, 5,
1, 37, 38, 2,
0, 47, 48, 2,
0, 0, 0, 0 };
#elif defined(__MK66FX1M0__) // 3.6
enum i2c_pins {I2C_PINS_3_4 = 0, // 3 SCL2 4 SDA2
I2C_PINS_7_8, // 7 SCL0 8 SDA0
I2C_PINS_16_17, // 16 SCL0 17 SDA0
I2C_PINS_18_19, // 19 SCL0 18 SDA0
I2C_PINS_33_34, // 33 SCL0 34 SDA0
I2C_PINS_37_38, // 37 SCL1 38 SDA1
I2C_PINS_47_48, // 47 SCL0 48 SDA0
I2C_PINS_56_57, // 57 SCL3 56 SDA3
I2C_PINS_DEFAULT,
I2C_PINS_COUNT};
const uint8_t i2c_valid_pins[] = { 2, 3, 4, 5, // bus, scl, sda, alt
0, 7, 8, 7,
0, 16, 17, 2,
0, 19, 18, 2,
0, 33, 34, 5,
1, 37, 38, 2,
0, 47, 48, 2,
3, 57, 56, 2,
0, 0, 0, 0 };
#endif
enum i2c_err_count {I2C_ERRCNT_RESET_BUS=0,
I2C_ERRCNT_TIMEOUT,
I2C_ERRCNT_ADDR_NAK,
I2C_ERRCNT_DATA_NAK,
I2C_ERRCNT_ARBL,
I2C_ERRCNT_NOT_ACQ,
I2C_ERRCNT_DMA_ERR};
// ------------------------------------------------------------------------------------------------------
// Divide ratio tables
//
const int32_t i2c_div_num[] =
{20,22,24,26,28,30,32,34,36,40,44,48,52,56,60,64,68,72,
80,88,96,104,112,128,136,144,160,176,192,224,240,256,288,
320,352,384,448,480,512,576,640,768,896,960,1024,1152,
1280,1536,1920,1792,2048,2304,2560,3072,3840};
const uint8_t i2c_div_ratio[] =
{I2C_F_DIV20,I2C_F_DIV22,I2C_F_DIV24,I2C_F_DIV26,
I2C_F_DIV28,I2C_F_DIV30,I2C_F_DIV32,I2C_F_DIV34,
I2C_F_DIV36,I2C_F_DIV40,I2C_F_DIV44,I2C_F_DIV48,
I2C_F_DIV52,I2C_F_DIV56,I2C_F_DIV60,I2C_F_DIV64,
I2C_F_DIV68,I2C_F_DIV72,I2C_F_DIV80,I2C_F_DIV88,
I2C_F_DIV96,I2C_F_DIV104,I2C_F_DIV112,I2C_F_DIV128,
I2C_F_DIV136,I2C_F_DIV144,I2C_F_DIV160,I2C_F_DIV176,
I2C_F_DIV192,I2C_F_DIV224,I2C_F_DIV240,I2C_F_DIV256,
I2C_F_DIV288,I2C_F_DIV320,I2C_F_DIV352,I2C_F_DIV384,
I2C_F_DIV448,I2C_F_DIV480,I2C_F_DIV512,I2C_F_DIV576,
I2C_F_DIV640,I2C_F_DIV768,I2C_F_DIV896,I2C_F_DIV960,
I2C_F_DIV1024,I2C_F_DIV1152,I2C_F_DIV1280,I2C_F_DIV1536,
I2C_F_DIV1920,I2C_F_DIV1792,I2C_F_DIV2048,I2C_F_DIV2304,
I2C_F_DIV2560,I2C_F_DIV3072,I2C_F_DIV3840};
// ------------------------------------------------------------------------------------------------------
// Main I2C data structure
//
struct i2cStruct
{
volatile uint8_t* A1; // Address Register 1 (User&ISR)
volatile uint8_t* F; // Frequency Divider Register (User&ISR)
volatile uint8_t* C1; // Control Register
gitextract_mjc7m6f3/ ├── README.md ├── archive/ │ └── README.md ├── examples/ │ ├── advanced_loopback/ │ │ └── advanced_loopback.ino │ ├── advanced_master/ │ │ └── advanced_master.ino │ ├── advanced_scanner/ │ │ └── advanced_scanner.ino │ ├── advanced_slave/ │ │ └── advanced_slave.ino │ ├── basic_echo/ │ │ └── basic_echo.ino │ ├── basic_interrupt/ │ │ └── basic_interrupt.ino │ ├── basic_master/ │ │ └── basic_master.ino │ ├── basic_master_callback/ │ │ └── basic_master_callback.ino │ ├── basic_master_mux/ │ │ └── basic_master_mux.ino │ ├── basic_scanner/ │ │ └── basic_scanner.ino │ ├── basic_slave/ │ │ └── basic_slave.ino │ └── basic_slave_range/ │ └── basic_slave_range.ino ├── i2c_t3.cpp ├── i2c_t3.h └── keywords.txt
SYMBOL INDEX (104 symbols across 2 files)
FILE: i2c_t3.cpp
type i2cStruct (line 41) | struct i2cStruct
type i2cStruct (line 110) | struct i2cStruct
type i2cStruct (line 200) | struct i2cStruct
type i2cStruct (line 345) | struct i2cStruct
type i2cStruct (line 392) | struct i2cStruct
type i2cStruct (line 444) | struct i2cStruct
type i2cStruct (line 557) | struct i2cStruct
type i2cStruct (line 613) | struct i2cStruct
type i2cStruct (line 633) | struct i2cStruct
type i2cStruct (line 759) | struct i2cStruct
type i2cStruct (line 786) | struct i2cStruct
type i2cStruct (line 963) | struct i2cStruct
type i2cStruct (line 975) | struct i2cStruct
type i2cStruct (line 1061) | struct i2cStruct
type i2cStruct (line 1075) | struct i2cStruct
type i2cStruct (line 1095) | struct i2cStruct
type i2cStruct (line 1106) | struct i2cStruct
type i2cStruct (line 1117) | struct i2cStruct
function i2c0_isr (line 1131) | void i2c0_isr(void) // I2C0 ISR
function i2c1_isr (line 1138) | void i2c1_isr(void) // I2C1 ISR
function i2c2_isr (line 1146) | void i2c2_isr(void) // I2C2 ISR
function i2c3_isr (line 1154) | void i2c3_isr(void) // I2C3 ISR
function i2c_isr_handler (line 1165) | void i2c_isr_handler(struct i2cStruct* i2c, uint8_t bus)
type i2cStruct (line 1633) | struct i2cStruct
FILE: i2c_t3.h
type i2c_op_mode (line 224) | enum i2c_op_mode {I2C_OP_MODE_IMM, I2C_OP_MODE_ISR, I2C_OP_MODE_DMA}
type i2c_mode (line 225) | enum i2c_mode {I2C_MASTER, I2C_SLAVE}
type i2c_pullup (line 226) | enum i2c_pullup {I2C_PULLUP_EXT, I2C_PULLUP_INT}
type i2c_rate (line 227) | enum i2c_rate {I2C_RATE_100 = 100000,
type i2c_stop (line 241) | enum i2c_stop {I2C_NOSTOP, I2C_STOP}
type i2c_status (line 242) | enum i2c_status {I2C_WAITING, // stopped states
type i2c_dma_state (line 255) | enum i2c_dma_state {I2C_DMA_OFF,
type i2c_pins (line 260) | enum i2c_pins {I2C_PINS_16_17 = 0, // 16 SCL0 17 SDA0
type i2c_pins (line 270) | enum i2c_pins {I2C_PINS_16_17 = 0, // 16 SCL0 17 SDA0
type i2c_pins (line 278) | enum i2c_pins {I2C_PINS_16_17 = 0, // 16 SCL0 17 SDA0
type i2c_pins (line 290) | enum i2c_pins {I2C_PINS_3_4 = 0, // 3 SCL2 4 SDA2
type i2c_pins (line 308) | enum i2c_pins {I2C_PINS_3_4 = 0, // 3 SCL2 4 SDA2
type i2c_err_count (line 328) | enum i2c_err_count {I2C_ERRCNT_RESET_BUS=0,
type i2cStruct (line 366) | struct i2cStruct
type i2cStruct (line 425) | struct i2cStruct
function class (line 427) | class i2c_t3 : public Stream
type i2cStruct (line 582) | struct i2cStruct
function setOpMode (line 592) | inline uint8_t setOpMode(i2c_op_mode opMode) { return setOpMode_(i2c, bu...
type i2cStruct (line 597) | struct i2cStruct
function setRate (line 634) | inline void setRate(uint32_t busFreq, uint32_t i2cFreq) { setRate_(i2c, ...
function setRate (line 636) | inline uint8_t setRate(uint32_t busFreq, i2c_rate rate) { setRate_(i2c, ...
function setClock (line 638) | inline void setClock(uint32_t i2cFreq)
function setRate (line 650) | inline uint8_t setRate(i2c_rate rate) { setClock((uint32_t)rate); return...
function getClock (line 656) | inline uint32_t getClock(void) { return i2c->currentRate; }
type i2cStruct (line 661) | struct i2cStruct
function pinConfigure (line 688) | inline uint8_t pinConfigure(i2c_pins pins, i2c_pullup pullup=I2C_PULLUP_...
function pinConfigure (line 690) | inline uint8_t pinConfigure(uint8_t pinSCL, uint8_t pinSDA, i2c_pullup p...
function setSCL (line 698) | inline void setSCL(uint8_t pin)
function setSDA (line 700) | inline void setSDA(uint8_t pin)
function getSCL (line 707) | inline uint8_t getSCL(void) { return i2c->currentSCL; }
function getSDA (line 708) | inline uint8_t getSDA(void) { return i2c->currentSDA; }
function setDefaultTimeout (line 717) | inline void setDefaultTimeout(uint32_t timeout) { i2c->defTimeout = time...
type i2cStruct (line 727) | struct i2cStruct
type i2cStruct (line 735) | struct i2cStruct
function resetBus (line 736) | inline void resetBus(void) { resetBus_(i2c, bus); }
function beginTransmission (line 745) | inline void beginTransmission(int address) { beginTransmission((uint8_t)...
type i2cStruct (line 750) | struct i2cStruct
function endTransmission (line 761) | inline uint8_t endTransmission(uint8_t sendStop) { return endTransmissio...
type i2cStruct (line 766) | struct i2cStruct
function sendTransmission (line 777) | inline void sendTransmission(i2c_stop sendStop=I2C_STOP) { sendTransmiss...
type i2cStruct (line 782) | struct i2cStruct
function requestFrom (line 796) | inline size_t requestFrom(int addr, int len)
type i2cStruct (line 804) | struct i2cStruct
function sendRequest (line 817) | inline void sendRequest(uint8_t addr, size_t len, i2c_stop sendStop=I2C_...
function i2c_status (line 830) | inline i2c_status status(void) { return i2c->currentStatus; }
type i2cStruct (line 835) | struct i2cStruct
function done (line 840) | inline uint8_t done(void) { return done_(i2c); }
type i2cStruct (line 845) | struct i2cStruct
function write (line 861) | inline size_t write(unsigned long n) { return write((uint8_t)n); }
function write (line 862) | inline size_t write(long n) { return write((uint8_t)n); }
function write (line 863) | inline size_t write(unsigned int n) { return write((uint8_t)n); }
function write (line 864) | inline size_t write(int n) { return write((uint8_t)n); }
function write (line 876) | inline size_t write(const char* str, size_t count) { return write((const...
function write (line 877) | inline size_t write(const char* str) { return write((const uint8_t*)str,...
function available (line 883) | inline int available(void) { return i2c->rxBufferLength - i2c->rxBufferI...
type i2cStruct (line 888) | struct i2cStruct
function read (line 893) | inline int read(void) { return read_(i2c); }
type i2cStruct (line 902) | struct i2cStruct
function read (line 903) | inline size_t read(uint8_t* data, size_t count) { return read_(i2c, data...
function read (line 904) | inline size_t read(char* str, size_t count) { return read_(i2c, (uint8_t...
type i2cStruct (line 909) | struct i2cStruct
function peek (line 914) | inline int peek(void) { return peek_(i2c); }
type i2cStruct (line 919) | struct i2cStruct
function readByte (line 924) | inline uint8_t readByte(void) { return readByte_(i2c); }
type i2cStruct (line 929) | struct i2cStruct
function peekByte (line 934) | inline uint8_t peekByte(void) { return peekByte_(i2c); }
function flush (line 939) | inline void flush(void) {}
function getRxAddr (line 945) | inline uint8_t getRxAddr(void) { return i2c->rxAddr; }
function onTransmitDone (line 950) | inline void onTransmitDone(void (*function)(void)) { i2c->user_onTransmi...
function onReqFromDone (line 955) | inline void onReqFromDone(void (*function)(void)) { i2c->user_onReqFromD...
function onReceive (line 960) | inline void onReceive(void (*function)(size_t len)) { i2c->user_onReceiv...
function onRequest (line 965) | inline void onRequest(void (*function)(void)) { i2c->user_onRequest = fu...
function onError (line 970) | inline void onError(void (*function)(void)) { i2c->user_onError = functi...
function getErrorCount (line 979) | inline uint32_t getErrorCount(i2c_err_count counter) { return i2c->errCo...
function zeroErrorCount (line 987) | inline void zeroErrorCount(i2c_err_count counter) { i2c->errCounts[count...
function send (line 991) | inline void send(uint8_t b) { write(b); }
function send (line 992) | inline void send(uint8_t* s, uint8_t n) { write(s, n); }
function send (line 993) | inline void send(int n) { write((uint8_t)n); }
function send (line 994) | inline void send(char* s) { write(s); }
function receive (line 995) | inline uint8_t receive(void) { int c = read(); return (c<0) ?...
Condensed preview — 17 files, each showing path, character count, and a content snippet. Download the .json file or copy for the full structured content (254K chars).
[
{
"path": "README.md",
"chars": 30281,
"preview": "# i2c_t3\nEnhanced I2C library for Teensy 3.x & LC devices\n\nThis is an enhanced I2C library for [Teensy 3.x/LC devices](h"
},
{
"path": "archive/README.md",
"chars": 73,
"preview": "# i2c_t3 Archive\nThis folder contains all older releases of the library.\n"
},
{
"path": "examples/advanced_loopback/advanced_loopback.ino",
"chars": 7410,
"preview": "// -------------------------------------------------------------------------------------------\n// Loopback\n// ----------"
},
{
"path": "examples/advanced_master/advanced_master.ino",
"chars": 23522,
"preview": "// -------------------------------------------------------------------------------------------\n// I2C Advanced Master\n//"
},
{
"path": "examples/advanced_scanner/advanced_scanner.ino",
"chars": 6026,
"preview": "// -------------------------------------------------------------------------------------------\n// I2C Advanced Bus Scann"
},
{
"path": "examples/advanced_slave/advanced_slave.ino",
"chars": 4982,
"preview": "// -------------------------------------------------------------------------------------------\n// I2C Advanced Slave\n// "
},
{
"path": "examples/basic_echo/basic_echo.ino",
"chars": 2844,
"preview": "// -------------------------------------------------------------------------------------------\n// Basic Echo\n// --------"
},
{
"path": "examples/basic_interrupt/basic_interrupt.ino",
"chars": 2432,
"preview": "// -------------------------------------------------------------------------------------------\n// Interrupt\n// ---------"
},
{
"path": "examples/basic_master/basic_master.ino",
"chars": 2940,
"preview": "// -------------------------------------------------------------------------------------------\n// Basic Master\n// ------"
},
{
"path": "examples/basic_master_callback/basic_master_callback.ino",
"chars": 5887,
"preview": "// -------------------------------------------------------------------------------------------\n// Basic Master Callback\n"
},
{
"path": "examples/basic_master_mux/basic_master_mux.ino",
"chars": 2906,
"preview": "// -------------------------------------------------------------------------------------------\n// Basic Master Multiplex"
},
{
"path": "examples/basic_scanner/basic_scanner.ino",
"chars": 2415,
"preview": "// -------------------------------------------------------------------------------------------\n// I2C Bus Scanner\n// ---"
},
{
"path": "examples/basic_slave/basic_slave.ino",
"chars": 1920,
"preview": "// -------------------------------------------------------------------------------------------\n// Basic Slave\n// -------"
},
{
"path": "examples/basic_slave_range/basic_slave_range.ino",
"chars": 2264,
"preview": "// -------------------------------------------------------------------------------------------\n// Basic Slave with Addre"
},
{
"path": "i2c_t3.cpp",
"chars": 84418,
"preview": "/*\n ------------------------------------------------------------------------------------------------------\n i2c_t3"
},
{
"path": "i2c_t3.h",
"chars": 64482,
"preview": "/*\n ------------------------------------------------------------------------------------------------------\n i2c_t3"
},
{
"path": "keywords.txt",
"chars": 2204,
"preview": "I2C_BUS_NUM LITERAL1\nI2C_TX_BUFFER_LENGTH LITERAL1\nI2C_RX_BUFFER_LENGTH LITERAL1\nI2C_OP_MODE_IMM\tLITERAL1\nI2C_OP_M"
}
]
About this extraction
This page contains the full source code of the nox771/i2c_t3 GitHub repository, extracted and formatted as plain text for AI agents and large language models (LLMs). The extraction includes 17 files (241.2 KB), approximately 66.0k tokens, and a symbol index with 104 extracted functions, classes, methods, constants, and types. Use this with OpenClaw, Claude, ChatGPT, Cursor, Windsurf, or any other AI tool that accepts text input. You can copy the full output to your clipboard or download it as a .txt file.
Extracted by GitExtract — free GitHub repo to text converter for AI. Built by Nikandr Surkov.